338749_ja-JP

liliconcom

カテゴリ別の要約データテーブル

こんにちは、

 

約5000行のデータがあります。

3つの列（グループ、スコア、カウント）があります

グループの値：A、B

0.5〜1の範囲のスコアの値

Countの値は、各行で1です。

 

 

グループAとBでデータを要約し、スコア値をいくつかのカテゴリにグループ化してから、以下の形式のように、各スコアカテゴリのカウントを合計したいと思います。

 

 

このタスクを実行するためのJSLスクリプトを作成する方法について、コミュニティからの支援を求めていますか？

 

ここにもデータを添付します。

 

 

ありがとう

 

 

 

 

 

スクリプティングRe：カテゴリ別の要約データテーブル

このためのスクリプトをキャプチャするには、インタラクティブなアプローチを使用します。 まず、データテーブルから始めましょう。

カウントは必要ないのでオフにしましたが、そこにあれば問題はありません。

 

[スコア]列を選択し、[列]、[ユーティリティ]、[ビニング式の作成]に移動しました。

 

そして、オフセットを0.5に設定し、ビンの幅を0.1に設定します。

新しい列（スコアビン）を右クリックし、列のプロパティをコピーします。

 

次に、新しいスクリプトウィンドウを開いて貼り付け（ctrl-V）すると、次のJSLが作成されます。

Add Column Properties(
 Value Labels(
  {-0.5 = "-0.5 — -0.4", -0.4 = "-0.4 — -0.3", -0.3 = "-0.3 — -0.2", -0.2 =
  "-0.2 — -0.1", -0.1 = "-0.1 — 0", 0 = "0 — 0.1", 0.1 = "0.1 — 0.2", 0.2 =
  "0.2 — 0.3", 0.3 = "0.3 — 0.4", 0.4 = "0.4 — 0.5", 0.5 = "0.5 — 0.6", 0.6 =
  "0.6 — 0.7", 0.7 = "0.7 — 0.8", 0.8 = "0.8 — 0.9", 0.9 = "0.9 — 1", 1 =
  "1 — 1.1", 1.1 = "1.1 — 1.2", 1.2 = "1.2 — 1.3", 1.3 = "1.3 — 1.4", 1.4 =
  "1.4 — 1.5", 1.5 = "1.5 — 1.6", 1.6 = "1.6 — 1.7", 1.7 = "1.7 — 1.8", 1.8 =
  "1.8 — 1.9", 1.9 = "1.9 — 2"}
 ),
 Use Value Labels( 1 ),
 Formula( 0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 ) )
)

ここで2つのこと：0.5未満（説明には存在しない）または1より大きいスコアは気にしないので、プロパティを少し変更して、ラベル名を編集して必要なものに一致させることができます。 スコアが正確に1であるエッジケースをキャプチャするためのIfステートメントも追加しました

Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

（ところで、0.599は0.5から0.59の間のラベルが付けられるため、これらのラベルは技術的に正確ではありません）

 

このスニペットをコードでラップして再利用できるようにすることができます。ここでは、現在のデータテーブルを使用し、Score Binnedという新しい列を追加して、次のプロパティをその列に追加します。

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

ここで、テーブルに戻ります。[テーブル]> [概要]を使用すると、目的の場所に移動できます。 GroupとScoreBinnedをGroupに入れ、実際に必要なのはそれだけです。

さて、N行が必要です。名前が間違っているので、左側の「ソース」という単語をダブルクリックして、テーブル作成スクリプトをコピーし、名前付きテーブル参照を作業テーブルである「dt」に置き換えて、キャッチします。変数「summ」の新しいテーブル：

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

最後に、必要に応じてN行の名前を「Total_Count」に変更します。

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

summ:"N Rows"n << Set Name("Total_Count");

次に、サマリーテーブルを閉じ、ソーステーブルからScore Binned列を削除して、スクリプトをテストします。

再び最終JSL：

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

summ:"N Rows"n << Set Name("Total_Count");

私が文字通り気づいた添付データでテストしました:flushed_face:

 

Re：カテゴリ別の要約データテーブル

これを行うには、いくつかの方法があります。ただし、以下の例は実際には主要なJMP機能に基づいているため、[ヘルプ]プルダウンメニューから入手できる[JMPドキュメントライブラリの検出]および[JMPドキュメントの使用]を読むことを強くお勧めします。

Names Default To Here( 1 );
dt = Current Data Table();

dt << New Column( "Score Category",
 character,
 formula(
  If(
   :Score < .6, "0.50-0.59",
   :Score < .8, "0.60-0.79",
   :Score < .9, "0.80-0.89",
   "0.90-1.00",
  )
 )
);

dtSum = dt << Summary(
 Group( :Group, :Score Category ),
 Sum( :Count ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

dtSum << delete columns( :N Rows );
dtSum:Name( "Sum(Count)" ) << set name( "Total_Count" );


// or

dt:score << set property(
 "value labels",
 {0.5 <= "0.50-0.59" < 0.6, 0.6 <= "0.60-0.79" < 0.8, 0.8 <= "0.80-0.89" < 0.9, 0.9
  <= "0.90-1.00" <= 1}
);
 
dtSum = dt << Summary(
 Group( :Group, :Score ),
 Sum( :Count ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

dtSum << delete columns( :N Rows );
dtSum:Name( "Sum(Count)" ) << set name( "Total_Count" );

Re：カテゴリ別の要約データテーブル

ジムとマイケルに感謝します。