331700_fr-FR

liliconcom

Exportation de plusieurs graphiques avec différents scripts

Salut les utilisateurs de Jmp,

 

J'essaye d'exporter plusieurs graphiques dans Jmp. Y a-t-il quand même pour sélectionner les scripts correspondants et exporter tous les graphiques ensemble.

 

Merci beaucoup !

 

je

Tableau de donnéesGraphiqueScriptingRe: Exporter plusieurs graphiques avec différents scripts

Voici un exemple qui exporte trois sorties graphiques de Big Class vers un document Word.

dt = open("$sample_data\Big Class.jmp");

dist = expr(dt << Distribution(
 Continuous Distribution( Column( :weight ) ),
 Nominal Distribution( Column( :age ) )
));

gb1 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :sex ) ),
 Elements( Heatmap( X, Y, Legend( 2 ) ) )
));

gb2 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
));

nw = new window("Example Export Multiple Platforms",
 chart_output = vlistbox(
  dist,
  page break box(),
  gb1,
  page break box(),
  gb2
 );
);

chart_output << save msword("c:\temp\SampleCharts.doc", Native);

Re: Exporter plusieurs graphiques avec différents scripts

salut @JMPdiscoverer ,

 

Je proposais une solution similaire pour @pmroz , et j'aime ce qu'ils ont fait.

 

Voici ce que je pensais, mais pas aussi agréable que de créer un document Word, etc. Vous pouvez également les enregistrer directement dans des fichiers PPT. J'ai créé les rapports dans le JSL juste pour les avoir sous la main, mais les boucles for peuvent fonctionner si vous les avez déjà ouvertes. Mais, si vous écrivez un script qui génère les rapports, vous pouvez simplement référencer le rapport par nom de variable au lieu de rechercher une liste de fenêtres.

 

Names Default To Here( 1 );

dt = open("$sample_data\Big Class.jmp");

rpt1 = dt << Bivariate( Y( :weight ), X( :height ) );
rpt2 = dt << Oneway( Y( :height ), X( :age ), X Axis Proportional( 0 ) );
rpt3 = dt << Fit Group(
 Oneway( Y( :weight ), X( :age ), X Axis Proportional( 0 ) ),
 Bivariate( Y( :weight ), X( :height ) ),
 <<{Arrange in Rows( 2 )}
);


reportlist = {};
For( i = 0, i <= N Items( Window() ), i++,
 If(
  !Is Missing( Regex( Window( i ) << getwindow title, "Fit" ) ) == 1 | !Is Missing(
   Regex( Window( i ) << getwindow title, "Oneway" )
  ) == 1 | !Is Missing( Regex( Window( i ) << getwindow title, "Bivariate" ) ) == 1,
  Insert Into( reportlist, Window( i ) << get window title )
 )
);


For( i = 1, i <= N Items( reportlist ), i++,
 picbox = Window( reportlist[i] ) << getPicture;
 picbox << SaveImage(
  "whatever your local directory to save is\pic" || Char( i ) || ".png"
 );
);

Celles-ci devraient vous permettre de bien travailler sur votre chemin.

 

Bonne chance!,

DS