pass column as variable to function for use in distribution

alex

Hi,
I'm trying to pass the column name to a function and then use it in the Distribution but it comes back with:
A command within the Distribution script was not recognized.
No data to analyze.
it's the Column( varB) line with-in the distribution.
Thanks,
Alex (on Jmp 8)

RuntheGraphs = function ({varB},
show (varB);

Distribution(
Uniform Scaling( 0 ),
Continuous Distribution(
Column( varB),
Horizontal Layout( 1 ),
Vertical( 0 ),
Count Axis( 1 ),
Show Counts( 1 ),
Outlier Box Plot( 0 )
),
Where( :IPRO_TPT_Completed == 1 )
)/*distribution*/
);

c="Cut Sheet";
RuntheGraphs(eval(c));

Message was edited by: alex

mattf

Hi Alex:

Jump into JMP Scripting
By: Wendy Murphrey and Rosemary Lucas

https://support.sas.com/pubscat/bookdetails.jsp?catid=1&pc=61733

Provide an example:

<-

/* Solution 9.2 */

/* Open the Fitness sample data tableNi. */
dt = Open( "$SAMPLE_DATA/Fitness.jmp" );

/* Assign the criteria to a global variable. */
selVar = "M";
yvar = "MaxPulse";
xvar = "RstPulse";
/* Build the main expression. */
bivExpr = Expr(
Bivariate(
Y( :Expr(yvar) ),
X( :Expr(xvar) ),
/* Identify the global variable by wrapping it with the Expr function. */
Where( :sex == Expr( selVar ) )
)
);

/* Resolve the global variable expression first. Then resolve the main expression. */
Eval( Eval Expr( bivExpr ) );

Adapting to you particular example:

dt = Open( "$sample_data/Big Class.jmp" );

/* Assign the criteria to a global variable. */
c = "Height";

/* Build the main expression. */
dist = Expr(Distribution(
Continuous Distribution(
/* Identify the global variable by wrapping it with the Expr function. */
Column( :Expr( c ) ),
Horizontal Layout( 1 ),
Vertical( 0 ),
Fit Distribution( Normal )
)
)
);

/* Resolve the global variable expression first. Then resolve the main expression. */
Eval( Eval Expr( dist ) );

->

Best regards,
-Matt