331700_es-ES

liliconcom

Exportación de múltiples gráficos con diferentes scripts

Hola usuarios de Jmp:

 

Estoy tratando de exportar varios gráficos en Jmp. ¿Hay alguna forma de seleccionar los scripts correspondientes y exportar todos los gráficos juntos?

 

Muchas gracias !

 

yo

Tabla de datosGráficosScriptingRe: exportar múltiples gráficos con diferentes scripts

Aquí hay un ejemplo que exporta tres salidas gráficas de Big Class a un documento de Word.

dt = open("$sample_data\Big Class.jmp");

dist = expr(dt << Distribution(
 Continuous Distribution( Column( :weight ) ),
 Nominal Distribution( Column( :age ) )
));

gb1 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :sex ) ),
 Elements( Heatmap( X, Y, Legend( 2 ) ) )
));

gb2 = expr(dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
));

nw = new window("Example Export Multiple Platforms",
 chart_output = vlistbox(
  dist,
  page break box(),
  gb1,
  page break box(),
  gb2
 );
);

chart_output << save msword("c:\temp\SampleCharts.doc", Native);

Re: exportar múltiples gráficos con diferentes scripts

Hola @JMPdiscoverer ,

 

Se me ocurrió una solución similar a @pmroz , y me gusta lo que hicieron.

 

Esto es lo que estaba pensando, pero no tan agradable como hacer un documento de Word, etc. También puede guardarlos directamente en archivos PPT. Creé los informes en JSL solo para tenerlos a mano, pero los bucles for pueden funcionar si ya los tiene abiertos. Pero, si escribe una secuencia de comandos que genera los informes, puede simplemente hacer referencia al informe por nombre de variable en lugar de buscar una lista de ventanas.

 

Names Default To Here( 1 );

dt = open("$sample_data\Big Class.jmp");

rpt1 = dt << Bivariate( Y( :weight ), X( :height ) );
rpt2 = dt << Oneway( Y( :height ), X( :age ), X Axis Proportional( 0 ) );
rpt3 = dt << Fit Group(
 Oneway( Y( :weight ), X( :age ), X Axis Proportional( 0 ) ),
 Bivariate( Y( :weight ), X( :height ) ),
 <<{Arrange in Rows( 2 )}
);


reportlist = {};
For( i = 0, i <= N Items( Window() ), i++,
 If(
  !Is Missing( Regex( Window( i ) << getwindow title, "Fit" ) ) == 1 | !Is Missing(
   Regex( Window( i ) << getwindow title, "Oneway" )
  ) == 1 | !Is Missing( Regex( Window( i ) << getwindow title, "Bivariate" ) ) == 1,
  Insert Into( reportlist, Window( i ) << get window title )
 )
);


For( i = 1, i <= N Items( reportlist ), i++,
 picbox = Window( reportlist[i] ) << getPicture;
 picbox << SaveImage(
  "whatever your local directory to save is\pic" || Char( i ) || ".png"
 );
);

Estos deberían ayudarlo a trabajar bien en su camino.

 

¡Buena suerte!,

DS