331700_zh-CN

liliconcom

使用不同的脚本导出多个图

嘿Jmp用户，

 

我正在尝试在Jmp中导出多个图。 无论如何，有没有选择相应的脚本并将所有图形一起导出。

 

非常感谢 ！

 

一世

数据表图形脚本编写回复：使用不同的脚本导出多个图

这是一个将Big Class的三个图形输出导出到word doc的示例。

dt = open("$sample_data\Big Class.jmp");

dist = expr(dt << Distribution(
 Continuous Distribution( Column( :weight ) ),
 Nominal Distribution( Column( :age ) )
));

gb1 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :sex ) ),
 Elements( Heatmap( X, Y, Legend( 2 ) ) )
));

gb2 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
));

nw = new window("Example Export Multiple Platforms",
 chart_output = vlistbox(
  dist,
  page break box(),
  gb1,
  page break box(),
  gb2
 );
);

chart_output << save msword("c:\temp\SampleCharts.doc", Native);

回复：使用不同的脚本导出多个图

你好@JMPdiscoverer ，

 

我想出了一个类似的解决方案@pmroz ，我喜欢他们的所作所为。

 

这就是我的想法，但不如制作Word文档等好。您也可以将它们直接保存到PPT文件中。 我在JSL中创建报表只是为了方便使用，但是如果您已经打开它们，则for循环可以使用。 但是，如果您编写了一个生成报告的脚本，则只需按变量名引用该报告，而不用查找窗口列表。

 

Names Default To Here( 1 );

dt = open("$sample_data\Big Class.jmp");

rpt1 = dt << Bivariate( Y( :weight ), X( :height ) );
rpt2 = dt << Oneway( Y( :height ), X( :age ), X Axis Proportional( 0 ) );
rpt3 = dt << Fit Group(
 Oneway( Y( :weight ), X( :age ), X Axis Proportional( 0 ) ),
 Bivariate( Y( :weight ), X( :height ) ),
 <<{Arrange in Rows( 2 )}
);


reportlist = {};
For( i = 0, i <= N Items( Window() ), i++,
 If(
  !Is Missing( Regex( Window( i ) << getwindow title, "Fit" ) ) == 1 | !Is Missing(
   Regex( Window( i ) << getwindow title, "Oneway" )
  ) == 1 | !Is Missing( Regex( Window( i ) << getwindow title, "Bivariate" ) ) == 1,
  Insert Into( reportlist, Window( i ) << get window title )
 )
);


For( i = 1, i <= N Items( reportlist ), i++,
 picbox = Window( reportlist[i] ) << getPicture;
 picbox << SaveImage(
  "whatever your local directory to save is\pic" || Char( i ) || ".png"
 );
);

这些应该使您的工作顺利进行。

 

祝好运！，

DS