328429_de-DE

liliconcom

Hintergrundreferenzdiagramm in Graph Builder

Angenommen, ich habe einen Basisdatensatz der Wachstumsrate von Bakterien A über die Zeit bei Raumtemperatur und 40% Luftfeuchtigkeit.

 

Dann führe ich ein Experiment mit Bakterien B durch, bei dem ich die Temperatur und Luftfeuchtigkeit verändere, um zu sehen, wie sich diese auf die Wachstumsrate auswirken, und sie im Verhältnis zu Bakterien A sehen möchte.

 

Meine Spalten sind: Bakterientyp, Temperatur, Luftfeuchtigkeit, Zeit, Wachstumsrate

 

Ich möchte dies tun: Zeit -> X, Wachstumsrate -> Y, Temperatur -> Gruppe X, Luftfeuchtigkeit -> Gruppe Y und Bakterientyp -> Überlagerung

 

... und lassen Sie die Referenzdaten (Bakterien A) auf jeder Parzelle hinter den Daten von Bakterien B auftragen. Aber ich habe es nicht für jede Temperatur und Luftfeuchtigkeit.

 

Gibt es eine Möglichkeit, dies zu tun?

GrafikBetreff: Hintergrundreferenzdiagramm in Graph Builder

In Anbetracht Ihrer Beschreibung werden die Basisreferenzbakterien, Bakterien a, in jedem Diagramm angezeigt, für das Sie Daten für diese Kombination von Faktoren haben.Wenn Ihre Frage lautet, wie Sie das Basisniveau eines Bakteriums in jedem Diagramm anzeigen lassen, müssen Sie lediglich die Wachstumsraten- und Zeitdaten für die fehlenden Kombinationen von Faktoren replizieren.

 

Ich hoffe ich verstehe was du willst.Wenn nicht, sagen Sie mir bitte, was ich nicht bekomme.

Betreff: Hintergrundreferenzdiagramm in Graph Builder

Ja, du hast es verstanden.

 

Ich hatte gehofft, nicht 25 Mal dieselben Daten für Bakterien A replizieren zu müssen, damit sie in jedem Diagramm angezeigt werden ...

 

Ich habe mich gefragt, ob es ein Skript gibt, mit dem ich dasselbe Diagramm erstellen kann, ähnlich wie Sie mit "Diagramm anpassen" Formen in die Diagrammfenster zeichnen und dann ein "Skript" hinzufügen können.

 

Oder wenn es eine Möglichkeit gab, davon auszugehen, dass eine bestimmte Zeile / ein bestimmter Datensatz im aktuellen Diagramm aufgezeichnet werden sollte, wenn das entsprechende Feld * keine * Daten enthält und das Feld mit dem Wert übereinstimmt, der durch die Spalte der Diagramme dargestellt wird?

 

Danke.

Betreff: Hintergrundreferenzdiagramm in Graph Builder

Es klingt entmutigend, aber das Replizieren der Daten kann ziemlich schnell erfolgen, indem die Wachstumsdaten mithilfe eines kartesischen Joins mit einer Tabelle der verfügbaren Optionen verknüpft und dann mit Ihren Originaldaten verknüpft werden.Hier ist ein Beispiel

 

Mehr sehen...

names default to here(1);

dtResults = New Table( "Results",
 Add Rows( 240 ),
 New Column( "time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Mod( Row() - 1, 10 ) )
 ),
 New Column( "humidity",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 30, 60, 10, 60 ) ),
  Set Selected
 ),
 New Column( "Bacteria Type",
  Character,
  "Nominal",
  Value Labels( {"1" = "a", "2" = "b"} ),
  Use Value Labels( 1 ),
  Set Values( Repeat( {"b"},240) )
 ),
 New Column( "magnitude",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( If( :time == 0, Random Uniform( 0.5, 1 ), Lag( :magnitude ) ) )
 ),
 New Column( "temp",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 80, 90, 2, 10 ) )
 ),
 New Column( "growthRate",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula(
   If( :time == 0,
    0,
    (1 - :time / (:time + 1)) * Ln( :time * 2 ) * :magnitude * :humidity
     * :temp + Random Normal( 0, 100 )
   )
  )
 )
);


