Esporta tutti i grafici di controllo dalla colonna Per su una pagina per l'esportazione in PowerPointCiao,
Ho uno script che utilizzo per creare 6 carte di controllo per 20 pozzi separati di monitoraggio delle acque sotterranee utilizzando la parte By nello script. Vorrei aggiungere alla fine dello script in modo da poter stampare i 6 grafici di controllo per ciascuna posizione di monitoraggio separata su una pagina in una presentazione powerpoint Risultato in una presentazione powerpoint lunga 20 pagine, con 6 grafici su ogni pagina. Sto cercando qualche consiglio su dove iniziare per questo compito? Ecco lo script che sto usando per creare i grafici:
Control Chart Builder(
Show Capability( 0 ),
Variables(
Subgroup( :SAMPLE_DATE ),
Y(
:Chloride,
:Cl_TDS,
:Sodium,
:Total Dissolved Solids,
:Sulphate,
:Calcium
),
),
By(:LOC_NAME)
);
Grazie!
Condivisione e comunicazione dei risultatiOggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPoint@txnelson Grazie per la sceneggiatura! È perfetto. Sono stato in grado di modificare una parte per consentire a tutti e 6 i grafici di ciascun campione di salvare su una diapositiva powerpoint. Apprezzo molto il tuo aiuto e mi è piaciuto imparare mentre leggevo la sceneggiatura.
Grazie ancora!
Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointDi seguito è riportato uno script che crea l'output di PowerPoint dalla tabella di dati di esempio
Names Default To Here( 1 );
dt = Current Data Table();
// Get a list of the LOC_Name's that are in the data
Summarize( dt, bygroup = by( :LOC_Name ) );
// Create a display window to put the graphs into
Nw = New Window( "Control Charts" );
// Loop across all of the LOC_Name's creating the six control
// charts
For( i = 1, i <= N Items( bygroup ), i++,
// Create the Outline Box to hold the 6 charts
ob = Outline Box( "Control Charts for LOC_Name=" || byGroup[i] );
// Create a display box of three objects wide
// With the 6 control charts, it will make it a
// 2 row 3 column output
lub = Lineup Box( N Col( 3 ) );
// Create the 6 charts
ccb = dt << Control Chart Builder( invisible,
Show Capability( 0 ),
Show control panel( 0 ),
Variables(
Subgroup( :SAMPLE_DATE ),
Y(
:Chloride,
:Cl_TDS,
:Sodium,
:Total Dissolved Solids,
:Sulphate,
:Calcium
)
),
show limit summaries( 0 ),
where( :loc_name == Eval( bygroup[i] ) )
);
// Loop across the output pulling out the 6 Picture Boxes
// that contains the desired output for each control chart
// and add them to the Lineup Box
For( k = 1, k <= 6, k++,
lub << append( Report( ccb )[Picture Box( i )] )
);
// Close the no longer needed Control Chart Builder window
Report( ccb ) << close window;
// Add the contents of the Line Up Box to the Outline Box
// but make it a single object so when saved to pptx it will
// be treated as a single graph
ob << append( lub << get picture );
// Add the current outline box to the display window
nw << append( ob );
);
// Save the graphs to PowerPoint
nw << save presentation( "$TEMP/myppt.pptx" );
// Display the PowerPoint output
Open( "$TEMP/myppt.pptx" );
Per favore, prenditi il tempo per studiare la sceneggiatura in modo da capire l'approccio che ho adottato, in modo da poter apportare le modifiche necessarie.La sezione nella Guida allo scripting sugli alberi di visualizzazione ti fornirà lo sfondo su come ho separato l'output e lo ho ricostruito in un nuovo formato di visualizzazione.
Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointCiao,
Sto cercando che vengano trasposti fondamentalmente. Vedi immagine allegata. Perché poi esporterò ogni set di 6 grafici come un jpg e lo inserirò in powerpoint. Guarda come LOC_NAME = 00-15A ha sei grafici, quindi il successivo set di sei grafici è LOC_NAME = 0016A.
Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointE 'questo quello che stai cercando?
Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, bygroup = by( :LOC_Name ) );
Nw = New Window( "Control Charts", lb = Lineup Box( N Col( 2 ) ) );
For( i = 1, i <= N Items( bygroup ), i++,
vlb = V List Box(
dt << Control Chart Builder(
Show Capability( 0 ),
Show control panel( 0 ),
Variables(
Subgroup( :SAMPLE_DATE ),
Y( :Chloride, :Cl_TDS, :Sodium, :Total Dissolved Solids, :Sulphate, :Calcium )
),
show limit summaries( 0 ),
where( :loc_name == Eval( bygroup[i] ) )
)
);
lb << append( vlb );
);Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointCiao,
Grazie per l'idea. Ho modificato leggermente lo script per includere una casella Lineup. All'inizio ho provato con più nomi univoci nella colonna "per". Tuttavia stava mettendo un campione diverso nella seconda colonna, piuttosto che suddividere i 6 grafici per ogni nome univoco in 2 colonne di tre. Vedi foto allegata.
Quindi ho riprovato utilizzando un solo valore univoco per vedere se suddivideva i sei grafici in 2 colonne ed esportava l'unico valore univoco in una colonna di sei grafici. Ancora non si è separato in 2 colonne. Che cosa sto facendo di sbagliato?
Ecco una parte della sceneggiatura.
Nw = New Window( "Control Charts",
Lineup Box( N Col( 3 ),
Control Chart Builder(
Show Capability( 0 ),
Variables(
Subgroup( :SAMPLE_DATE ),
Y(
:Chloride,
:Cl_TDS,
:Sodium,
:Total Dissolved Solids,
:Sulphate,
:Calcium
),
),
SendToReport(
Dispatch( {}, "Chloride Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {}, "Cl_TDS Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {}, "Sodium Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {},
"Total Dissolved Solids Limit Summaries",
OutlineBox,
{Close( 1 )}
),
Dispatch( {}, "Sulphate Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {}, "Calcium Limit Summaries", OutlineBox, {Close( 1 )} )
),by(:LOC_NAME);
);
);
);Ho anche incluso un esempio del mio set di dati se questo aiuta.
Grazie per l'aiuto.
Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointEcco uno dei metodi che utilizzo per creare più colonne di output
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
Nw = New Window( "Control Charts",
Lineup Box( N Col( 2 ),
Control Chart Builder(
Show Capability( 0 ),
Variables( Y( :height, :weight ) ),
by( :age )
)
)
);
Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointCIAO!
Grazie per la risposta. Ho guardato il video e mi ha dato le informazioni giuste per inserire le carte di controllo in powerpoint e farle aggiornare automaticamente. Questo è decisamente utile. Ora ho aggiunto al mio script per salvare ogni set dei miei grafici di controllo come jpg in una cartella specifica, e li inserirò in powerpoint come hai detto (con un collegamento). Tuttavia, il mio ultimo pezzo del puzzle consiste nel sistemare i grafici nei miei jpg tre grafici in orizzontale e due in basso. Attualmente stanno esportando 6 down, il che non sembra carino su una diapositiva powerpoint.Vedi immagine allegata.
Grazie per l'aiuto!
ccb = dt << Control Chart Builder(
Show Capability( 0 ),
Variables(
Subgroup( :SAMPLE_DATE ),
Y(
:Chloride,
:Cl_TDS,
:Sodium,
:Total Dissolved Solids,
:Sulphate,
:Calcium
),
),
SendToReport(
Dispatch( {}, "Chloride Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {}, "Cl_TDS Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {}, "Sodium Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {},
"Total Dissolved Solids Limit Summaries",
OutlineBox,
{Close( 1 )}
),
Dispatch( {}, "Sulphate Limit Summaries", OutlineBox, {Close( 1 )} ),
Dispatch( {}, "Calcium Limit Summaries", OutlineBox, {Close( 1 )} )
),
By(:LOC_NAME)
);
for(c=1, c<=NItems(ccb), c++,
thisrep = Report(ccb[c]);
firstOB = thisrep[OutlineBox(1)];
thistitle = firstOB << getTitle;
firstOB << save picture ("desktop/"||thistitle);
);Oggetto: Esportare tutti i grafici di controllo dalla colonna Per in una pagina per l'esportazione in PowerPointCIAO,
Ho registrato una sessione di Mastering JMP alcuni mesi fa in cui dimostro come salvare automaticamente i report in PowerPoint ( Padroneggiare JMP Condividere i risultati , a partire dalle 33:30).Questo potrebbe essere un buon punto di partenza.Per favore, dai un'occhiata e fammi sapere se questo ti indirizza nella giusta direzione.
