340641_zh-TW

liliconcom

從一頁上的“按列”導出所有控製圖，以便導出到 powerpoint

你好，

 

我有一個腳本，使用腳本中的“按”部分為 20 個獨立的地下水監測井製作 6 個控製圖。 我想在腳本的末尾添加內容，這樣我就可以在 powerpoint 演示文稿的一頁上打印每個單獨監控位置的 6 個控製圖，結果是一個 20 頁長的 powerpoint 演示文稿，每頁有 6 個圖表。 我正在尋求一些關於從哪裡開始執行此任務的建議？ 這是我用來製作圖表的腳本：

 

Control Chart Builder(
 Show Capability( 0 ),
 Variables(
  Subgroup( :SAMPLE_DATE ),
  Y(
   :Chloride,
   :Cl_TDS,
   :Sodium,
   :Total Dissolved Solids,
   :Sulphate,
   :Calcium
  ),
  
 ),
 By(:LOC_NAME)
);

謝謝你！

分享和交流結果回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

@tx尼爾森謝謝你的劇本！ 那是完美的。 我能夠修改一部分，以便將每個樣本的全部 6 個圖表保存在一張幻燈片上。 我真的很感謝你的幫助，我在閱讀劇本時很享受學習的過程。

 

再次感謝！

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

下面是一個從示例數據表創建 PowerPoint 輸出的腳本

Names Default To Here( 1 );
dt = Current Data Table();

// Get a list of the LOC_Name's that are in the data
Summarize( dt, bygroup = by( :LOC_Name ) );

// Create a display window to put the graphs into
Nw = New Window( "Control Charts" );

// Loop across all of the LOC_Name's creating the six control
// charts 
For( i = 1, i <= N Items( bygroup ), i++,

 // Create the Outline Box to hold the 6 charts
 ob = Outline Box( "Control Charts for LOC_Name=" || byGroup[i] );
 
 // Create a display box of three objects wide
 // With the 6 control charts, it will make it a 
 // 2 row 3 column output
 lub = Lineup Box( N Col( 3 ) );
 
 // Create the 6 charts
 ccb = dt << Control Chart Builder( invisible,
  Show Capability( 0 ),
  Show control panel( 0 ),
  Variables(
   Subgroup( :SAMPLE_DATE ),
   Y(
    :Chloride,
    :Cl_TDS,
    :Sodium,
    :Total Dissolved Solids,
    :Sulphate,
    :Calcium
   )
  ),
  show limit summaries( 0 ),
  where( :loc_name == Eval( bygroup[i] ) )
 );
 
 // Loop across the output pulling out the 6 Picture Boxes
 // that contains the desired output for each control chart
 // and add them to the Lineup Box
 For( k = 1, k <= 6, k++,
  lub << append( Report( ccb )[Picture Box( i )] )
 );
 
 // Close the no longer needed Control Chart Builder window
 Report( ccb ) << close window;
 
 // Add the contents of the Line Up Box to the Outline Box
 // but make it a single object so when saved to pptx it will
 // be treated as a single graph
 ob << append( lub << get picture );
 
 // Add the current outline box to the display window
 nw << append( ob );
 
);

// Save the graphs to PowerPoint
nw << save presentation( "$TEMP/myppt.pptx" );

// Display the PowerPoint output
Open( "$TEMP/myppt.pptx" );

請花時間研究腳本，以便您了解我所採用的方法，以便您可以進行任何所需的調整。腳本指南中有關顯示樹的部分將向您介紹我如何分離輸出並將其重新構建為新的顯示格式的背景知識。

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

你好，

 

我正在尋找它們基本上可以轉置。 參見附圖。 因為那時我會將每組 6 個圖表導出為一個 jpg 並插入到 powerpoint 中。 看看 LOC_NAME = 00-15A 有六個圖，然後下一組六個圖是 LOC_NAME = 0016A。

 

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

這是你想要的？

Names Default To Here( 1 );
dt = Current Data Table();

Summarize( dt, bygroup = by( :LOC_Name ) );

Nw = New Window( "Control Charts", lb = Lineup Box( N Col( 2 ) ) );


