みなさん、こんにちは。
株価の動きを表すデータは、始値/終値と最高/最低価格によって作成されます。 添付の写真のように、始値と終値から実体を持ち、最大（高）と最小（低）の価格の値を持つ上下の影を持つJMPで箱ひげ図（ローソク足チャート）を作成する方法はありますか？それを行うためのより良い方法は？ 伝統的な箱ひげ図ただし、要素は外れ値または分位数の箱ひげ図を表示し、値の分布のコンパクトなビューを提供します。 いくつかのタイムスタンプと価格値（最小、オープン、クローズ、高）が提供されているサンプルデータテーブルを添付しました。 ヒントや提案をいただければ幸いです。
（出典：ウィキペディア）
宜しくお願いします
これは、JMPがスクリプトなしで実行できる最善の方法だと思います
しかし、少しの努力で、ローソク足プロットを作成するJSLを簡単に書くことができます。
はい、ジムが指摘しているように、グラフビルダーはこれを簡単に行うことができます。 ただし、より多くのデータを取得するにつれて、IR（個々の移動範囲チャート）を検討することをお勧めします。これらは、時間の経過に伴うメトリックの一貫性/安定性に関する洞察を提供するためです。
私はこれを調べるためにもう少し時間がありました、そして私は以下の簡単な解決策があなたのために実行可能な解決策であるかもしれないと思います。
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Stock Prices.jmp" );
dt:open << label;
dt:close << label;
gb = dt << Graph Builder(
Size( 1289, 456 ),
Show Control Panel( 0 ),
Variables( X( :Date ), Y( :High ), Y( :Low, Position( 1 ) ) ),
Elements( Bar( X, Y( 1 ), Y( 2 ), Legend( 10 ), Bar Style( "Interval" ) ) ),
SendToReport(
Dispatch(
{},
"Date",
ScaleBox,
{ Interval( "Day" ), Inc( 1 ),
Minor Ticks( 0 )}
),
Dispatch(
{},
"400",
ScaleBox,
{Legend Model(
10,
Properties( 0, {Line Width( 2 )}, Item ID( "High..Low", 1 ) )
)}
)
)
);
// Add the boxes to the chart
Report( gb )[framebox( 1 )] << add graphics script(
halfDayincr = In Days( 1 ) / 2 * .8;
days = (Col Max( :Date ) - Col Min( :Date )) / In Days( 1 );
Pen Color( black );
Pen Size( 2 );
For( i = 1, i <= N Rows( dt ), i++,
If( :Open[i] <= :close[i],
Fill Color( light green );
,
Fill Color( light red );
);
Rect( :date[i] - halfDayincr, Max( :open[i], :close[i] ), :date[i] + halfDayincr, Min( :open[i], :close[i] ), 1 );
Rect( :date[i] - halfDayincr, Max( :open[i], :close[i] ), :date[i] + halfDayincr, Min( :open[i], :close[i] ), 0 );
);
);
