331438_fr-FR

liliconcom

comment créer un contenu pour les graphiques dans un rapport?

Salut,

J'ai beaucoup de graphiques dans ma fenêtre de rapport qui sont créés par le générateur de graphiques. J'aime avoir une fenêtre avec le contenu de mon graphique et quand je clique dessus, elle peut me montrer le graphique identifié.

Je n'ai pas pu trouver de solution à un problème similaire. J'apprécierai si quelqu'un peut m'aider.

Merci

ScriptingRe: comment faire un contenu pour les graphiques dans un rapport?

Voici quelques façons de procéder:

D'autres méthodes existent également

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Graphs",
 V List Box(
  ob1 = Graph Builder(
   Size( 528, 456 ),
   Show Control Panel( 0 ),
   Variables( X( :weight ), Y( :height ) ),
   Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
  );
  ob1rpt = Report( ob1 );
  ob1rpt[Outline Box( 1 )] << set title( "Graph 1" );
  ob1rpt << close;

  ob2 = Graph Builder(
   Size( 528, 456 ),
   Show Control Panel( 0 ),
   Variables( Y( :weight ), X( :sex ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  );
  ob2rpt = Report( ob2 );
  ob2rpt[Outline Box( 1 )] << set title( "Graph " );
  ob2rpt << close;
 )
);

nw2 = New Window( "Graphs",
 V List Box(
 
  Button Box( "Graph 1",
   Graph Builder(
    Size( 528, 456 ),
    Show Control Panel( 0 ),
    Variables( X( :weight ), Y( :height ) ),
    Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
   )
  ),
  Button Box( "Graph 2",
   Graph Builder(
    Size( 528, 456 ),
    Show Control Panel( 0 ),
    Variables( Y( :weight ), X( :sex ) ),
    Elements( Points( X, Y, Legend( 6 ) ) )
   )
  )
 )
);

Re: comment faire un contenu pour les graphiques dans un rapport?Merci Jim
comme toujours votre idée est très bonne. Mais dans mon cas, j'aime tout avoir dans la même fenêtre de rapport car il y a une fenêtre de filtre de données pour différents produits qui sont pour tous les graphiques. dans votre exemple, le graphique s'ouvre dans une fenêtre différente, ce qui rend difficile la visualisation de différents produits dans deux fenêtres.Re: comment faire un contenu pour les graphiques dans un rapport?

Voici une autre méthode qui vous donnera une solution possible qui est acceptable

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw2 = New Window( "Graphs",
 hlb = H List Box(
  V List Box(
 
   Button Box( "Graph 1",
    Try( Report( gb ) << delete );
    hlb << append(
     gb = Graph Builder(
      Size( 528, 456 ),
      Show Control Panel( 0 ),
      Variables( X( :weight ), Y( :height ) ),
      Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
     )
    );
   ),
   Button Box( "Graph 2",
    Try( Report( gb ) << delete );
    hlb << append(
     gb = Graph Builder(
      Size( 528, 456 ),
      Show Control Panel( 0 ),
      Variables( Y( :weight ), X( :sex ) ),
      Elements( Points( X, Y, Legend( 6 ) ) )
     )
    );
   )
  )
 )
);