304444_zh-TW

liliconcom

表轉換查詢

我在JMP中重新格式化表格數據有困難。我希望將表格從“積分”格式轉換為“每週分數格式”，例如

 

從：

 

週1st_Name 1st_Score 2nd_Name 2nd_Score 3rd_Name 3rd_Score

1大衛5提姆2拉結1

2蒂姆7亞歷克西斯4雷切爾2

3蒂娜6雷切爾5大衛2

 

至：

 

周大衛·蒂姆·雷切爾·亞歷克西斯·蒂娜

1 5 2 1 0 0

2 0 7 2 4 0

3 2 0 5 0 6

 

如果可以更方便地重新設置格式，則可以在原始數據提取中對列進行不同的排序。

如果有人能夠提供幫助，我將非常感謝。

數據表腳本編寫回复：表轉換查詢

這很容易做到。  

互動式您：

1. 堆疊在“堆疊”對話框中指定的名稱和分數以使用多系列堆疊
2. 然後拆分堆疊表
   1. 按列數據拆分
   2. 將列Data2指定為拆分列
3. 然後，您將需要遍歷每一列，然後選擇缺失值並將其更改為0

這是一個腳本，根據您的示例數據說明了解決方案

Names Default To Here( 1 );
dt = New Table( "Example",
 Add Rows( 3 ),
 New Column( "Week", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 2, 3] ) ),
 New Column( "1st_Name", Character, "Nominal", Set Values( {"David", "Tim", "Tina"} ) ),
 New Column( "1st_Score", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [5, 7, 6] ) ),
 New Column( "2nd_Name", Character, "Nominal", Set Values( {"Tim", "Alexis", "Rachel"} ) ),
 New Column( "2nd_Score", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 4, 5] ) ),
 New Column( "3rd_Name", Character, "Nominal", Set Values( {"Rachel", "Rachel", "David"} ) ),
 New Column( "3rd_Score", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 2, 3] ) )
);

dtStack = dt << Stack(
 columns(
  :"1st_Name"n,
  :"1st_Score"n,
  :"2nd_Name"n,
  :"2nd_Score"n,
  :"3rd_Name"n,
  :"3rd_Score"n
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ),
 Number of Series( 2 ),
 Output Table( "Stacked Data" )
);

dtFinal = dtStack << Split(
 Split By( :Data ),
 Split( :Data 2 ),
 Remaining Columns( Drop All ),
 Sort by Column Property
);

For( i=1, i<=N Cols(dtFinal), i++,
 missing = dtFinal << get rows where( isMissing(as column( i )));
 try(column(i)[missing]=0);
);