329671_fr-FR

liliconcom

Fonction de copie de fichier

J'utilise JMP 12.

Je veux juste copier cinq fichiers csv avec un nom différent du dossier A et l'enregistrer dans le dossier B.

Le dossier A contient de nombreux fichiers csv.

En utilisant la fonction Copier un fichier (comme ci-dessous), je ne peux copier qu'un seul fichier à la fois.

Je dois écrire cinq fois le script ci-dessous pour copier les cinq fichiers

 

 

Copy File( "C:\A\data1.csv", "C:\B\data1.csv" );
Copy File( "C:\A\data2.csv", "C:\B\data2.csv" );
Copy File( "C:\A\data3.csv", "C:\B\data3.csv" );
Copy File( "C:\A\data4.csv", "C:\B\data4.csv" );
Copy File( "C:\A\data5.csv", "C:\B\data5.csv" );

 

 

Existe-t-il un moyen de copier plusieurs fichiers à l'aide d'une seule fonction de copie de fichier ?

ou y a-t-il une autre fonction/script que je peux utiliser pour atteindre cet objectif ?

 

Merci pour votre aide.

Organisation du contenuRe : Fonction de copie de fichier

Merci.

Re : Fonction de copie de fichier

juste une autre approche utilisant une fonction de liste de fichiers ou de répertoire de copie,

pourtant testé sous JMP 15 avec Windows, je n'ai pas de JMP12.

 

Names Default To Here( 1 );

source_dir = "$TEMP\ADIR";
destination_dir = "$TEMP\BDIR";

// Prepare a directory and some files
If( !Directory Exists( source_dir ),
 Create Directory( source_dir )
);
Save Text File( source_dir || "\afile.txt", "afile content" );
Save Text File( source_dir || "\bfile.txt", "bfile content" );
Save Text File( source_dir || "\cfile.txt", "cfile content" );

// Generate list of files
file_list = Files In Directory( source_dir );

// Prepare destination directory
If( !Directory Exists( destination_dir ),
 Create Directory( destination_dir )
);

// Copy all files from list
For( i = 1, i <= N Items( file_list ), i++,
 Copy File( source_dir || "\" || file_list[i], destination_dir || "\" || file_list[i] )
);

// Copy directory
Copy Directory( source_dir, "$HOME", recursive( 1 ) );

// see results
Open( "$TEMP" );
Open( "$HOME" );

 

 

 

Re : Fonction de copie de fichier

for (i = 1, i <= 5, i++,
 file1 = evalinsert("C:\A\data^i^.csv");
 file2 = evalinsert("C:\B\data^i^.csv");
 copy file(file1, file2);
);