328429_fr-FR

liliconcom

Tracé de référence en arrière-plan dans Graph Builder

Supposons que je dispose d'un ensemble de données de base du taux de croissance de la bactérie A au fil du temps à température ambiante et à 40% d'humidité.

 

Ensuite, je lance une expérience sur les bactéries B où je fais varier les niveaux de température et d'humidité pour voir comment ceux-ci affectent le taux de croissance, en voulant les voir par rapport aux bactéries A.

 

Mes colonnes sont: bactérieType, température, humidité, temps, croissanceRate

 

Je voudrais faire ceci: time -> X, growthRate -> Y, temp -> groupX, humidité -> groupY, et bacterType -> Overlay

 

... et faire tracer les données de référence (bactéries A) sur chaque parcelle derrière les données sur les bactéries B. Mais je ne l'ai pas pour chaque température et niveau d'humidité.

 

Y a-t-il un moyen de faire cela?

GraphiqueRe: tracé de référence en arrière-plan dans Graph Builder

Compte tenu de votre description, les bactéries de référence de base, les bactéries a seront affichées sur chaque graphique contenant des données pour cette combinaison de facteurs.Si votre question est de savoir comment faire apparaître le niveau de base d'une bactérie dans chaque graphique, il s'agit simplement de reproduire les données de taux de croissance et les données de temps pour les combinaisons de facteurs manquants.

 

J'espère que je comprends ce que vous voulez.Sinon, dites-moi ce que je ne reçois pas.

Re: tracé de référence en arrière-plan dans Graph Builder

Oui, vous l'avez.

 

J'espérais ne pas avoir à reproduire les mêmes données pour les bactéries A 25 fois pour les faire apparaître dans chaque graphique ...

 

Je me suis demandé s'il y avait un script que je pourrais utiliser pour générer le même tracé, de la même manière que vous pouvez dessiner des formes dans les fenêtres de tracé avec "Personnaliser le graphique", puis en ajoutant un "script"?

 

Ou s'il y avait un moyen de supposer qu'une ligne / un enregistrement donné devrait être tracé dans le tracé actuel s'il n'y a * pas * de données dans le champ correspondant ainsi que si le champ correspond à la valeur représentée par la colonne de tracés?

 

Merci.

Re: tracé de référence en arrière-plan dans Graph Builder

Cela semble intimidant, mais la réplication des données peut être effectuée assez rapidement en joignant les données de croissance à une table des options disponibles à l'aide d'une `` jointure cartésienne '', puis en la concaténant avec vos données d'origine.Voici un exemple

 

Voir plus...

names default to here(1);

dtResults = New Table( "Results",
 Add Rows( 240 ),
 New Column( "time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Mod( Row() - 1, 10 ) )
 ),
 New Column( "humidity",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 30, 60, 10, 60 ) ),
  Set Selected
 ),
 New Column( "Bacteria Type",
  Character,
  "Nominal",
  Value Labels( {"1" = "a", "2" = "b"} ),
  Use Value Labels( 1 ),
  Set Values( Repeat( {"b"},240) )
 ),
 New Column( "magnitude",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( If( :time == 0, Random Uniform( 0.5, 1 ), Lag( :magnitude ) ) )
 ),
 New Column( "temp",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 80, 90, 2, 10 ) )
 ),
 New Column( "growthRate",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula(
   If( :time == 0,
    0,
    (1 - :time / (:time + 1)) * Ln( :time * 2 ) * :magnitude * :humidity
     * :temp + Random Normal( 0, 100 )
   )
  )
 )
);


dtRef = New Table( "Reference",
 Add Rows( 10 ),
 New Column( "time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Row() - 1 )
 ),
 New Column( "growthRate",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula(
   If( :time == 0,
    0,
    (1 - :time / (:time + 1)) * Ln( :time * 2 ) * 0.7 * 40 * 80
    +Random Normal( 0, 100 )
   )
  )
 ),
 New Column( "Bacteria Type",
  Character,
  "Nominal",
  Set Selected,
  Set Values( {"a", "a", "a", "a", "a", "a", "a", "a", "a", "a"} )
 )
);

dtAll = New Table( "All Conditions",
 Add Rows( 24 ),
 New Column( "temp",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 80, 90, 2 ) )
 ),
 New Column( "humidity",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 30, 60, 10, 6 ) ),
  Set Selected
 ),
 Set Row States(
  [0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0]
 )
);

wait(1);

dtRefAll = dtRef << Join(
 With( dtAll ),
 Cartesian Join,
 Copy formula(1)
);
dtRefAll << Set Name( "All Reference Data" );

dtForGraph = dtResults << Concatenate( dtRefAll, Keep Formulas );
dtForGraph << Set Name("For Graphing");

dtForGraph << Graph Builder(
 Size( 676, 633 ),
 Show Control Panel( 0 ),
 Variables(
  X( :time ),
  Y( :growthRate ),
  Group X( :temp ),
  Group Y( :humidity ),
  Overlay( :Bacteria Type )
 ),
 Elements( Points( X, Y, Legend( 10 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    10,
    Properties( 0, {Line Color( 32 )}, Item ID( "a", 1 ) ),
    Properties( 1, {Line Color( 56 )}, Item ID( "b", 1 ) )
   )}
  ),
  Dispatch( {}, "400", LegendBox, {Set Title( "Bacteria" )} )
 )
);

Il y a une fonction appelée "Fonction Y ()" qui me permet de plo ...

Il existe une fonction appelée "Fonction Y ()" qui me permet de tracer directement dans chaque tracé dans Graph Builder en utilisant la fenêtre "Personnaliser le graphique", ce qui est super cool ...

 

Existe-t-il une fonction similaire qui me permettra de tracer les données de la table de données principale via cette même interface? Cela résoudrait mon problème sans m'obliger à créer une table de données beaucoup plus grande.

Re: Il y a une fonction appelée "Fonction Y ()" qui me permet de plo ...

L'option Personnaliser qui est disponible à partir des graphiques dans JMP est une interface dans la capacité de JMP à utiliser JSL pour utiliser des routines graphiques de niveau de base à ajouter à l'affichage.Voici un exemple simple tiré de l'index de script.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
 Transparency( 0.5 );
 Fill Color( {1.0, 0.5, 0.0} );
 Polygon( [60, 72, 57], [75, 120, 120] );
);

 

La fonction Y () n'est que l'une des primitives graphiques disponibles pour être ajoutée à n'importe quel graphique affiché.Ou, on peut également écrire dans un objet d'affichage appelé Graph Box () et générer un affichage graphique original et autonome.

Toutes ces fonctions graphiques sont documentées dans l’index des scripts, sous «Graphiques»

Alors pour répondre à ta question,

Oui, vous pouvez ajouter JSL à chacun de vos graphiques qui liront à partir de la table de données d'origine et traceront les valeurs.Il suffit d'écrire le JSL pour prendre les valeurs de la table de données et d'utiliser les fonctions Marqueur, Couleur du stylo, Ligne, etc. pour construire l'affichage graphique.