304523_es-ES

liliconcom

Crear visualización de expresión de predicción basada en la fórmula de columna

Me gustaría crear una expresión de predicción formateada, basada en una fórmula de columna, en una ventana de informe personalizada.  Cuando ajusto un modelo lineal usando Ajustar mínimos cuadrados, en el informe del modelo, puedo activar la visualización de la expresión de predicción, que muestra una vista de "imagen" formateada de la ecuación.

 

Luego puedo guardar la ecuación en la tabla de datos como una columna con una fórmula.  

 

Ahora quiero seleccionar esa columna y mostrar una expresión de predicción para la fórmula guardada en la columna, por sí sola, en una nueva ventana de informe.  

 

¿Hay alguna forma de hacer esto con JSL?  

 

 

ScriptingRe: Crear pantalla de expresión de predicción basada en fórmula de columna

Simplemente puede recuperar la fórmula con un mensaje << obtener fórmula pasado a la columna.

Names Default To Here( 1 );
dt = New Table( "Example",
 add rows( 10 ),
 New Column( "The Column", formula( Random Integer( 1, 100 ) ) )
);

theFormla = dt:The Column << get formula;

Re: Crear pantalla de expresión de predicción basada en fórmula de columna

Si está buscando una imagen de la expresión de predicción, puede usar Expr As Picture ().

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );
obj = dt << Fit Model(
 Y( :y ),
 Effects( :Drug, :x ),
 Personality( Standard Least Squares ),
 Emphasis( Minimal Report ),
 Run
);
obj << Prediction Formula;


New Window( "Example",
 Lineup Box( N Col( 1 ), spacing( 10 ),
  Text Box( "Column Formula" ),
  Border Box( Left( 10 ), Right( 10 ), bottom( 10 ), top( 10 ), sides( 15 ),
   Expr As Picture( dt:pred formula y << get formula )
  )
 )
);

 

Re: Crear pantalla de expresión de predicción basada en fórmula de columna

Gracias, eso es lo que necesitaba.  Sabía que había una manera de hacerlo, simplemente no podía recordar la Expr como imagen () objeto de visualización de caja.  

Re: Crear pantalla de expresión de predicción basada en fórmula de columna

Ha pasado un tiempo desde que publiqué esto y obtuve una buena respuesta.  Quería compartir el script que desarrollé para permitir ver rápidamente las fórmulas en columnas en una tabla de datos, lo que permite cambiar las columnas de forma interactiva.

 

/* this script presents a list of columns in the current data table
in a list box, and upon selecting a column, if the column has a formula, 
it will display the formula below the list box as a picture.  
If the column does not have a formula, "No Column Formula" is displayed
*/

Names Default To Here( 1 );
_dt = Current Data Table();

expr_ShowFormulaAsPicture = Expr(
 _vb1 << Delete;
 _vb << Append( _vb1 = V List Box() );
 _c = Column( dt, (_clb << Get Selected)[1] );
 If( Is Empty( _c << Get Property( "Formula" ) ),
  _vb1 << Append( Text Box( "No Column Formula" ) ),
  _vb1 << Append( Picture Box( Expr As Picture( _c << get formula ) ) )
 );
);


New Window( "Show Column Formula as Picture",
 _vb = V List Box(
  
 )
);

_vb << Append(
 _pb = Panel Box( "Select Column With Formula To Display as Picture",
  _clb = Col List Box(
   _dt,
   max selected( 1 ),
   grouped,
   all,
   On Change( expr_ShowFormulaAsPicture )
  )
 )
);

_vb << Append( _vb1 = V List Box() );

Ventana de ejemplo aquí: