Graph Builder with Local Data Filter to Journal

OneNorthJMP

I try to append a graph builder graph with local data filter into Journal. It look fine on JMP when i run the JSL. But when i export to pdf, the local data filter features is gone. Can anyone advice what wrong? According to Bryon feedback, local data filter features is not present on PDF, but the filter still present with notes at below chart. 

 

Another issue that i have is i generate 2 charts with data filter and send it to journal. But the first chart with data filter display correctly with filter fuction. But 2nd chart data filter is not present.

 

Correct charts that i expected inside PDF. 

I attached my JSL, sample and pdf that generated. 

 

Names Default To Here( 1 );
Clear Symbols();
Clear Log();
Close All( Data Tables, NoSave );
Close All( Journals, NoSave );

//Journal
nw = New Window( "Reports",
	<<Journal,
	hlb = H List Box(
		lub = Lineup Box( N Col( 1 ) )
	)
);

//*************************************
//dt_source = Data Table( "Wafer_Sort" );
dt_source = Open( "test.jmp" );

cht_uNV_EC_RD_Set_AfterCyc = dt_source << Graph Builder(
	Size( 1029, 643 ),
	Show Control Panel( 0 ),
	Variables(
		X( :SplitGrp ),
		X( :Wafer, Position( 1 ) ),
		Y( :Name( "DL_uNV_EC_RD_Set_AfterCyc-DL_uNV_EC_RD_Set_AfterCyc,11510,-" ) )
	),
	Elements( Points( X( 1 ), X( 2 ), Y, Legend( 32 ) ) ),
	Local Data Filter(
		Add Filter(
			columns(
				:Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ),
				:Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ),
				:Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ),
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-" ),
				:Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" )
			),
			Where(
				:Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ) == 0
			),
			Where(
				:Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ) == 0
			),
			Where(
				:Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ) == 0
			),
			Where(
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-" ) == 0
			),
			Where(
				:Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" ) == 0 
			)
		)
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position( {32, [-1]} ), Position( {-1} )}
		)
	)
);

cht_uNV_EC_RD_Erase_AfterCyc = dt_source << Graph Builder(
	Size( 1029, 643 ),
	Show Control Panel( 0 ),
	Variables(
		X( :SplitGrp ),
		X( :Wafer, Position( 1 ) ),
		Y(
			:Name(
				"DL_uNV_EC_RD_Erase_AfterCyc-DL_uNV_EC_RD_Erase_AfterCyc,11512,-"
			)
		)
	),
	Elements( Points( X( 1 ), X( 2 ), Y, Legend( 32 ) ) ),
	Local Data Filter(
		Add Filter(
			columns(
				:Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ),
				:Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ),
				:Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ),
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-"
				),
				:Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" )
			),
			Where(
				:Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ) == 0
			),
			Where(
				:Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" )
				 == 0
			),
			Where(
				:Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ) ==
				0
			),
			Where(
				:Name(
					"DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-"
				) == 0
			),
			Where( :Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" ) == 0 )
		)
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position( {32, [-1]} ), Position( {-1} )}
		)
	)
);


lub << Append( tb = Text Box( "uNV RD_Set & RD_Erase after 10k" ));
tb << Set Font Size( 14 ) << Set Font Style( "Bold" ) << Justify Text( "center" );
tb << set width(700) << set wrap(700);
lub << Append(Report (cht_uNV_EC_RD_Set_AfterCyc));
lub << Append(Report (cht_uNV_EC_RD_Erase_AfterCyc));


//**** Report *******

Reports = Current Journal();
//Reports << Set page setup( margins( 0.1, 0.1, 0.1, 0.1 ), scale( 0.8 ), portrait( 0 ), paper size( "A4" ) );
Reports << Set page setup( margins( 0.05, 0.05, 0.05, 0.05 ), scale( 1 ), portrait( 0 ), paper size( "A3" ) );

Reports << get page setup();
Reports << SavePDF("debug.pdf");

//Close All( Data Tables, NoSave );
Close All( Journals, NoSave );
//Exit();

 

test.jmp

debug.pdf

debug.jsl

Byron_JMP

I'm not sure. When I ran your script with the test table. Both graphs are the same, and both can be exported to PDF. In all 4 (?) cases the local data filter is included with the figures.

 

I messed around with your script a little.

I wrapped the two graphs and the filters in an expression.

