340093_it-IT

liliconcom

Allinea la visualizzazione dei grafici Vlist e Hlist

Ciao,

 

Sto cercando di creare un rapporto più estatico da guardare allineando i grafici V e H uno accanto all'altro.

 

il mio script produce un grafico di tendenza e un grafico BoxPlot per ~ 10 parametri, da qualche parte nel mezzo del rapporto i due grafici, per lo stesso parametro, non sono uno accanto all'altro, come nell'immagine sotto.

 

qualcuno può suggerire un modo per allineare le classifiche?

 

il mio script di seguito

 

 

 New Window( "XXX_Charts",
  Outline Box( "TrendCharts and TMM",
   H List Box(
    V List Box(
        lst = dtN << Bivariate(
        Y(:MEAN_VALUE),
        X(:RUN_DATE),
        SendToReport(
         0,
         Dispatch(
          {},
          "Bivar Plot",
          FrameBox,
          {Frame Size(524, 260), 
          Row Legend(
           CHAMBER,
           Color(1),
           Color Theme("JMP Default"),
           Marker(1),
           Marker Theme("Standard"),
           Continuous Scale(0),
           Reverse Scale(0),
           Excluded Rows(0)
          )}
         )
        ),
        By(Column("ALIAS"))
        );

       lst<< Group By (:CHAMBER);
       lst<< Fit Spline( 0.1, Standardized); 
      ),//end of V list
     V List Box(   
       lst = dtN << Oneway(
         Y( :MEAN_VALUE ),
         X( :CHAMBER ),
         By(Column("ALIAS")),
         Means and Std Dev( 0 ),
         Box Plots( 1 ),
         Mean Lines( 1 ),
         Mean Diamonds( 1 ),
         X Axis Proportional( 0 ),
         Points Jittered( 0 ),
         Grand Mean( 0 ),
         SendToReport(
         Dispatch(
          {},
          "Oneway Plot",
          FrameBox,
          {Frame Size( 510, 310 )}
         )
          )
           );// end of oneway
        
    )
   )
  );
 );

ScriptingRi: Allinea i grafici Vlist e Hlist

'Aiuto> Libri> Guida allo scripting' contiene molte informazioni sulle diverse finestre di visualizzazione e in genere puoi ottenere il layout che desideri abbastanza facilmente. In questo caso, "LineUpBox ()" lo fa?

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

// A couple of not very useful 'template' reports for a parameter
ow1 = Expr(Oneway( Y( yTBD ), X( :SITE ) ));
ow2 = Expr(Oneway( Y( yTBD ), X( :lot_id ) ));

// Make a list of alll parameters
allParams = dt << getColumnNames("String");
RemoveFrom(allParams, {1, 2, 3, 4});

// Take ten parameters at random
myParams = allParams[RandomIndex(NItems(allParams), 10)];

// Use a 'LineUpBox()' with two columns (so one parameter in each row)
lub = LineUpBox(NCol(2));
for(p=1, p<=NItems(myParams), p++,
 plot1 = Substitute(NameExpr(ow1), Expr(yTBD), myParams[p]);
 plot2 = Substitute(NameExpr(ow2), Expr(yTBD), myParams[p]);
 lub << append(plot1);
 lub << append(plot2); 
);

// Make a window
nw = NewWindow("Two reports per Parameter", lub);