338907_de-DE

liliconcom

JSL fügt einen konstanten kategorialen Faktor DoE hinzu

Verwendung des DoE
Ich würde gerne konstante kategoriale Faktoren in einem JSL-Skript aufzeichnen, aber es scheint, dass nur konstante kontinuierliche Faktoren ordnungsgemäß gespeichert und geladen werden.
Während ich Zeichenfolgenwerte für einen konstanten Faktor eingeben kann, werden die Zeichenfolgenwerte beim Generieren des JSL-Skripts durch numerische Werte ersetzt.
Wenn ich beispielsweise die konstanten Faktoren „X1“ und „X2“ mit den Werten 99 bzw. „a_string“ eingebe, lautet das generierte Skript:

DOE(
 Custom Design,
 {
  Add Response( Maximize, "Y", ., ., . ), 
  Add Factor( Constant, 99, "X1" ),
  Add Factor( Constant, 1, "X2" ), 
  Set Random Seed( 1385290084 ),
  Simulate Responses( 0 ), 
  Save X Matrix( 0 )
 }
);

Dh mein String-Wert „a_string“ wurde durch 1 ersetzt.
Screenshot beigefügt.

Weiß jemand, wie ich einen konstanten kategorialen Faktor in ein JSL-Skript integrieren kann?

Automatisierung und SkripterstellungBetreff: JSL fügt einen konstanten kategorialen Faktor DoE hinzu

Da Sie JSL erwähnen, gehe ich davon aus, dass Sie bereits über „Hilfe > Skriptindex“ Bescheid wissen. Die Suche nach „doe“ liefert viele Informationen, meist mit Beispielen:

Und natürlich gibt es auch die umfangreichere Dokumentation.

Aber um es klarzustellen: Was ich angeboten habe, war eine Problemumgehung für einen scheinbaren Fehler. Bitte senden Sie daher eine E-Mail an support@jmp.com und weisen Sie sie auf diesen Thread hin. Auf diese Weise wird es behoben.

 

 

Betreff: JSL fügt einen konstanten kategorialen Faktor DoE hinzu

Danke!
Das ist hervorragend.
Haben Sie einen Link zu einer Dokumentation, in der ich möglicherweise herausgefunden habe, wie das geht?

Betreff: JSL fügt einen konstanten kategorialen Faktor DoE hinzu

Es ist etwas umständlich, aber das hier reicht aus (JMP 15 auf einem Mac):

NamesDefaultToHere(1);

// Make a factor table
dt =
New Table( "My Factors",
 Add Rows( 2 ),
 New Table Variable( "Table Type", "DOE Factor Table" ),
 New Column( "X1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Property( "Design Role", Design Role( Constant ) ),
  Set Property( "Factor Changes", Easy ),
  Set Values( [99, .] )
 ),
 New Column( "X2",
  Character,
  "Nominal",
  Set Property( "Design Role", Design Role( Constant ) ),
  Set Property( "Factor Changes", Easy ),
  Set Values( {"a_string_value", ""} )
 )
);

// Make a DOE object
myDOE = 
DOE(
 Custom Design,
 {
  Add Response( Maximize, "Y", ., ., . ), 
  Set Random Seed( 1385290084 ),
  Simulate Responses( 0 ), 
  Save X Matrix( 0 )
 }
);

// Load in the factors
myDOE << loadFactors(dt);

// Delete the factors
Close(dt, noSave);