When I make the window, I put them directly into the window vlistbox (Lub) by evaluating the expressions there.

 

Then I prepended (opposite of append, kind of) the text to the top.

After the window was complete I journaled it as the last step.  Journals can be a pain to work with so I always try to journal last. Saved the journal as a PDF and then opened it to check to see how it looked. 

 

//*************************************
//dt_source = Data Table( "Wafer_Sort" );
dt_source = Open( "test.jmp" );

set = Expr(
	cht_uNV_EC_RD_Set_AfterCyc = dt_source << Graph Builder(
		Size( 1029, 643 ),
		Show Control Panel( 0 ),
		Variables(
			X( :SplitGrp ),
			X( :Wafer, Position( 1 ) ),
			Y( :Name( "DL_uNV_EC_RD_Set_AfterCyc-DL_uNV_EC_RD_Set_AfterCyc,11510,-" ) )
		),
		Elements( Points( X( 1 ), X( 2 ), Y, Legend( 32 ) ) ), 
	
	
		SendToReport(
			Dispatch(
				{},
				"400",
				LegendBox,
				{Legend Position( {32, [-1]} ), Position( {-1} )}
			)
		)
	)
);

erase = Expr(
	cht_uNV_EC_RD_Erase_AfterCyc = dt_source << Graph Builder(
		Size( 1029, 643 ),
		Show Control Panel( 0 ),
		Variables(
			X( :SplitGrp ),
			X( :Wafer, Position( 1 ) ),
			Y( :Name( "DL_uNV_EC_RD_Erase_AfterCyc-DL_uNV_EC_RD_Erase_AfterCyc,11512,-" ) )
		),
		Elements( Points( X( 1 ), X( 2 ), Y, Legend( 32 ) ) ), 
	
		SendToReport(
			Dispatch(
				{},
				"400",
				LegendBox,
				{Legend Position( {32, [-1]} ), Position( {-1} )}
			)
		)
	)
);

filters = Expr(
	cht_uNV_EC_RD_Set_AfterCyc << Local Data Filter(
		Add Filter(
			columns(
				:Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ),
				:Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ),
				:Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ),
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-" ),
				:Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" )
			),
			Where( :Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ) == 0 ),
			Where( :Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ) == 0 ),
			Where( :Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ) == 0 ),
			Where(
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-" ) == 0
			),
			Where( :Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" ) == 0 )
		)
	);
	cht_uNV_EC_RD_Erase_AfterCyc << Local Data Filter(
		Add Filter(
			columns(
				:Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ),
				:Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ),
				:Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ),
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-" ),
				:Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" )
			),
			Where( :Name( "DL_uNV_EC_Set_PreCyc-DL_uNV_EC_Set_PreCyc,11504,-" ) == 0 ),
			Where( :Name( "DL_uNV_EC_RD_Set_PreCyc-DL_uNV_EC_RD_Set_PreCyc,11505,-" ) == 0 ),
			Where( :Name( "DL_uNV_EC_Erase_PreCyc-DL_uNV_EC_Erase_PreCyc,11506,-" ) == 0 ),
			Where(
				:Name( "DL_uNV_EC_RD_Erase_PreCyc-DL_uNV_EC_RD_Erase_PreCyc,11507,-" ) == 0
			),
			Where( :Name( "DL_uNV_EC_10k_Cycle-DL_uNV_EC_10k_Cycle,11508,-" ) == 0 )
		)
	);
);

nw = New Window( "Reports",
	hlb = H List Box(
		lub = vlist Box( set,erase )
	)
);
filters;

lub << prepend( tb = Text Box( "uNV RD_Set & RD_Erase after 10k
" ));
tb << Set Font Size( 14 ) << Set Font Style( "Bold" ) << Justify Text( "center" );
tb << set width(700) << set wrap(700);
nw<<journal;


//**** Report *******

Reports = Current Journal();
//Reports << Set page setup( margins( 0.1, 0.1, 0.1, 0.1 ), scale( 0.8 ), portrait( 0 ), paper size( "A4" ) );
Reports << Set page setup( margins( 0.05, 0.05, 0.05, 0.05 ), scale( 1 ), portrait( 0 ), paper size( "A3" ) );

Reports << get page setup();
Reports << SavePDF("debug.pdf");
open ("debug.pdf");
//Close All( Data Tables, NoSave );
Close All( Journals, NoSave );
//Exit();