331700_ja-JP

liliconcom

異なるスクリプトで複数のグラフをエクスポートする

Jmpユーザーの皆さん、

 

Jmpで複数のグラフをエクスポートしようとしています。 対応するスクリプトを選択して、すべてのグラフを一緒にエクスポートする方法はありますか？

 

どうもありがとう ！

 

私

データ表グラフィックススクリプティングRe：異なるスクリプトで複数のグラフをエクスポートする

これは、BigClassからWorddocに3つのグラフィカル出力をエクスポートする例です。

dt = open("$sample_data\Big Class.jmp");

dist = expr(dt << Distribution(
 Continuous Distribution( Column( :weight ) ),
 Nominal Distribution( Column( :age ) )
));

gb1 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :sex ) ),
 Elements( Heatmap( X, Y, Legend( 2 ) ) )
));

gb2 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
));

nw = new window("Example Export Multiple Platforms",
 chart_output = vlistbox(
  dist,
  page break box(),
  gb1,
  page break box(),
  gb2
 );
);

chart_output << save msword("c:\temp\SampleCharts.doc", Native);

Re：異なるスクリプトで複数のグラフをエクスポートする

こんにちは@JMPdiscoverer 、

 

私はと同様の解決策を考え出していました@pmroz 、そして私は彼らがしたことを好きです。

 

これが私が考えていたものですが、Word文書などを作成するほど良くはありません。PPTファイルに直接保存することもできます。 便利なようにJSLでレポートを作成しましたが、forループは、既に開いている場合は機能します。 ただし、レポートを生成するスクリプトを作成する場合は、ウィンドウのリストを見つける代わりに、変数名でレポートを参照するだけで済みます。

 

Names Default To Here( 1 );

dt = open("$sample_data\Big Class.jmp");

rpt1 = dt << Bivariate( Y( :weight ), X( :height ) );
rpt2 = dt << Oneway( Y( :height ), X( :age ), X Axis Proportional( 0 ) );
rpt3 = dt << Fit Group(
 Oneway( Y( :weight ), X( :age ), X Axis Proportional( 0 ) ),
 Bivariate( Y( :weight ), X( :height ) ),
 <<{Arrange in Rows( 2 )}
);


reportlist = {};
For( i = 0, i <= N Items( Window() ), i++,
 If(
  !Is Missing( Regex( Window( i ) << getwindow title, "Fit" ) ) == 1 | !Is Missing(
   Regex( Window( i ) << getwindow title, "Oneway" )
  ) == 1 | !Is Missing( Regex( Window( i ) << getwindow title, "Bivariate" ) ) == 1,
  Insert Into( reportlist, Window( i ) << get window title )
 )
);


For( i = 1, i <= N Items( reportlist ), i++,
 picbox = Window( reportlist[i] ) << getPicture;
 picbox << SaveImage(
  "whatever your local directory to save is\pic" || Char( i ) || ".png"
 );
);

これらはあなたがあなたの方法でうまく働くようになるはずです。

 

幸運を！、

DS