Export all control charts from By column on one page for export to powerpoint

Lharbicht

Hello,

 

I have a script that I use to make 6 control charts for 20 separate groundwater monitoring wells using the By portion in the script. I would like to add on to the end of the script so I can print the 6 control charts for each separate monitoring location on one page in a powerpoint presentation Result in a powerpoint presentation that is 20 pages long, with 6 graphs on each page. I'm looking for some advice on where to start for this task? Here is the script I'm using to make the charts: 

 

Control Chart Builder(
	Show Capability( 0 ),
	Variables(
		Subgroup( :SAMPLE_DATE ),
		Y(
			:Chloride,
			:Cl_TDS,
			:Sodium,
			:Total Dissolved Solids,
			:Sulphate,
			:Calcium
		),
		
	),
	By(:LOC_NAME)
);

Thank you!

txnelson

Below is a script that creates the PowerPoint output from your Example data table

Names Default To Here( 1 );
dt = Current Data Table();

// Get a list of the LOC_Name's that are in the data
Summarize( dt, bygroup = by( :LOC_Name ) );

// Create a display window to put the graphs into
Nw = New Window( "Control Charts" );

// Loop across all of the LOC_Name's creating the six control
// charts 
For( i = 1, i <= N Items( bygroup ), i++,

	// Create the Outline Box to hold the 6 charts
	ob = Outline Box( "Control Charts for LOC_Name=" || byGroup[i] );
	
	// Create a display box of three objects wide
	// With the 6 control charts, it will make it a 
	// 2 row 3 column output
	lub = Lineup Box( N Col( 3 ) );
	
	// Create the 6 charts
	ccb = dt << Control Chart Builder( invisible,
		Show Capability( 0 ),
		Show control panel( 0 ),
		Variables(
			Subgroup( :SAMPLE_DATE ),
			Y(
				:Chloride,
				:Cl_TDS,
				:Sodium,
				:Total Dissolved Solids,
				:Sulphate,
				:Calcium
			)
		),
		show limit summaries( 0 ),
		where( :loc_name == Eval( bygroup[i] ) )
	);
	
	// Loop across the output pulling out the 6 Picture Boxes
	// that contains the desired output for each control chart
	// and add them to the Lineup Box
	For( k = 1, k <= 6, k++,
		lub << append( Report( ccb )[Picture Box( i )] )
	);
	
	// Close the no longer needed Control Chart Builder window
	Report( ccb ) << close window;
	
	// Add the contents of the Line Up Box to the Outline Box
	// but make it a single object so when saved to pptx it will
	// be treated as a single graph
	ob << append( lub << get picture );
	
	// Add the current outline box to the display window
	nw << append( ob );
	
);

// Save the graphs to PowerPoint
nw << save presentation( "$TEMP/myppt.pptx" );

// Display the PowerPoint output
Open( "$TEMP/myppt.pptx" );

Please take the time to study the script so you understand the approach I took, so you can make any adjustments needed.  The section in the Scripting Guide on Display Trees will give you the background on how I picked apart the output, and built it back into a new display format.