331700_it-IT

liliconcom

Esportazione di più grafici con diversi script

Ehi utenti di Jmp,

 

Sto cercando di esportare più grafici in Jmp. C'è comunque da selezionare gli script corrispondenti ed esportare tutti i grafici insieme.

 

Molte grazie !

 

io

Tabella datiGraficaScriptingRi: Esportazione di più grafici con diversi script

Ecco un esempio che esporta tre output grafici da Big Class a un documento word.

dt = open("$sample_data\Big Class.jmp");

dist = expr(dt << Distribution(
 Continuous Distribution( Column( :weight ) ),
 Nominal Distribution( Column( :age ) )
));

gb1 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :sex ) ),
 Elements( Heatmap( X, Y, Legend( 2 ) ) )
));

gb2 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
));

nw = new window("Example Export Multiple Platforms",
 chart_output = vlistbox(
  dist,
  page break box(),
  gb1,
  page break box(),
  gb2
 );
);

chart_output << save msword("c:\temp\SampleCharts.doc", Native);

Ri: Esportazione di più grafici con diversi script

Ciao @JMPdiscoverer ,

 

Stavo cercando una soluzione simile a @pmroz e mi piace quello che hanno fatto.

 

Ecco cosa stavo pensando, ma non così bello come creare un documento Word, ecc. Puoi anche salvarli direttamente in file PPT. Ho creato i report nel JSL solo per averli a portata di mano, ma i cicli for possono funzionare se li hai già aperti. Tuttavia, se scrivi uno script che genera i rapporti, puoi semplicemente fare riferimento al rapporto in base al nome della variabile invece di trovare un elenco di finestre.

 

Names Default To Here( 1 );

dt = open("$sample_data\Big Class.jmp");

rpt1 = dt << Bivariate( Y( :weight ), X( :height ) );
rpt2 = dt << Oneway( Y( :height ), X( :age ), X Axis Proportional( 0 ) );
rpt3 = dt << Fit Group(
 Oneway( Y( :weight ), X( :age ), X Axis Proportional( 0 ) ),
 Bivariate( Y( :weight ), X( :height ) ),
 <<{Arrange in Rows( 2 )}
);


reportlist = {};
For( i = 0, i <= N Items( Window() ), i++,
 If(
  !Is Missing( Regex( Window( i ) << getwindow title, "Fit" ) ) == 1 | !Is Missing(
   Regex( Window( i ) << getwindow title, "Oneway" )
  ) == 1 | !Is Missing( Regex( Window( i ) << getwindow title, "Bivariate" ) ) == 1,
  Insert Into( reportlist, Window( i ) << get window title )
 )
);


For( i = 1, i <= N Items( reportlist ), i++,
 picbox = Window( reportlist[i] ) << getPicture;
 picbox << SaveImage(
  "whatever your local directory to save is\pic" || Char( i ) || ".png"
 );
);

Questi dovrebbero farti lavorare bene sulla tua strada.

 

In bocca al lupo!,

DS