For( i = 1, i <= N Items( bygroup ), i++,
 vlb = V List Box(
  dt << Control Chart Builder(
   Show Capability( 0 ),
   Show control panel( 0 ),
   Variables(
    Subgroup( :SAMPLE_DATE ),
    Y( :Chloride, :Cl_TDS, :Sodium, :Total Dissolved Solids, :Sulphate, :Calcium )
   ),
   show limit summaries( 0 ),
   where( :loc_name == Eval( bygroup[i] ) )
  )
 );
 lb << append( vlb );
);

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

你好，

 

謝謝你的主意。 我對腳本進行了一些更改以包含陣容框。 起初，我嘗試在“by”列中使用多個唯一名稱。 然而，它在第二列中放置了不同的樣本，而不是將每個唯一名稱的 6 個圖表分成 2 列，每列 3 個。 參見附圖。

 

因此，我再次嘗試僅使用一個唯一值，看看它是否會將六個圖表分成兩列，並導出一列六個圖表中的一個唯一值。 它仍然沒有分成兩列。 我究竟做錯了什麼？

 

這是腳本的一部分。

 

Nw = New Window( "Control Charts",
 Lineup Box( N Col( 3 ),
  Control Chart Builder(
   Show Capability( 0 ),
 Variables(
  Subgroup( :SAMPLE_DATE ),
  Y(
   :Chloride,
   :Cl_TDS,
   :Sodium,
   :Total Dissolved Solids,
   :Sulphate,
   :Calcium
  ),
  
 ),
  SendToReport(
  Dispatch( {}, "Chloride Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Cl_TDS Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Sodium Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {},
   "Total Dissolved Solids Limit Summaries",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch( {}, "Sulphate Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Calcium Limit Summaries", OutlineBox, {Close( 1 )} )
 ),by(:LOC_NAME);
);

);
);

如果有幫助的話，我還提供了我的數據集的示例。

感謝您的幫助。

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

這是我用來創建多列輸出的方法之一

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

Nw = New Window( "Control Charts",
 Lineup Box( N Col( 2 ),
  Control Chart Builder(
   Show Capability( 0 ),
   Variables( Y( :height, :weight ) ),
   by( :age )
  )
 )
);

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

你好！

 

感謝你的回复。 我觀看了視頻，它為我提供了將控製圖放入 powerpoint 並自動更新的正確信息。 這絕對有幫助。 我現在已經添加到我的腳本中，將每組控製圖保存為特定文件夾中的 jpg，並且我將按照您所說的將它們插入到 powerpoint 中（帶有鏈接）。 然而，我的最後一個難題涉及將我的 jpg 中的圖表排列成三個橫向、兩個向下。 目前他們正在導出 6 個下來，這在幻燈片上看起來不太好。參見附圖。

 

感謝您的幫助！

 

ccb = dt << Control Chart Builder(
 Show Capability( 0 ),
 Variables(
  Subgroup( :SAMPLE_DATE ),
  Y(
   :Chloride,
   :Cl_TDS,
   :Sodium,
   :Total Dissolved Solids,
   :Sulphate,
   :Calcium
  ),
  
 ),
  SendToReport(
  Dispatch( {}, "Chloride Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Cl_TDS Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Sodium Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {},
   "Total Dissolved Solids Limit Summaries",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch( {}, "Sulphate Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Calcium Limit Summaries", OutlineBox, {Close( 1 )} )
 ),
 By(:LOC_NAME)
);

for(c=1, c<=NItems(ccb), c++,

 thisrep = Report(ccb[c]);
 
 firstOB = thisrep[OutlineBox(1)];

 thistitle = firstOB << getTitle;

 firstOB << save picture ("desktop/"||thistitle);
 );

回复：從一頁上的按列導出所有控製圖以導出到 powerpoint

你好，

 

幾個月前，我錄製了掌握 JMP 課程，其中演示瞭如何自動將報告保存到 PowerPoint（掌握 JMP 分享您的結果，33:30 開始）。這可能是一個很好的起點。請看一下並告訴我這是否為您指明了正確的方向。