335794_zh-TW

liliconcom

如何找到隨機間隔的樣本平均值？

我有一個存儲臨時值的csv文件。 我必鬚根據以下步驟找到某些樣本集的組平均值：

1.使所有小於25的溫度值等於零，即post_process

2. group_avg列是通過忽略大於或等於4個連續零的行而得出的。 接下來計算樣本組的平均值，如下所示

3. final_average列是從group_avg列生成的結果

 

我們如何使用jsl編寫此過程的腳本？

附加csv文件

最終結果是最終的_average如下表所示：

 

數據表腳本編寫回复：如何找到隨機間隔的樣本平均值？

這是一個僅使用TEMP列創建數據表的腳本，然後創建其餘列，並使用公式填充它們。

Names Default To Here( 1 );
dt = New Table( "temp_temp",
 Add Rows( 54 ),
 New Column( "TEMP",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [23.23019577, 23.44946668, 23.56111955, 23.47601143, 23.36428639,
   23.24016499, 32.42091411, 23, 32.26821731, 32.14990084, 32.42091411,
   32.26821731, 32.14990084, 23.23019577, 23.44946668, 23.56111955,
   23.47601143, 23.36428639, 23.24016499, 32.15353181, 32.16785998, 21,
   32.502366, 32.16261133, 32.15757688, 32.16790474, 23.23019577,
   23.44946668, 23.56111955, 23.47601143, 23.36428639, 23.24016499,
   32.42091411, 10, 32.26821731, 32.14990084, 32.41334166, 32.17456755,
   32.52383338, 32.17310331, 19.28571429, 19.28571429, 19.28571429,
   19.28571429, 34.62948075, 34.28766971, 34.29470736, 34.61532486,
   34.386807, 34.36554216, 34.58410721, 34.28726312, 23.57142857,
   23.57142857]
  )
 )
);

dt << New Column( "post process", formula( If( :TEMP <= 25, 0, :TEMP ) ) );
dt:post process << delete formula;

dt << New Column( "group_avg",
 formula(
  value = .;
  If( Row() == 1,
   flag = 0;
   zeroCounter = 0;
  );
  If( flag == 0 & :post process > 0,
   flag = 1;
   captureMatrix = [];
   Show( "start", Row(), flag );
  );
  If( :post process == 0 & flag == 1,
   zeroCounter
   ++);
  If( flag == 1,
   captureMatrix = captureMatrix || Matrix( :post process );
   Show( "cap", Row(), captureMatrix );
   If( zeroCounter == 4 | Row() == N Rows( dt ),
    For( i = N Cols( captureMatrix ), i >= 1, i--,
     If( captureMatrix[i] != 0,
      Break(),
      captureMatrix[i] = .
     )
    );
    value = Mean( captureMatrix );
    Show( value );
    Show( Row(), captureMatrix, zeroCounter, Index( 1, N Cols( captureMatrix ) - (zeroCounter - 1) ) );
    flag = 0;
    zeroCounter = 0;
    Show( flag );
    captureMatrix = [];
   );
  );
  value;
 )
);

dt << new column("final Avg",
 formula(
  if(row()==1,
   theRows = current data table() << get rows where(isMissing(:group_avg)==0);
  );
  If(row()<= nrows(theRows),
   value=:group_avg[theRows[Row()]],
   value=.
  )
 )
);

回复：如何找到隨機間隔的樣本平均值？

該腳本適用於小型文件。 但是，在大型文件中，我們有16000個零而不是4個JMP會停止響應。 有什麼辦法可以防止這種情況並且在不掛起的情況下運行腳本？

回复：如何找到隨機間隔的樣本平均值？

我懷疑問題是由於錯誤，我在代碼中留下了幾個“ Show（）”語句，這迫使對JMP日誌進行大量寫入。

以下是“後期處理”列規範，這是我認為存在使JMP掛起的問題的部分。嘗試運行它，看看它是否可以不掛起運行

dt << New Column( "group_avg",
 formula(
  value = .;
  If( Row() == 1,
   flag = 0;
   zeroCounter = 0;
  );
  If( flag == 0 & :post process > 0,
   flag = 1;
   captureMatrix = [];
  );
  If( :post process == 0 & flag == 1,
   zeroCounter
   ++);
  If( flag == 1,
   captureMatrix = captureMatrix || Matrix( :post process );
   If( zeroCounter == 4 | Row() == N Rows( dt ),
    /*For( i = N Cols( captureMatrix ), i >= 1, i--,
     If( captureMatrix[i] != 0,
      Break(),
      captureMatrix[i] = .
     )
    );*/
    if( Row() == N Rows( dt ), zerocounter++ );
    value = Mean( captureMatrix[ 1:: ncols(captureMatrix) - (zeroCounter - 1)] );
    flag = 0;
    zeroCounter = 0;
    captureMatrix = [];
   );
  );
  value;
 )
);

回复：如何找到隨機間隔的樣本平均值？

第一個腳本給出了正確的答案，但是兩個腳本的輸出都不相同，為什麼還要註釋部分代碼

回复：如何找到隨機間隔的樣本平均值？

該代碼的第二個版本效率更高。 考慮到您正在運行的數據量，我認為這會有所幫助。它應該提供相同的結果。如果沒有，您可以嘗試從代碼的第一個版本中刪除所有Show（）語句，如果可行。