dtRef = New Table( "Reference",
 Add Rows( 10 ),
 New Column( "time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Row() - 1 )
 ),
 New Column( "growthRate",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula(
   If( :time == 0,
    0,
    (1 - :time / (:time + 1)) * Ln( :time * 2 ) * 0.7 * 40 * 80
    +Random Normal( 0, 100 )
   )
  )
 ),
 New Column( "Bacteria Type",
  Character,
  "Nominal",
  Set Selected,
  Set Values( {"a", "a", "a", "a", "a", "a", "a", "a", "a", "a"} )
 )
);

dtAll = New Table( "All Conditions",
 Add Rows( 24 ),
 New Column( "temp",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 80, 90, 2 ) )
 ),
 New Column( "humidity",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 30, 60, 10, 6 ) ),
  Set Selected
 ),
 Set Row States(
  [0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0]
 )
);

wait(1);

dtRefAll = dtRef << Join(
 With( dtAll ),
 Cartesian Join,
 Copy formula(1)
);
dtRefAll << Set Name( "All Reference Data" );

dtForGraph = dtResults << Concatenate( dtRefAll, Keep Formulas );
dtForGraph << Set Name("For Graphing");

dtForGraph << Graph Builder(
 Size( 676, 633 ),
 Show Control Panel( 0 ),
 Variables(
  X( :time ),
  Y( :growthRate ),
  Group X( :temp ),
  Group Y( :humidity ),
  Overlay( :Bacteria Type )
 ),
 Elements( Points( X, Y, Legend( 10 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    10,
    Properties( 0, {Line Color( 32 )}, Item ID( "a", 1 ) ),
    Properties( 1, {Line Color( 56 )}, Item ID( "b", 1 ) )
   )}
  ),
  Dispatch( {}, "400", LegendBox, {Set Title( "Bacteria" )} )
 )
);

Es gibt eine Funktion namens "Y Function ()", mit der ich ...

Es gibt eine Funktion namens "Y Function ()", mit der ich über das Fenster "Graph anpassen" direkt in jedes Diagramm in Graph Builder zeichnen kann. Das ist super cool ...

 

Gibt es eine ähnliche Funktion, mit der ich Daten aus der Hauptdatentabelle über dieselbe Schnittstelle zeichnen kann? Das würde mein Problem lösen, ohne dass ich eine Datentabelle erstellen müsste, die erheblich größer ist.

Betreff: Es gibt eine Funktion namens "Y Function ()", mit der ich ...

Die Option "Anpassen", die in JMP-Diagrammen verfügbar ist, ist eine Schnittstelle zu JMPs Fähigkeit, JSL zu verwenden, um Grafikroutinen auf Basisebene zum Hinzufügen zur Anzeige zu verwenden.Hier ist ein einfaches Beispiel aus dem Scripting Index.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
 Transparency( 0.5 );
 Fill Color( {1.0, 0.5, 0.0} );
 Polygon( [60, 72, 57], [75, 120, 120] );
);

 

Die Y-Funktion () ist nur eines der grafischen Grundelemente, die zu jedem angezeigten Diagramm hinzugefügt werden können.Sie können auch in ein Anzeigeobjekt namens Graph Box () schreiben und eine originale, eigenständige grafische Anzeige erstellen.

Alle diese grafischen Funktionen sind im Scripting Index unter "Grafik" dokumentiert.

Um Ihre Frage zu beantworten,

Ja, Sie können jedem Ihrer Diagramme JSL hinzufügen, die aus der ursprünglichen Datentabelle lesen und die Werte darstellen.Man müsste nur die JSL schreiben, um die Werte aus der Datentabelle zu übernehmen und die Funktionen Marker, Stiftfarbe, Linie usw. zu verwenden, um die grafische Anzeige zu erstellen.