328429_it-IT

liliconcom

Grafico di riferimento in background in Graph Builder

Supponiamo di avere un set di dati di riferimento del tasso di crescita dei batteri A nel tempo a temperatura ambiente e umidità del 40%.

 

Quindi eseguo un esperimento sui batteri B dove vari i livelli di temperatura e umidità per vedere come questi influenzano il tasso di crescita, volendo vederli rispetto ai batteri A.

 

Le mie colonne sono: batteriTipo, temperatura, umidità, tempo, velocità di crescita

 

Mi piacerebbe fare questo: time -> X, growthRate -> Y, temp -> groupX, humidity -> groupY e batteriType -> Overlay

 

... e fare tracciare i dati di riferimento (batteri A) su ogni tracciato dietro i dati dei batteri B. Ma non ce l'ho per ogni temperatura e livello di umidità.

 

C'è un modo per fare questo?

GraficaOggetto: grafico di riferimento in background in Graph Builder

Data la tua descrizione, i batteri di riferimento di base, batteri a verranno visualizzati su ogni grafico in cui hai dati per quella combinazione di fattori.Se la tua domanda è: come fai a visualizzare il livello base di un batterio in ogni grafico, si tratta solo di replicare i dati sul tasso di crescita ei dati temporali per le combinazioni di fattori che mancano.

 

Spero di capire cosa vuoi.In caso contrario, per favore dimmi cosa non ricevo.

Oggetto: grafico di riferimento in background in Graph Builder

Sì, hai capito.

 

Speravo di non dover replicare gli stessi dati per i batteri A 25 volte per farli apparire in ogni grafico ...

 

Mi chiedevo se ci fosse uno script che potessi usare per generare la stessa trama, simile a come puoi disegnare forme nelle finestre di trama con "Personalizza grafico", quindi aggiungendo uno "script"?

 

O se ci fosse un modo per far sì che una data riga / record debba essere tracciata nel grafico corrente se non ci sono * dati * nel campo corrispondente e se il campo corrisponde al valore rappresentato dalla colonna dei grafici?

 

Grazie.

Oggetto: grafico di riferimento in background in Graph Builder

Sembra scoraggiante, ma la replica dei dati può essere eseguita abbastanza rapidamente unendo i dati di crescita a una tabella delle opzioni disponibili utilizzando un "join cartesiano" e quindi concatenandoli ai dati originali.Ecco un esempio

 

Vedi di più ...

names default to here(1);

dtResults = New Table( "Results",
 Add Rows( 240 ),
 New Column( "time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Mod( Row() - 1, 10 ) )
 ),
 New Column( "humidity",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 30, 60, 10, 60 ) ),
  Set Selected
 ),
 New Column( "Bacteria Type",
  Character,
  "Nominal",
  Value Labels( {"1" = "a", "2" = "b"} ),
  Use Value Labels( 1 ),
  Set Values( Repeat( {"b"},240) )
 ),
 New Column( "magnitude",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( If( :time == 0, Random Uniform( 0.5, 1 ), Lag( :magnitude ) ) )
 ),
 New Column( "temp",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 80, 90, 2, 10 ) )
 ),
 New Column( "growthRate",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula(
   If( :time == 0,
    0,
    (1 - :time / (:time + 1)) * Ln( :time * 2 ) * :magnitude * :humidity
     * :temp + Random Normal( 0, 100 )
   )
  )
 )
);


dtRef = New Table( "Reference",
 Add Rows( 10 ),
 New Column( "time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Row() - 1 )
 ),
 New Column( "growthRate",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula(
   If( :time == 0,
    0,
    (1 - :time / (:time + 1)) * Ln( :time * 2 ) * 0.7 * 40 * 80
    +Random Normal( 0, 100 )
   )
  )
 ),
 New Column( "Bacteria Type",
  Character,
  "Nominal",
  Set Selected,
  Set Values( {"a", "a", "a", "a", "a", "a", "a", "a", "a", "a"} )
 )
);

dtAll = New Table( "All Conditions",
 Add Rows( 24 ),
 New Column( "temp",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 80, 90, 2 ) )
 ),
 New Column( "humidity",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 30, 60, 10, 6 ) ),
  Set Selected
 ),
 Set Row States(
  [0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0]
 )
);

wait(1);

dtRefAll = dtRef << Join(
 With( dtAll ),
 Cartesian Join,
 Copy formula(1)
);
dtRefAll << Set Name( "All Reference Data" );

dtForGraph = dtResults << Concatenate( dtRefAll, Keep Formulas );
dtForGraph << Set Name("For Graphing");

dtForGraph << Graph Builder(
 Size( 676, 633 ),
 Show Control Panel( 0 ),
 Variables(
  X( :time ),
  Y( :growthRate ),
  Group X( :temp ),
  Group Y( :humidity ),
  Overlay( :Bacteria Type )
 ),
 Elements( Points( X, Y, Legend( 10 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    10,
    Properties( 0, {Line Color( 32 )}, Item ID( "a", 1 ) ),
    Properties( 1, {Line Color( 56 )}, Item ID( "b", 1 ) )
   )}
  ),
  Dispatch( {}, "400", LegendBox, {Set Title( "Bacteria" )} )
 )
);

C'è una funzione chiamata "Funzione Y ()" che mi permette di plo ...

C'è una funzione chiamata "Funzione Y ()" che mi permette di tracciare direttamente in ogni tracciato in Graph Builder usando la finestra "Personalizza grafico", che è molto interessante ...

 

Esiste una funzione simile che mi consentirà di tracciare i dati dalla tabella dati principale tramite la stessa interfaccia? Ciò risolverebbe il mio problema senza richiedermi di creare una tabella di dati notevolmente più grande.

Ri: C'è una funzione chiamata "Funzione Y ()" che mi permette di plo ...

L'opzione Personalizza disponibile dai grafici in JMP è un'interfaccia nella capacità di JMP di utilizzare JSL per utilizzare routine grafiche di livello base da aggiungere alla visualizzazione.Ecco un semplice esempio tratto dallo Scripting Index.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
 Transparency( 0.5 );
 Fill Color( {1.0, 0.5, 0.0} );
 Polygon( [60, 72, 57], [75, 120, 120] );
);

 

La funzione Y () è solo una delle primitive grafiche disponibili per l'aggiunta a qualsiasi grafico visualizzato.Oppure si può anche scrivere su un oggetto di visualizzazione chiamato Graph Box () e generare un display grafico originale e autonomo.

Tutte queste funzioni grafiche sono documentate nell'indice di scripting, in "Grafica"

Quindi per rispondere alla tua domanda

Sì, puoi aggiungere JSL a ciascuno dei tuoi grafici che leggono dalla tabella dati originale e tracciano i valori.Basterebbe scrivere il JSL per prendere i valori dalla tabella dati e utilizzare le funzioni Marker, Pen Color, Line, ecc. Per costruire il display grafico.