314324_ja-JP

liliconcom

JSLを使用して構成ファイルから列名を更新する

こんにちはJMPユーザー、

 

JSLを使用して構成ファイルから列名を更新し、タイトルと軸に更新された列名が含まれるプロットを作成します。 私はこれをどのように行うことができるかについてのアイデアを探しています。

 

これまでのところ、コードとテーブルを添付しています。 助けてくれてありがとう。

 

最終的なグラフにしたいものを添付しました（desired_Bivariate）

 

-サイモン

Names Default To Here( 1 );
dt = Open( "table_1.jmp" );
dt1 = Open( "config_table.jmp" );
dt1 << New Column( "New Column", character, formula( Column_name || "_" || additional_name ) );

graph = dt << Bivariate( Y( :height ), X( :id ) );

 

スクリプティングRe：JSLを使用して構成ファイルから列名を更新する

これを試して：

Names Default To Here( 1 );
dt = Open( "table_1.jmp" );
dt1 = Open( "config_table.jmp" );

for(i = 1, i <= N Rows(dt1), i++,
 x = Column(dt1, "Column_name")[i];
 y = Column(dt1, "additional_name")[i];
 Column(dt, i) << Set Name( x || "_" || y);
);

Re：JSLを使用して構成ファイルから列名を更新する

これは、列の実際の名前を変更しないが、求めていることを実現する、この問題に対する2つの異なるアプローチです。1つ目は、2変量の実行に指定された新しい名前を持つTransform列を作成します。これらの列は、2変量の実行にのみ存在します。

2番目の例では、データテーブルのさまざまな列にUnitsColumnプロパティを使用します。JMPのプラットフォームは、Units列プロパティを尊重し、列名の後にUnits値を（）に配置することで、実際の列名への追加として表示します。

// This version of the script used Transform variables
// to temporarially change the name of the column just
// for the running of the Bivariate

Names Default To Here( 1 );
dt = Data Table( "table_1" );
dt1 = Data Table( "config_table" );

// Loop across the columns to run the Bivariate
For( i = 2, i <= N Cols( dt ), i++,
 // Check to see if a column name change is specified
 // in the config table
 foundRow = dt1 << get rows where(
  :Column_name == Column( dt, i ) << get name & dt1
  :additional_name != ""
 );
 // If a column name change is found make the change
 If( N Rows( foundRow ) > 0,
  Eval(
   Substitute(
     Expr(
      Bivariate(
       Y(
        Transform Column(
         __trans__,
         Formula( __col__ )
        )
       ),
       X( :id )
      )
     ),
    Expr( __trans__ ),
     dt1:Column_name[foundRow[1]] || "_" || dt1
     :additional_name[foundRow[1]],
    Expr( __col__ ),
     Parse( ":" || dt1:Column_name[foundRow[1]] )
   )
  ),
  // otherwise just run the bivariate
  dt << Bivariate( Y( Column( i ) ), X( :id ) )
 );
);

// This version of the script takes advantage of the Units
// column property.  It will automatically add (unit value) to
// the display output, without actually changing the columns
// name
Names Default To Here( 1 );
dt = Data Table( "table_1" );
dt1 = Data Table( "config_table" );

// Add the Units Column Property to the columns in the
// original data table
For( i = 1, i <= N Cols( dt ), i++,
 foundRow = dt1 << get rows where(
  :Column_name == Column( dt, i ) << get name & dt1
  :additional_name != ""
 );

 If( N Rows( foundRow ) > 0,
  column( dt, i ) << set property("units", eval(dt1:additional_name[foundRow[1]]));
 );
);

// Now run the normal bivariates
For( i = 2, i <= N Cols( dt ), i++,
 dt << Bivariate( Y( Column( i ) ), X( :id ) )
);