複数の単語の値を分割してアルファベット順に並べ替える方法2文字の略語である文字値の列があります。 一部は単一の値であり、その他は区切り文字「/」で区切られた複数の値です。 問題は、複数値の値がアルファベット順になっていないことです。
各行を繰り返し処理し、複数の値を分割してアルファベット順に並べ替え、新しい「値」を新しい列に挿入したいと思います。 単一の値は単に「コピー」され、nullはnullとして残される必要があります。
これは私の頭の上の方法であり、これを修正するのに役立つ提案ポインタまたは読書リストをいただければ幸いです。
ありがとう！
現在のデータ新しいデータ
AB AB
CD CD
EF EF
CD / AB AB / CD
null null
EF / AB / CD AB / CD / EF
col = ("Really | Long | and | Boring | Column | Name");
Vals = As Column (col) << Get Values; // Get Values
dt = New Column ("NewAbs", Character, "Nominal" ); //New column for NEW DATA
rows = N rows (dt); // Total number of rows to iterate
for(i = 1 , i <= rows, i++,
if(rowVal (Contains (Vals[i], "/")), // check if is multi-value i.e. AB/DF
rowVal = Words(Vals[i],"/"); // Words will split multi-values at "/"
sval = Sort List(Eval List(rowVal) ); // sort the character values
For(i = 1, i <= N Items (sVal), i++,
newVal = sVal[i];
conCat = Concat Items ( newVal[i] || "/"|| newVal[i+i])
),
Insert Into (dt, conCat[i]),
if(rowVal (!Contains (Vals[i], "/")), // if is NOT multi-value i.e. AB/DF
Insert Into (dt, rowVal[i])),
),
);スクリプティングRe：複数の単語の値を分割してアルファベット順に並べ替える方法これは、サンプルデータテーブルで機能する式です。添付されているのは、式が適用されたデータテーブルです。
If( Contains( :Current data, "/" ) == 0,
x = :Current data,
i = 1;
theList = {};
While( Word( i, :Current data, "/" ) != "",
Insert Into( theList, Word( i, :Current data, "/" ) );
i++;
);
theList = Sort List( theList );
x = theList[1];
For( i = 2, i <= N Items( theList ), i++,
x = x || "/" || theList[i]
);
)Re：複数の単語の値を分割してアルファベット順に並べ替える方法改善できることはめったにありません@txnelson 、しかし私はそれを一行の式にまとめることができます：
Concat Items( Sort List( Words( :Current data, "/" ) ), "/" )
Words（）区切り文字として「/」を使用して列を単語に分割することにより、単語のリストを作成します。
ソートリスト（）リストをアルファベット順に並べ替えます
Concat Items（） 「/」を使用してリスト内のアイテムを単一の文字列に連結し、アイテムを区切ります。
Re：複数の単語の値を分割してアルファベット順に並べ替える方法とってもとっても素敵Re：複数の単語の値を分割してアルファベット順に並べ替える方法親愛な@txnelsonそして@Jeff_Perkinsonご回答ありがとうございます。ループと他の気が遠くなるようなワンライナーについての素晴らしいレッスン。
両方をJSLのバッグに追加します。
宜しくお願いします。
Re：複数の単語の値を分割してアルファベット順に並べ替える方法セグメンテーションと並べ替えに加えて、この数式はセグメンテーション後に重複した値を追加および削除し、繰り返されないフィールドのみを保持しますか？
宜しくお願いします。
Re：複数の単語の値を分割してアルファベット順に並べ替える方法いいえ、指定されたソリューションはどちらも重複を削除しません。その要件は元の要求の一部ではありませんでした。
contains（）関数には、リスト内の項目全体をチェックして、一致するものが見つかったかどうかを確認する機能があります。よく使います。
Names Default To Here( 1 );
theList = {"AB", "AB", "CD", "EF"};
x = {};
Insert Into( x, theList[1] );
For( i = 2, i <= N Items( theList ), i++,
If( Contains( x, theList[i] ) == 0,
Insert Into( x, theList[i] )
)
);
show(x);
したがって、実行する必要があるのは、このコードをいずれかの推奨ソリューションに配置することだけです。
x = :Current data;
If( Contains( x, "/" ) > 0,
theList = Words( x, "/" );
theList = Sort List( theList );
x = {};
Insert Into( x, theList[1] );
For( i = 2, i <= N Items( theList ), i++,
If( Contains( x, theList[i] ) == 0,
Insert Into( x, theList[i] )
)
);
x = Concat Items( x, "/" );
);
x;
