340641_es-ES

liliconcom

Exporte todos los gráficos de control de Por columna en una página para exportarlos a PowerPoint

Hola,

 

Tengo una secuencia de comandos que utilizo para hacer 6 gráficos de control para 20 pozos de monitoreo de agua subterránea separados usando la parte Por en la secuencia de comandos. Me gustaría agregar al final de la secuencia de comandos para poder imprimir los 6 gráficos de control para cada ubicación de monitoreo por separado en una página en una presentación de PowerPoint. El resultado es una presentación de PowerPoint de 20 páginas, con 6 gráficos en cada página. Estoy buscando algunos consejos sobre por dónde empezar para esta tarea. Aquí está el script que estoy usando para hacer los gráficos:

 

Control Chart Builder(
 Show Capability( 0 ),
 Variables(
  Subgroup( :SAMPLE_DATE ),
  Y(
   :Chloride,
   :Cl_TDS,
   :Sodium,
   :Total Dissolved Solids,
   :Sulphate,
   :Calcium
  ),
  
 ),
 By(:LOC_NAME)
);

¡Gracias!

Gráficossecuencias de comandosRe: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

@txnelson ¡Gracias por el guión! Eso es perfecto. Pude modificar una parte para permitir que los 6 gráficos de cada muestra se guardaran en una diapositiva de PowerPoint. Realmente aprecio su ayuda y disfruté aprendiendo mientras leía el guión.

 

¡Gracias de nuevo!

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

A continuación se muestra una secuencia de comandos que crea la salida de PowerPoint a partir de su tabla de datos de ejemplo

Names Default To Here( 1 );
dt = Current Data Table();

// Get a list of the LOC_Name's that are in the data
Summarize( dt, bygroup = by( :LOC_Name ) );

// Create a display window to put the graphs into
Nw = New Window( "Control Charts" );

// Loop across all of the LOC_Name's creating the six control
// charts 
For( i = 1, i <= N Items( bygroup ), i++,

 // Create the Outline Box to hold the 6 charts
 ob = Outline Box( "Control Charts for LOC_Name=" || byGroup[i] );
 
 // Create a display box of three objects wide
 // With the 6 control charts, it will make it a 
 // 2 row 3 column output
 lub = Lineup Box( N Col( 3 ) );
 
 // Create the 6 charts
 ccb = dt << Control Chart Builder( invisible,
  Show Capability( 0 ),
  Show control panel( 0 ),
  Variables(
   Subgroup( :SAMPLE_DATE ),
   Y(
    :Chloride,
    :Cl_TDS,
    :Sodium,
    :Total Dissolved Solids,
    :Sulphate,
    :Calcium
   )
  ),
  show limit summaries( 0 ),
  where( :loc_name == Eval( bygroup[i] ) )
 );
 
 // Loop across the output pulling out the 6 Picture Boxes
 // that contains the desired output for each control chart
 // and add them to the Lineup Box
 For( k = 1, k <= 6, k++,
  lub << append( Report( ccb )[Picture Box( i )] )
 );
 
 // Close the no longer needed Control Chart Builder window
 Report( ccb ) << close window;
 
 // Add the contents of the Line Up Box to the Outline Box
 // but make it a single object so when saved to pptx it will
 // be treated as a single graph
 ob << append( lub << get picture );
 
 // Add the current outline box to the display window
 nw << append( ob );
 
);

// Save the graphs to PowerPoint
nw << save presentation( "$TEMP/myppt.pptx" );

// Display the PowerPoint output
Open( "$TEMP/myppt.pptx" );

Tómese el tiempo para estudiar el guión para que comprenda el enfoque que tomé, para que pueda hacer los ajustes necesarios.La sección de la Guía de secuencias de comandos sobre árboles de visualización le brindará información sobre cómo seleccioné la salida y la construí nuevamente en un nuevo formato de visualización.

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

Hola,

 

Estoy buscando que se transpongan básicamente. Ver imagen adjunta. Porque luego exportaré cada conjunto de 6 gráficos como un jpg y lo insertaré en PowerPoint. Vea cómo LOC_NAME = 00-15A tiene seis gráficos, y luego el siguiente conjunto de seis gráficos es LOC_NAME = 0016A.

 

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

¿Es esto lo que estás buscando?

Names Default To Here( 1 );
dt = Current Data Table();

Summarize( dt, bygroup = by( :LOC_Name ) );

Nw = New Window( "Control Charts", lb = Lineup Box( N Col( 2 ) ) );


