Align Vlist and Hlist charts display

AdamChoen

Hi,

 

I'm trying to create a more ecstatic report to look at by aligning the V and H charts one next to each other.

 

my script produces a trend chart and BoxPlot chart for ~10 parameters, somewhere in the middle of the report the two charts, for the same parameter, are not next to each other - as in the image below.

 

can someone suggest a way to lineup the charts?

 

my script below

 

 

 New Window( "XXX_Charts",
		Outline Box( "TrendCharts and TMM",
			H List Box(
				V List Box(
								lst = dtN << Bivariate(
								Y(:MEAN_VALUE),
								X(:RUN_DATE),
								SendToReport(
									0,
									Dispatch(
										{},
										"Bivar Plot",
										FrameBox,
										{Frame Size(524, 260), 
										Row Legend(
											CHAMBER,
											Color(1),
											Color Theme("JMP Default"),
											Marker(1),
											Marker Theme("Standard"),
											Continuous Scale(0),
											Reverse Scale(0),
											Excluded Rows(0)
										)}
									)
								),
								By(Column("ALIAS"))
								);

							lst<< Group By (:CHAMBER);
							lst<< Fit Spline( 0.1, Standardized);	
						),//end of V list
					V List Box(			
							lst = dtN << Oneway(
									Y( :MEAN_VALUE ),
									X( :CHAMBER ),
									By(Column("ALIAS")),
									Means and Std Dev( 0 ),
									Box Plots( 1 ),
									Mean Lines( 1 ),
									Mean Diamonds( 1 ),
									X Axis Proportional( 0 ),
									Points Jittered( 0 ),
									Grand Mean( 0 ),
									SendToReport(
									Dispatch(
										{},
										"Oneway Plot",
										FrameBox,
										{Frame Size( 510, 310 )}
									)
										)
											);// end of oneway
								
				)
			)
		);
	);

ian_jmp

'Help > Books > Scripting Guide' has a lot of information about the different display boxes, and you can generally get the layout you want fairly easily. In this case, does 'LineUpBox()' do it?

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

// A couple of not very useful 'template' reports for a parameter
ow1 = Expr(Oneway( Y( yTBD ), X( :SITE ) ));
ow2 = Expr(Oneway( Y( yTBD ), X( :lot_id ) ));

// Make a list of alll parameters
allParams = dt << getColumnNames("String");
RemoveFrom(allParams, {1, 2, 3, 4});

// Take ten parameters at random
myParams = allParams[RandomIndex(NItems(allParams), 10)];

// Use a 'LineUpBox()' with two columns (so one parameter in each row)
lub = LineUpBox(NCol(2));
for(p=1, p<=NItems(myParams), p++,
	plot1 = Substitute(NameExpr(ow1), Expr(yTBD), myParams[p]);
	plot2 = Substitute(NameExpr(ow2), Expr(yTBD), myParams[p]);
	lub << append(plot1);
	lub << append(plot2);	
);

// Make a window
nw = NewWindow("Two reports per Parameter", lub);