304523_fr-FR

liliconcom

Créer un affichage d'expression de prédiction basé sur une formule de colonne

Je souhaite créer une expression de prédiction formatée, basée sur une formule de colonne, dans une fenêtre de rapport personnalisée.  Lorsque j'adapte un modèle linéaire à l'aide de Ajuster les moindres carrés, dans le rapport du modèle, je peux activer l'affichage de l'expression de prédiction, qui affiche une vue «image» formatée de l'équation.

 

Je peux ensuite enregistrer l'équation dans la table de données sous forme de colonne avec une formule.  

 

Maintenant, je veux sélectionner cette colonne et afficher une expression de prédiction pour la formule enregistrée dans la colonne, toute seule, dans une nouvelle fenêtre de rapport.  

 

Existe-t-il un moyen de faire cela avec JSL?  

 

 

ScriptingRe: Créer un affichage d'expression de prédiction basé sur une formule de colonne

Vous pouvez simplement récupérer la formule avec un message << get formula passé à la colonne.

Names Default To Here( 1 );
dt = New Table( "Example",
 add rows( 10 ),
 New Column( "The Column", formula( Random Integer( 1, 100 ) ) )
);

theFormla = dt:The Column << get formula;

Re: Créer un affichage d'expression de prédiction basé sur une formule de colonne

Si vous recherchez une image de l'expression de prédiction, vous pouvez utiliser Expr As Picture ().

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );
obj = dt << Fit Model(
 Y( :y ),
 Effects( :Drug, :x ),
 Personality( Standard Least Squares ),
 Emphasis( Minimal Report ),
 Run
);
obj << Prediction Formula;


New Window( "Example",
 Lineup Box( N Col( 1 ), spacing( 10 ),
  Text Box( "Column Formula" ),
  Border Box( Left( 10 ), Right( 10 ), bottom( 10 ), top( 10 ), sides( 15 ),
   Expr As Picture( dt:pred formula y << get formula )
  )
 )
);

 

Re: Créer un affichage d'expression de prédiction basé sur une formule de colonne

Merci, c'est ce dont j'avais besoin.  Je savais qu'il y avait un moyen de le faire, je ne pouvais tout simplement pas me souvenir du Expr comme image () objet d'affichage de boîte.  

Re: Créer un affichage d'expression de prédiction basé sur une formule de colonne

Cela fait un moment que j'ai posté ceci et j'ai obtenu une bonne réponse.  Je voulais partager le script que j'ai développé pour permettre de visualiser rapidement les formules en colonnes dans une table de données, permettant de changer de colonne de manière interactive.

 

/* this script presents a list of columns in the current data table
in a list box, and upon selecting a column, if the column has a formula, 
it will display the formula below the list box as a picture.  
If the column does not have a formula, "No Column Formula" is displayed
*/

Names Default To Here( 1 );
_dt = Current Data Table();

expr_ShowFormulaAsPicture = Expr(
 _vb1 << Delete;
 _vb << Append( _vb1 = V List Box() );
 _c = Column( dt, (_clb << Get Selected)[1] );
 If( Is Empty( _c << Get Property( "Formula" ) ),
  _vb1 << Append( Text Box( "No Column Formula" ) ),
  _vb1 << Append( Picture Box( Expr As Picture( _c << get formula ) ) )
 );
);


New Window( "Show Column Formula as Picture",
 _vb = V List Box(
  
 )
);

_vb << Append(
 _pb = Panel Box( "Select Column With Formula To Display as Picture",
  _clb = Col List Box(
   _dt,
   max selected( 1 ),
   grouped,
   all,
   On Change( expr_ShowFormulaAsPicture )
  )
 )
);

_vb << Append( _vb1 = V List Box() );

Exemple de fenêtre ici: