324267_ja-JP

liliconcom

二変量解析でグラフを非表示にしますか?

こんにちは、

二変量分析を含むスクリプトがありますが、線形適合統計テーブルだけを表示し、グラフ自体は非表示にしたいと思います。

this_dt << Bivariate(
		Y( Column(this_dt, this_cols[j])),
		X( :"Time (Months)" ),
		By( :"Lot Number" ),
		Fit Line,
		Invisible
)

ご覧のとおり、Bivariate() に Invisible 条件を含めましたが、グラフはまだ JRN ファイルに表示されており、それを削除する方法がわかりません。

マスカスタマイゼーションRe: 二変量解析でグラフを非表示にしますか?

こんにちは、

メイン グラフの線形近似統計を生成するためだけに Bivariate 関数を使用しています。 V リスト ボックスと H リスト ボックスを使用してグラフ ビルダーを使用してプロットを生成し、次に二変量を使用してプロットの横の H リスト ボックスに各ロット番号の線形近似統計を生成しています。 各グラフ ビルダー プロットには、最大 20 ～ 30 の二変量が関連付けられている場合があります。

 

より良い代替案を提案できましたら、ぜひお聞かせください。 以下は私のスクリプトの例です。わかりにくい場合は申し訳ありませんが、特定のファイル パスと列名を非表示にする必要がありました。

  // Generating Graphs
setup = Function({dt}, {Default Local},
 
 dt = Open ( "file.JMP" );
 dt << Select Where(:"column example" == "string example" );
 cfg1 = EvalList({dt << Data View, { "col1", "col2", "col3", "coln"}});
 EvalList({cfg1});
 
);

build_graphs = Function({cfgs}, {Default Local},
 win = New Window( "window", vlb = V List Box() );

 ncfg = NItems(cfgs); 
 
 for(i = 1, i <= ncfg, i++,
  {this_dt, this_cols} = cfgs[i];
  ncols = NItems(this_cols);
  for(j = 1, j <= ncols, j++,
   vlb << Append(H List Box (
     this_dt << Graph Builder(
      Show Control Panel( 0 ),
      Size( 600, 400),
      Variables(
       X( :"X axis" ), 
       Y( Column(this_dt, this_cols[j]) ), 
       Overlay( :"overlay" )   
      ),
      Elements( 
       Points( X, Y, Legend(12) )
      ),
      SendToReport(
       Dispatch(
        {},
        "",
        ScaleBox,
        {Format( "Fixed Dec", 10, 0 ), Min(0), Max(50), Inc(6),
        Minor Ticks(0)}
        ) 
       )
      ),
      this_dt << Bivariate(
       Y( Column(this_dt, this_cols[j])),
       X( :"X axis" ),
       By( :"overlay" ),
       Fit Line,
       SendToReport( Dispatch( {}, "", ListBox, {Visibility( "Collapse" )} ) )
       )
      ));   
   )
  );
  win  
 );
 

dt = Open ( "file.JMP" );
cfgs = setup(dt);
Show(cfgs);
win = build_graphs(cfgs);
Show(win);
win << Save Journal("file.jrn", embed data(1));
   

Re: 二変量解析でグラフを非表示にしますか?隠す方法があるようですが、なぜですか? プロットは、二変量解析の中で私のお気に入りの部分です (プロットが多数ある場合を除き、その場合は応答スクリーニングを使用します)。 世界統計デーおめでとうございます!Re: 二変量解析でグラフを非表示にしますか?

提案ありがとう。

 

Bivariate() 内に記述できる代替ソリューションも見つけました。

 

SendToReport( Dispatch( {}, "", ListBox, {Visibility( "Collapse" )} ) )

上の行は、二変量プロットを含むボックスを非表示にします。

Re: 二変量解析でグラフを非表示にしますか?

biv = this_dt << Bivariate(
  Y( Column(this_dt, this_cols[j])),
  X( :"Time (Months)" ),
  By( :"Lot Number" ),
  Fit Line,
  Invisible
);

biv rep = biv << Report;

// one way
biv rep[PictureBox(1)] << Delete;

// other way
biv rep[PictureBox(1)] << Visibility( "Collapse" );