338749_ja-JP

liliconcom

カテゴリ別の概要データ表

やあ、

 

約5000行のデータがあります。

3 つの列 (グループ、スコア、カウント) があります。

グループの値: A、B

スコアの値の範囲は 0.5 ～ 1

Count の値は各行で 1 です。

 

 

以下の形式のように、グループ A と B ごとにデータを要約し、スコア値をいくつかのカテゴリにグループ化し、各スコア カテゴリの数を合計したいと思います。

 

 

このタスクを実行するための JSL スクリプトを作成する方法をコミュニティに求めています。

 

こちらにもデータを添付させていただきます。

 

 

ありがとう

 

 

 

 

 

自動化とスクリプト作成Re: カテゴリ別集計データ表

ジムとマイケルに感謝します。

Re: カテゴリ別集計データ表

これを行う方法がいくつかあります。ただし、以下の例は実際には主要な JMP 機能に基づいているだけであるため、ヘルプ プルダウン メニューにある JMP ドキュメント ライブラリの「JMP の発見」および「JMP の使用」ドキュメントを読むことを強くお勧めします。

Names Default To Here( 1 );
dt = Current Data Table();

dt << New Column( "Score Category",
 character,
 formula(
  If(
   :Score < .6, "0.50-0.59",
   :Score < .8, "0.60-0.79",
   :Score < .9, "0.80-0.89",
   "0.90-1.00",
  )
 )
);

dtSum = dt << Summary(
 Group( :Group, :Score Category ),
 Sum( :Count ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

dtSum << delete columns( :N Rows );
dtSum:Name( "Sum(Count)" ) << set name( "Total_Count" );


// or

dt:score << set property(
 "value labels",
 {0.5 <= "0.50-0.59" < 0.6, 0.6 <= "0.60-0.79" < 0.8, 0.8 <= "0.80-0.89" < 0.9, 0.9
  <= "0.90-1.00" <= 1}
);
 
dtSum = dt << Summary(
 Group( :Group, :Score ),
 Sum( :Count ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

dtSum << delete columns( :N Rows );
dtSum:Name( "Sum(Count)" ) << set name( "Total_Count" );

Re: カテゴリ別集計データ表

このためのスクリプトをキャプチャするには、対話型のアプローチを使用します。 まず、データテーブルから始めましょう。

Count は必要ないのでオフのままにしましたが、あっても問題ありません。

 

[スコア] 列を選択し、[列]、[ユーティリティ]、[ビニング式の作成] に移動しました。

 

そして、オフセットを 0.5 に、ビン幅を 0.1 に設定します。

新しい列 (スコアビン) を右クリックし、列のプロパティをコピーします。

 

次に、新しいスクリプト ウィンドウを開いて貼り付け (ctrl-V)、次の JSL が生成されます。

Add Column Properties(
 Value Labels(
  {-0.5 = "-0.5 — -0.4", -0.4 = "-0.4 — -0.3", -0.3 = "-0.3 — -0.2", -0.2 =
  "-0.2 — -0.1", -0.1 = "-0.1 — 0", 0 = "0 — 0.1", 0.1 = "0.1 — 0.2", 0.2 =
  "0.2 — 0.3", 0.3 = "0.3 — 0.4", 0.4 = "0.4 — 0.5", 0.5 = "0.5 — 0.6", 0.6 =
  "0.6 — 0.7", 0.7 = "0.7 — 0.8", 0.8 = "0.8 — 0.9", 0.9 = "0.9 — 1", 1 =
  "1 — 1.1", 1.1 = "1.1 — 1.2", 1.2 = "1.2 — 1.3", 1.3 = "1.3 — 1.4", 1.4 =
  "1.4 — 1.5", 1.5 = "1.5 — 1.6", 1.6 = "1.6 — 1.7", 1.7 = "1.7 — 1.8", 1.8 =
  "1.8 — 1.9", 1.9 = "1.9 — 2"}
 ),
 Use Value Labels( 1 ),
 Formula( 0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 ) )
)

ここで 2 つのことが重要です。0.5 未満 (説明には存在しません) または 1 より大きいスコアは気にしないので、必要に応じてプロパティを少し変更し、ラベル名を編集できます。 また、スコアがちょうど 1 であるエッジケースをキャプチャするための If ステートメントも追加しました。

Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

(ちなみに、0.599 は 0.5 から 0.59 の間としてラベル付けされるため、これらのラベルは技術的に正確ではありません)

 

このスニペットの周囲にコードをラップして再利用可能にします。現在のデータ テーブルを使用し、Score Binned という新しい列を追加し、その列に次のプロパティを追加します。

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

さて、表に戻ります。「表」>「概要」を選択すると、目的の場所に移動します。 Group と Score Binned を Group に配置します。実際に必要なのはこれだけです。

ここで、必要なのは N 行です。名前が間違っているだけです。左側の「Source」という単語をダブルクリックしてテーブル作成スクリプトをコピーし、名前付きのテーブル参照を作業テーブルである「dt」に置き換えて、変数「summ」で新しいテーブルをキャッチしましょう。

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

最後に、必要に応じて N Rows の名前を「Total_Count」に変更します。

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

summ:"N Rows"n << Set Name("Total_Count");

ここで、サマリー テーブルを閉じ、ソース テーブルから Score Binned 列を削除し、スクリプトをテストします。

最終的な JSL をもう一度:

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

summ:"N Rows"n << Set Name("Total_Count");

添付されたデータでテストしました。文字通り今気づきました:flushed_face: