322791_es-ES

liliconcom

Presentación de datos de existencias en forma de diagrama de caja

Hola todos,

los datos que describen los movimientos del precio de las acciones se crean mediante el precio de apertura / cierre y el precio máximo / mínimo. ¿Hay alguna forma de crear un diagrama de caja (gráfico de velas) en JMP que tenga el cuerpo real del precio de apertura y cierre y la sombra superior e inferior con valores en los precios máximo (alto) y mínimo (bajo) respectivamente, como en la imagen adjunta o hay? mejor manera de hacer eso? Lo tradicional Diagrama de caja elemento, sin embargo, muestra diagramas de caja de cuantiles o valores atípicos y proporciona una vista compacta de una distribución de valores. Adjunté una tabla de datos de ejemplo en la que se proporcionan varias marcas de tiempo y valores de precio (mínimo, abierto, cerrado y máximo). Agradecería sugerencias y sugerencias.

(fuente: Wikipedia)

 

Atentamente

AnalíticaGráficosScriptinginkRe: Presentación de datos de existencias en forma de diagrama de caja

Creo que esto es lo mejor que puede hacer JMP sin scripts

Pero con un poco de esfuerzo, se podría escribir fácilmente un JSL que crearía los gráficos de Candlestick.

Re: presentación de datos de existencias en forma de diagrama de caja

Sí, como señala Jim, Graph Builder puede hacer esto fácilmente. Sin embargo, a medida que obtenga más datos, es posible que desee considerar los IR (gráficos de rango móvil individuales), ya que proporcionarán información sobre la coherencia / estabilidad de las métricas a lo largo del tiempo.

Re: presentación de datos de existencias en forma de diagrama de caja

Tuve un poco más de tiempo para investigar esto, y creo que la solución fácil a continuación podría ser una solución viable para usted.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Stock Prices.jmp" );

dt:open << label;
dt:close << label;

gb = dt << Graph Builder(
 Size( 1289, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :Date ), Y( :High ), Y( :Low, Position( 1 ) ) ),
 Elements( Bar( X, Y( 1 ), Y( 2 ), Legend( 10 ), Bar Style( "Interval" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Date",
   ScaleBox,
   { Interval( "Day" ), Inc( 1 ),
   Minor Ticks( 0 )}
  ),
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    10,
    Properties( 0, {Line Width( 2 )}, Item ID( "High..Low", 1 ) )
   )}
  )
 )
);

// Add the boxes to the chart
Report( gb )[framebox( 1 )] << add graphics script(
 halfDayincr = In Days( 1 ) / 2 * .8;
 days = (Col Max( :Date ) - Col Min( :Date )) / In Days( 1 );
 Pen Color( black );
 Pen Size( 2 );
 For( i = 1, i <= N Rows( dt ), i++,
  If( :Open[i] <= :close[i],
   Fill Color( light green );
  ,
   Fill Color( light red );
  );
  Rect( :date[i] - halfDayincr, Max( :open[i], :close[i] ), :date[i] + halfDayincr, Min( :open[i], :close[i] ), 1 );
  Rect( :date[i] - halfDayincr, Max( :open[i], :close[i] ), :date[i] + halfDayincr, Min( :open[i], :close[i] ), 0 );
 );
);