338749_es-ES

liliconcom

Tabla de datos resumidos por categoría

Hola,

 

Tengo datos con alrededor de 5000 filas.

Hay tres columnas (grupo, puntuación y recuento)

Valor para el grupo: A, B

Valor de la puntuación que varía de 0,5 a 1

El valor de Count es 1 para cada fila.

 

 

Me gustaría resumir los datos por grupo A y B y agrupar el valor de Puntaje en pocas categorías y luego sumar el recuento para cada categoría de puntaje, como se muestra a continuación.

 

 

Estoy buscando ayuda de la comunidad sobre cómo crear un script JSL para realizar esta tarea.

 

Adjunto datos aquí también.

 

 

Gracias

 

 

 

 

 

ScriptingRe: Tabla de datos resumidos por categoría

Usaría un enfoque interactivo para capturar un script para esto. Primero, comencemos con la tabla de datos:

Dejé a Count apagado porque no lo necesitaremos, pero no dolerá si está allí.

 

Seleccioné la columna Score, luego navegué a Cols, Utilities, Make Binning Formula:

 

Y establezca Offset en 0.5 y el ancho de bin en 0.1:

Haga clic con el botón derecho en la nueva columna (puntuación agrupada) y copie las propiedades de la columna:

 

Luego abra una nueva ventana de script y pegue (ctrl-V), lo que da como resultado este JSL:

Add Column Properties(
 Value Labels(
  {-0.5 = "-0.5 — -0.4", -0.4 = "-0.4 — -0.3", -0.3 = "-0.3 — -0.2", -0.2 =
  "-0.2 — -0.1", -0.1 = "-0.1 — 0", 0 = "0 — 0.1", 0.1 = "0.1 — 0.2", 0.2 =
  "0.2 — 0.3", 0.3 = "0.3 — 0.4", 0.4 = "0.4 — 0.5", 0.5 = "0.5 — 0.6", 0.6 =
  "0.6 — 0.7", 0.7 = "0.7 — 0.8", 0.8 = "0.8 — 0.9", 0.9 = "0.9 — 1", 1 =
  "1 — 1.1", 1.1 = "1.1 — 1.2", 1.2 = "1.2 — 1.3", 1.3 = "1.3 — 1.4", 1.4 =
  "1.4 — 1.5", 1.5 = "1.5 — 1.6", 1.6 = "1.6 — 1.7", 1.7 = "1.7 — 1.8", 1.8 =
  "1.8 — 1.9", 1.9 = "1.9 — 2"}
 ),
 Use Value Labels( 1 ),
 Formula( 0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 ) )
)

Aquí dos cosas: no nos importa ningún puntaje menor a 0.5 (no existen en su descripción) o mayor que 1, por lo que podemos cambiar un poco las propiedades y editar los nombres de las etiquetas para que coincidan con lo que desea. También agregué una declaración If para capturar el caso límite donde una puntuación es exactamente 1

Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

(Por cierto, esas etiquetas no son técnicamente precisas, ya que 0.599 se etiquetaría como entre 0.5 y 0.59)

 

Podemos envolver un código alrededor de este fragmento para hacerlo reutilizable, donde usamos la tabla de datos actual, agregamos una nueva columna llamada Score Binned y agregamos estas propiedades a esa columna:

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

Ahora, de vuelta en nuestra mesa, Tablas> Resumen nos lleva a donde queremos ir. Ponemos Grupo y Clasificación de puntuación en Grupo, y eso es todo lo que realmente necesitamos:

Ahora, N filas es lo que queremos, simplemente tiene un nombre incorrecto, así que hagamos doble clic en la palabra "Fuente" a la izquierda y copiemos el script de creación de la tabla y reemplacemos la referencia de la tabla nombrada con "dt", nuestra tabla de trabajo, y captura la nueva tabla en la variable "summ":

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

Finalmente, cambie el nombre de N filas a "Total_Count" como desee:

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

summ:"N Rows"n << Set Name("Total_Count");

Ahora, cierre la tabla de resumen, elimine la columna Score Binned de la tabla de origen y pruebe el script:

JSL final de nuevo:

dt = Current Data Table();

dt << New Column("Score Binned", Character);

dt:"Score Binned"n << Add Column Properties(
 Value Labels(
  {0.5 = "0.5 — 0.59", 0.6 = "0.6 — 0.69", 0.7 = "0.7 — 0.79", 0.8 = "0.8 — 0.89", 0.9 =
  "0.9 — 1"}
 ),
 Use Value Labels( 1 ),
 Formula(
  If(
   (0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )) == 1, 0.9,
   0.5 + 0.1 * Floor( (:Score - 0.5) / 0.1 )
  )
 )
);

summ = dt << Summary(
 Group( :Group, :Score Binned ),
 Freq( "None" ),
 Weight( "None" )
);

summ:"N Rows"n << Set Name("Total_Count");

Probado en sus datos adjuntos, que literalmente acabo de notar:flushed_face:

 

Re: Tabla de datos resumidos por categoría

Aquí hay un par de formas de hacer esto.Pero dado que el ejemplo siguiente se basa realmente en la funcionalidad principal de JMP, le sugiero encarecidamente que lea los documentos Descubriendo JMP y Uso de JMP de la Biblioteca de documentación de JMP, disponible en el menú desplegable Ayuda.

Names Default To Here( 1 );
dt = Current Data Table();

dt << New Column( "Score Category",
 character,
 formula(
  If(
   :Score < .6, "0.50-0.59",
   :Score < .8, "0.60-0.79",
   :Score < .9, "0.80-0.89",
   "0.90-1.00",
  )
 )
);

dtSum = dt << Summary(
 Group( :Group, :Score Category ),
 Sum( :Count ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

dtSum << delete columns( :N Rows );
dtSum:Name( "Sum(Count)" ) << set name( "Total_Count" );


// or

dt:score << set property(
 "value labels",
 {0.5 <= "0.50-0.59" < 0.6, 0.6 <= "0.60-0.79" < 0.8, 0.8 <= "0.80-0.89" < 0.9, 0.9
  <= "0.90-1.00" <= 1}
);
 
dtSum = dt << Summary(
 Group( :Group, :Score ),
 Sum( :Count ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

dtSum << delete columns( :N Rows );
dtSum:Name( "Sum(Count)" ) << set name( "Total_Count" );

Re: Tabla de datos resumidos por categoría

Gracias Jim y Michael.