331700_ko-KR

liliconcom

다른 스크립트로 여러 그래프 내보내기

Jmp 사용자 여러분,

 

Jmp에서 여러 그래프를 내보내려고합니다. 어쨌든 해당 스크립트를 선택하고 모든 그래프를 함께 내보낼 수 있습니까?

 

고마워요!

 

나는

데이터 테이블제도법스크립팅Re : 다른 스크립트로 여러 그래프 내보내기

다음은 Big Class에서 3 개의 그래픽 출력을 워드 문서로 내보내는 예입니다.

dt = open("$sample_data\Big Class.jmp");

dist = expr(dt << Distribution(
 Continuous Distribution( Column( :weight ) ),
 Nominal Distribution( Column( :age ) )
));

gb1 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :sex ) ),
 Elements( Heatmap( X, Y, Legend( 2 ) ) )
));

gb2 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
));

nw = new window("Example Export Multiple Platforms",
 chart_output = vlistbox(
  dist,
  page break box(),
  gb1,
  page break box(),
  gb2
 );
);

chart_output << save msword("c:\temp\SampleCharts.doc", Native);

Re : 다른 스크립트로 여러 그래프 내보내기

안녕하세요 뿡 빵뀨 ,

 

나는 비슷한 해결책을 생각해 냈습니다. @pmroz , 그리고 나는 그들이 한 일을 좋아합니다.

 

여기 제가 생각했던 것이지만 워드 문서 등을 만드는 것만 큼 좋지는 않습니다. PPT 파일에 직접 저장할 수도 있습니다. JSL에서 보고서를 작성하여 편리하게 사용할 수 있지만 이미 열려있는 경우 for 루프가 작동 할 수 있습니다. 그러나 보고서를 생성하는 스크립트를 작성하는 경우 창 목록을 찾는 대신 변수 이름으로 보고서를 참조 할 수 있습니다.

 

Names Default To Here( 1 );

dt = open("$sample_data\Big Class.jmp");

rpt1 = dt << Bivariate( Y( :weight ), X( :height ) );
rpt2 = dt << Oneway( Y( :height ), X( :age ), X Axis Proportional( 0 ) );
rpt3 = dt << Fit Group(
 Oneway( Y( :weight ), X( :age ), X Axis Proportional( 0 ) ),
 Bivariate( Y( :weight ), X( :height ) ),
 <<{Arrange in Rows( 2 )}
);


reportlist = {};
For( i = 0, i <= N Items( Window() ), i++,
 If(
  !Is Missing( Regex( Window( i ) << getwindow title, "Fit" ) ) == 1 | !Is Missing(
   Regex( Window( i ) << getwindow title, "Oneway" )
  ) == 1 | !Is Missing( Regex( Window( i ) << getwindow title, "Bivariate" ) ) == 1,
  Insert Into( reportlist, Window( i ) << get window title )
 )
);


For( i = 1, i <= N Items( reportlist ), i++,
 picbox = Window( reportlist[i] ) << getPicture;
 picbox << SaveImage(
  "whatever your local directory to save is\pic" || Char( i ) || ".png"
 );
);

이것들은 당신이 당신의 길에서 잘 일하게 할 것입니다.

 

행운을 빕니다!,

DS