331438_zh-TW

liliconcom

如何為報告中的圖表製作內容？

你好，

我的報告視窗中有很多由圖形生成器創建的圖形。 我喜歡有一個包含圖表內容的窗口，當我單擊它們時，它可以向我顯示已識別的圖表。

我找不到任何類似問題的解決方案。 如果有人能幫助我，我將不勝感激。

謝謝

內容組織大規模客製化回覆：如何為報告中的圖表製作內容？

您所要做的就是在所有圖形周圍包裝一個額外的顯示對象，然後刪除該對象而不是平台對象。請參閱下面的範例：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw2 = New Window( "Graphs",
 hlb = H List Box(
  V List Box(
 
   Button Box( "Graph 1",
    Try( gb << delete );
    hlb << append(
     gb = V List Box(
      Graph Builder(
       Size( 528, 456 ),
       Show Control Panel( 0 ),
       Variables( X( :weight ), Y( :height ) ),
       Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
      ),
      Graph Builder(
       Size( 528, 456 ),
       Show Control Panel( 0 ),
       Variables( X( :age ), Y( :height ) ),
       Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
      )
     )
    );
   ),
   Button Box( "Graph 2",
    Try( gb << delete );
    hlb << append(
     gb = V List Box(
      Graph Builder(
       Size( 528, 456 ),
       Show Control Panel( 0 ),
       Variables( Y( :weight ), X( :sex ) ),
       Elements( Points( X, Y, Legend( 6 ) ) )
      )
     )
    );
   )
  )
 )
);

我強烈建議您花時間閱讀腳本指南。

回覆：如何為報告中的圖表製作內容？嗨吉姆
如果我想在一個按鈕框中包含多個繪圖，則當我單擊另一個按鈕時必須刪除這些繪圖。正如你在腳本中所做的那樣。有時我有 4 或 6 張圖，如何一鍵刪除整個報告而不刪除（gb1，gb2，gb3....）？回覆：如何為報告中的圖表製作內容？

這是另一種方法，將為您提供可接受的可能解決方案

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw2 = New Window( "Graphs",
 hlb = H List Box(
  V List Box(
 
   Button Box( "Graph 1",
    Try( Report( gb ) << delete );
    hlb << append(
     gb = Graph Builder(
      Size( 528, 456 ),
      Show Control Panel( 0 ),
      Variables( X( :weight ), Y( :height ) ),
      Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
     )
    );
   ),
   Button Box( "Graph 2",
    Try( Report( gb ) << delete );
    hlb << append(
     gb = Graph Builder(
      Size( 528, 456 ),
      Show Control Panel( 0 ),
      Variables( Y( :weight ), X( :sex ) ),
      Elements( Points( X, Y, Legend( 6 ) ) )
     )
    );
   )
  )
 )
);

回覆：如何為報告中的圖表製作內容？感謝 吉姆
一如既往，你的想法非常好。 但就我而言，我喜歡將所有內容放在同一個報告視窗中，因為對於所有圖形的不同產品都有一個過濾資料視窗。在您的範例中，圖表在不同的視窗中打開，這使得很難在兩個視窗中查看不同的產品。回覆：如何為報告中的圖表製作內容？

以下是執行此操作的幾種方法：

還有其他方法

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Graphs",
 V List Box(
  ob1 = Graph Builder(
   Size( 528, 456 ),
   Show Control Panel( 0 ),
   Variables( X( :weight ), Y( :height ) ),
   Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
  );
  ob1rpt = Report( ob1 );
  ob1rpt[Outline Box( 1 )] << set title( "Graph 1" );
  ob1rpt << close;

  ob2 = Graph Builder(
   Size( 528, 456 ),
   Show Control Panel( 0 ),
   Variables( Y( :weight ), X( :sex ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  );
  ob2rpt = Report( ob2 );
  ob2rpt[Outline Box( 1 )] << set title( "Graph " );
  ob2rpt << close;
 )
);

nw2 = New Window( "Graphs",
 V List Box(
 
  Button Box( "Graph 1",
   Graph Builder(
    Size( 528, 456 ),
    Show Control Panel( 0 ),
    Variables( X( :weight ), Y( :height ) ),
    Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
   )
  ),
  Button Box( "Graph 2",
   Graph Builder(
    Size( 528, 456 ),
    Show Control Panel( 0 ),
    Variables( Y( :weight ), X( :sex ) ),
    Elements( Points( X, Y, Legend( 6 ) ) )
   )
  )
 )
);