331438_es-ES

liliconcom

¿Cómo hacer un contenido para los gráficos en un informe?

Hola,

Tengo muchos gráficos en la ventana de mi informe creados por el generador de gráficos. Me gusta tener una ventana con el contenido de mi gráfico y cuando hago clic en ellos, me puede mostrar el gráfico identificado.

No pude encontrar una solución a ningún problema similar. Agradeceré si alguien me puede ayudar.

Gracias

ScriptingRe: ¿como hacer un contenido para los gráficos en un informe?

Aquí hay un par de formas de hacer esto:

También existen otros métodos

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Graphs",
 V List Box(
  ob1 = Graph Builder(
   Size( 528, 456 ),
   Show Control Panel( 0 ),
   Variables( X( :weight ), Y( :height ) ),
   Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
  );
  ob1rpt = Report( ob1 );
  ob1rpt[Outline Box( 1 )] << set title( "Graph 1" );
  ob1rpt << close;

  ob2 = Graph Builder(
   Size( 528, 456 ),
   Show Control Panel( 0 ),
   Variables( Y( :weight ), X( :sex ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  );
  ob2rpt = Report( ob2 );
  ob2rpt[Outline Box( 1 )] << set title( "Graph " );
  ob2rpt << close;
 )
);

nw2 = New Window( "Graphs",
 V List Box(
 
  Button Box( "Graph 1",
   Graph Builder(
    Size( 528, 456 ),
    Show Control Panel( 0 ),
    Variables( X( :weight ), Y( :height ) ),
    Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
   )
  ),
  Button Box( "Graph 2",
   Graph Builder(
    Size( 528, 456 ),
    Show Control Panel( 0 ),
    Variables( Y( :weight ), X( :sex ) ),
    Elements( Points( X, Y, Legend( 6 ) ) )
   )
  )
 )
);

Re: ¿como hacer un contenido para los gráficos en un informe?Gracias, Jim
como siempre tu idea es muy buena. Pero en mi caso me gusta tener todo en la misma ventana de Informe ya que hay una ventana de Filtrar Datos para diferentes productos que son para todos los gráficos. en su ejemplo, el gráfico se abre en una ventana diferente, lo que dificulta ver diferentes productos en dos ventanas.Re: ¿como hacer un contenido para los gráficos en un informe?

Aquí hay otro método que le dará una posible solución que es aceptable.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw2 = New Window( "Graphs",
 hlb = H List Box(
  V List Box(
 
   Button Box( "Graph 1",
    Try( Report( gb ) << delete );
    hlb << append(
     gb = Graph Builder(
      Size( 528, 456 ),
      Show Control Panel( 0 ),
      Variables( X( :weight ), Y( :height ) ),
      Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
     )
    );
   ),
   Button Box( "Graph 2",
    Try( Report( gb ) << delete );
    hlb << append(
     gb = Graph Builder(
      Size( 528, 456 ),
      Show Control Panel( 0 ),
      Variables( Y( :weight ), X( :sex ) ),
      Elements( Points( X, Y, Legend( 6 ) ) )
     )
    );
   )
  )
 )
);

Re: ¿como hacer un contenido para los gráficos en un informe?Hola Jim
Si quiero tener varios gráficos en un cuadro de botones, los gráficos deben eliminarse cuando hago clic en el otro botón. como tenías en tu guión. alguna vez tengo 4 parcelas o 6, ¿cómo puedo borrar todo el informe en un botón sin borrar (gb1, gb2, gb3 ....)?