324267_zh-CN

liliconcom

在双变量分析中隐藏图表？

你好，

我有一个包含双变量分析的脚本，但是我只想显示线性拟合统计表，并隐藏图形本身。

this_dt << Bivariate(
		Y( Column(this_dt, this_cols[j])),
		X( :"Time (Months)" ),
		By( :"Lot Number" ),
		Fit Line,
		Invisible
)

正如您所看到的，我在 Bivariate() 中包含了 Invisible 条件，但图表仍然显示在我的 JRN 文件中，我不确定如何摆脱它。

大规模定制回复：在双变量分析中隐藏图形？

你好，

我使用 Bivariate 函数只是为我的主图生成线性拟合统计数据。 我使用 V 列表框和 H 列表框通过图形生成器生成图，然后使用双变量为图旁边的 H 列表框中的每个批号生成线性拟合统计数据。 每个图形生成器图可能有多达 20-30 个与之关联的双变量。

 

如果您能提出更好的选择，我很乐意听到！ 下面是我的脚本示例，抱歉，如果它令人困惑，我不得不隐藏特定的文件路径和列名。

  // Generating Graphs
setup = Function({dt}, {Default Local},
 
 dt = Open ( "file.JMP" );
 dt << Select Where(:"column example" == "string example" );
 cfg1 = EvalList({dt << Data View, { "col1", "col2", "col3", "coln"}});
 EvalList({cfg1});
 
);

build_graphs = Function({cfgs}, {Default Local},
 win = New Window( "window", vlb = V List Box() );

 ncfg = NItems(cfgs); 
 
 for(i = 1, i <= ncfg, i++,
  {this_dt, this_cols} = cfgs[i];
  ncols = NItems(this_cols);
  for(j = 1, j <= ncols, j++,
   vlb << Append(H List Box (
     this_dt << Graph Builder(
      Show Control Panel( 0 ),
      Size( 600, 400),
      Variables(
       X( :"X axis" ), 
       Y( Column(this_dt, this_cols[j]) ), 
       Overlay( :"overlay" )   
      ),
      Elements( 
       Points( X, Y, Legend(12) )
      ),
      SendToReport(
       Dispatch(
        {},
        "",
        ScaleBox,
        {Format( "Fixed Dec", 10, 0 ), Min(0), Max(50), Inc(6),
        Minor Ticks(0)}
        ) 
       )
      ),
      this_dt << Bivariate(
       Y( Column(this_dt, this_cols[j])),
       X( :"X axis" ),
       By( :"overlay" ),
       Fit Line,
       SendToReport( Dispatch( {}, "", ListBox, {Visibility( "Collapse" )} ) )
       )
      ));   
   )
  );
  win  
 );
 

dt = Open ( "file.JMP" );
cfgs = setup(dt);
Show(cfgs);
win = build_graphs(cfgs);
Show(win);
win << Save Journal("file.jrn", embed data(1));
   

回复：在双变量分析中隐藏图形？我看到你有办法隐藏它，但我想问为什么？ 情节是我最喜欢的双变量部分（除非你有很多，在这种情况下我会使用反应筛选）。 世界统计日快乐！回复：在双变量分析中隐藏图形？

谢谢你的建议。

 

我还找到了一个替代解决方案，我可以在 Bivariate() 中编写它。

 

SendToReport( Dispatch( {}, "", ListBox, {Visibility( "Collapse" )} ) )

上面的行隐藏了包含双变量图的框。

回复：在双变量分析中隐藏图形？

biv = this_dt << Bivariate(
  Y( Column(this_dt, this_cols[j])),
  X( :"Time (Months)" ),
  By( :"Lot Number" ),
  Fit Line,
  Invisible
);

biv rep = biv << Report;

// one way
biv rep[PictureBox(1)] << Delete;

// other way
biv rep[PictureBox(1)] << Visibility( "Collapse" );