338907_it-IT

liliconcom

JSL che aggiunge un fattore categorico costante DoE

Utilizzando il DoE
Vorrei registrare fattori categoriali costanti in uno script JSL, ma sembra che solo i fattori continui costanti vengano salvati e caricati correttamente.
Sebbene sia possibile inserire valori di stringa per un fattore costante, quando si genera lo script JSL i valori di stringa vengono sostituiti con numerici.
Ad esempio, se inserisco fattori costanti "X1" e "X2" rispettivamente con i valori 99 e "a_string", lo script generato è:

DOE(
 Custom Design,
 {
  Add Response( Maximize, "Y", ., ., . ), 
  Add Factor( Constant, 99, "X1" ),
  Add Factor( Constant, 1, "X2" ), 
  Set Random Seed( 1385290084 ),
  Simulate Responses( 0 ), 
  Save X Matrix( 0 )
 }
);

cioè il mio valore di stringa "a_string" è stato sostituito da 1.
Screenshot allegato.

Qualcuno sa come posso ottenere un fattore categorico costante in uno script JSL?

DOEOggetto: JSL aggiunta di un fattore categorico costante DoE

È un po 'tortuoso, ma questo lo fa (JMP 15 su un Mac):

NamesDefaultToHere(1);

// Make a factor table
dt =
New Table( "My Factors",
 Add Rows( 2 ),
 New Table Variable( "Table Type", "DOE Factor Table" ),
 New Column( "X1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Property( "Design Role", Design Role( Constant ) ),
  Set Property( "Factor Changes", Easy ),
  Set Values( [99, .] )
 ),
 New Column( "X2",
  Character,
  "Nominal",
  Set Property( "Design Role", Design Role( Constant ) ),
  Set Property( "Factor Changes", Easy ),
  Set Values( {"a_string_value", ""} )
 )
);

// Make a DOE object
myDOE = 
DOE(
 Custom Design,
 {
  Add Response( Maximize, "Y", ., ., . ), 
  Set Random Seed( 1385290084 ),
  Simulate Responses( 0 ), 
  Save X Matrix( 0 )
 }
);

// Load in the factors
myDOE << loadFactors(dt);

// Delete the factors
Close(dt, noSave);

Oggetto: JSL aggiunta di un fattore categorico costante DoE

Grazie!
È geniale.
Hai un collegamento alla documentazione che potrei aver scoperto come fare questo?

Oggetto: JSL aggiunta di un fattore categorico costante DoE

Dato che hai menzionato JSL, presumo che tu sappia già di "Aiuto> Indice scripting". La ricerca di "doe" fornisce molte informazioni, di solito con esempi:

E c'è anche la documentazione più ampia, ovviamente.

Ma, per essere chiari, quello che ho offerto era una soluzione alternativa a quello che sembra essere un bug. Quindi per favore invia un'e-mail a support@jmp.com e indirizzali a questo thread. In questo modo verrà risolto.