For( i = 1, i <= N Items( bygroup ), i++,
 vlb = V List Box(
  dt << Control Chart Builder(
   Show Capability( 0 ),
   Show control panel( 0 ),
   Variables(
    Subgroup( :SAMPLE_DATE ),
    Y( :Chloride, :Cl_TDS, :Sodium, :Total Dissolved Solids, :Sulphate, :Calcium )
   ),
   show limit summaries( 0 ),
   where( :loc_name == Eval( bygroup[i] ) )
  )
 );
 lb << append( vlb );
);

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

Hola,

 

Gracias por la idea. Cambié un poco el guión para incluir un cuadro de alineación. Al principio probé con múltiples nombres únicos en la columna 'por'. Sin embargo, estaba poniendo una muestra diferente en la segunda columna, en lugar de dividir los 6 gráficos para cada nombre único en 2 columnas de tres. Ver foto adjunta.

 

Así que intenté nuevamente usando solo un valor único para ver si dividía los seis gráficos en 2 columnas y exportaba el valor único en una columna de seis gráficos. Todavía no se separó en 2 columnas. ¿Qué estoy haciendo mal?

 

Aquí hay una parte del guión.

 

Nw = New Window( "Control Charts",
 Lineup Box( N Col( 3 ),
  Control Chart Builder(
   Show Capability( 0 ),
 Variables(
  Subgroup( :SAMPLE_DATE ),
  Y(
   :Chloride,
   :Cl_TDS,
   :Sodium,
   :Total Dissolved Solids,
   :Sulphate,
   :Calcium
  ),
  
 ),
  SendToReport(
  Dispatch( {}, "Chloride Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Cl_TDS Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Sodium Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {},
   "Total Dissolved Solids Limit Summaries",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch( {}, "Sulphate Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Calcium Limit Summaries", OutlineBox, {Close( 1 )} )
 ),by(:LOC_NAME);
);

);
);

También he incluido un ejemplo de mi conjunto de datos si eso ayuda.

Gracias por tu ayuda.

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

Este es uno de los métodos que utilizo para crear múltiples columnas de salida.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

Nw = New Window( "Control Charts",
 Lineup Box( N Col( 2 ),
  Control Chart Builder(
   Show Capability( 0 ),
   Variables( Y( :height, :weight ) ),
   by( :age )
  )
 )
);

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

¡Hola!

 

Gracias por su respuesta. Vi el video y me dio la información correcta para poner los gráficos de control en PowerPoint y hacer que se actualicen automáticamente. Eso definitivamente es útil. Ahora agregué a mi secuencia de comandos para guardar cada conjunto de mis gráficos de control como un jpg en una carpeta específica, y los insertaré en PowerPoint como dijiste (con un enlace). Sin embargo, mi última pieza del rompecabezas consiste en organizar los gráficos en mis jpg, tres gráficos de lado a lado y dos de lado a lado. Actualmente están exportando 6 hacia abajo, lo que no se ve bien en una diapositiva de PowerPoint.Ver imagen adjunta.

 

¡Gracias por tu ayuda!

 

ccb = dt << Control Chart Builder(
 Show Capability( 0 ),
 Variables(
  Subgroup( :SAMPLE_DATE ),
  Y(
   :Chloride,
   :Cl_TDS,
   :Sodium,
   :Total Dissolved Solids,
   :Sulphate,
   :Calcium
  ),
  
 ),
  SendToReport(
  Dispatch( {}, "Chloride Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Cl_TDS Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Sodium Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {},
   "Total Dissolved Solids Limit Summaries",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch( {}, "Sulphate Limit Summaries", OutlineBox, {Close( 1 )} ),
  Dispatch( {}, "Calcium Limit Summaries", OutlineBox, {Close( 1 )} )
 ),
 By(:LOC_NAME)
);

for(c=1, c<=NItems(ccb), c++,

 thisrep = Report(ccb[c]);
 
 firstOB = thisrep[OutlineBox(1)];

 thistitle = firstOB << getTitle;

 firstOB << save picture ("desktop/"||thistitle);
 );

Re: Exportar todos los gráficos de control de Por columna en una página para exportar a PowerPoint

Hola,

 

Grabé una sesión de Mastering JMP hace unos meses en la que demuestro cómo guardar informes automáticamente en PowerPoint ( Dominar JMP Compartir sus resultados , a partir de las 33:30).Este podría ser un buen lugar para comenzar.Por favor, eche un vistazo y avíseme si esto lo lleva en la dirección correcta.