329671_zh-TW

liliconcom

複製文件功能

我正在使用 JMP 12。

我只想從 A 資料夾複製五個不同名稱的 csv 檔案並將其保存在 B 資料夾中。

A 資料夾包含許多 csv 檔案。

使用複製文件功能（如下），我一次只能複製一個文件。

我需要編寫下面的腳本五次才能複製所有五個文件

 

 

Copy File( "C:\A\data1.csv", "C:\B\data1.csv" );
Copy File( "C:\A\data2.csv", "C:\B\data2.csv" );
Copy File( "C:\A\data3.csv", "C:\B\data3.csv" );
Copy File( "C:\A\data4.csv", "C:\B\data4.csv" );
Copy File( "C:\A\data5.csv", "C:\B\data5.csv" );

 

 

有沒有一種方法可以使用一個複製檔案功能複製多個檔案？

或者，我可以使用其他函數/腳本來實現此目標嗎？

 

感謝您的協助。

內容組織回覆：複製文件功能

謝謝。

回覆：複製文件功能

只是使用檔案列表或複製目錄功能的另一種方法，

但在 Windows 下的 JMP 15 下進行測試，我沒有 JMP12。

 

Names Default To Here( 1 );

source_dir = "$TEMP\ADIR";
destination_dir = "$TEMP\BDIR";

// Prepare a directory and some files
If( !Directory Exists( source_dir ),
 Create Directory( source_dir )
);
Save Text File( source_dir || "\afile.txt", "afile content" );
Save Text File( source_dir || "\bfile.txt", "bfile content" );
Save Text File( source_dir || "\cfile.txt", "cfile content" );

// Generate list of files
file_list = Files In Directory( source_dir );

// Prepare destination directory
If( !Directory Exists( destination_dir ),
 Create Directory( destination_dir )
);

// Copy all files from list
For( i = 1, i <= N Items( file_list ), i++,
 Copy File( source_dir || "\" || file_list[i], destination_dir || "\" || file_list[i] )
);

// Copy directory
Copy Directory( source_dir, "$HOME", recursive( 1 ) );

// see results
Open( "$TEMP" );
Open( "$HOME" );

 

 

 

回覆：複製文件功能

for (i = 1, i <= 5, i++,
 file1 = evalinsert("C:\A\data^i^.csv");
 file2 = evalinsert("C:\B\data^i^.csv");
 copy file(file1, file2);
);