304523_it-IT

liliconcom

Crea la visualizzazione dell'espressione di previsione in base alla formula della colonna

Vorrei creare un'espressione di previsione formattata, basata su una formula di colonna, in una finestra di report personalizzata.  Quando si adatta un modello lineare utilizzando Adatta minimi quadrati, nel report del modello, è possibile attivare la visualizzazione dell'espressione di previsione, che mostra una vista "immagine" formattata dell'equazione.

 

Posso quindi salvare l'equazione nella tabella dati come colonna con una formula.  

 

Ora voglio selezionare quella colonna e visualizzare un'espressione di previsione per la formula salvata nella colonna, da sola, in una nuova finestra del report.  

 

C'è un modo per farlo con JSL?  

 

 

ScriptingRi: Crea la visualizzazione dell'espressione di previsione in base alla formula della colonna

Puoi semplicemente recuperare la formula con un messaggio << get formula passato alla colonna.

Names Default To Here( 1 );
dt = New Table( "Example",
 add rows( 10 ),
 New Column( "The Column", formula( Random Integer( 1, 100 ) ) )
);

theFormla = dt:The Column << get formula;

Ri: Crea la visualizzazione dell'espressione di previsione in base alla formula della colonna

Se stai cercando un'immagine dell'espressione di previsione, puoi utilizzare Espr As Picture ().

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );
obj = dt << Fit Model(
 Y( :y ),
 Effects( :Drug, :x ),
 Personality( Standard Least Squares ),
 Emphasis( Minimal Report ),
 Run
);
obj << Prediction Formula;


New Window( "Example",
 Lineup Box( N Col( 1 ), spacing( 10 ),
  Text Box( "Column Formula" ),
  Border Box( Left( 10 ), Right( 10 ), bottom( 10 ), top( 10 ), sides( 15 ),
   Expr As Picture( dt:pred formula y << get formula )
  )
 )
);

 

Ri: Crea la visualizzazione dell'espressione di previsione basata sulla formula della colonna

Grazie, è quello di cui avevo bisogno.  Sapevo che c'era un modo per farlo, semplicemente non riuscivo a ricordare il file Espr come immagine () oggetto di visualizzazione box.  

Ri: Crea la visualizzazione dell'espressione di previsione basata sulla formula della colonna

È passato un po 'di tempo da quando ho pubblicato questo e ho avuto una buona risposta.  Volevo condividere lo script che ho sviluppato per consentire la visualizzazione rapida delle formule nelle colonne di una tabella dati, consentendo di cambiare le colonne in modo interattivo.

 

/* this script presents a list of columns in the current data table
in a list box, and upon selecting a column, if the column has a formula, 
it will display the formula below the list box as a picture.  
If the column does not have a formula, "No Column Formula" is displayed
*/

Names Default To Here( 1 );
_dt = Current Data Table();

expr_ShowFormulaAsPicture = Expr(
 _vb1 << Delete;
 _vb << Append( _vb1 = V List Box() );
 _c = Column( dt, (_clb << Get Selected)[1] );
 If( Is Empty( _c << Get Property( "Formula" ) ),
  _vb1 << Append( Text Box( "No Column Formula" ) ),
  _vb1 << Append( Picture Box( Expr As Picture( _c << get formula ) ) )
 );
);


New Window( "Show Column Formula as Picture",
 _vb = V List Box(
  
 )
);

_vb << Append(
 _pb = Panel Box( "Select Column With Formula To Display as Picture",
  _clb = Col List Box(
   _dt,
   max selected( 1 ),
   grouped,
   all,
   On Change( expr_ShowFormulaAsPicture )
  )
 )
);

_vb << Append( _vb1 = V List Box() );

Finestra di esempio qui: