304444_it-IT

liliconcom

Query di trasformazione della tabella

Ho difficoltà a riformattare i dati di una tabella in JMP. Spero di trasformare una tabella da un formato "classifica" a "formato punteggio settimanale", ad es

 

A partire dal:

 

Settimana 1st_Name 1st_Score 2nd_Name 2nd_Score 3rd_Name 3rd_Score

1 Davide 5 Tim 2 Rachele 1

2 Tim 7 Alexis 4 Rachel 2

3 Tina 6 Rachel 5 David 2

 

Per:

 

Settimana David Tim Rachel Alexis Tina

1 5 2 1 0 0

2 0 7 2 4 0

3 2 0 5 0 6

 

Posso ordinare le colonne in modo diverso nell'estrazione dati originale se ciò semplifica la riformattazione.

Se qualcuno è in grado di aiutare con questo, gliene sarei molto grato.

Tabella datiScriptingOggetto: query di trasformazione della tabella

È facile da fare.  

In modo interattivo:

1. Impila i nomi e i punteggi specificando nella finestra di dialogo Pila di utilizzare Pila di serie multiple
2. Quindi dividi il tavolo impilato
   1. Dividi per dati della colonna
   2. Specificare la colonna Data2 come Split Column
3. Quindi dovrai passare attraverso ogni colonna e selezionare e modificare i valori mancanti su 0

Ecco uno script che illustra la soluzione in base ai dati di esempio

Names Default To Here( 1 );
dt = New Table( "Example",
 Add Rows( 3 ),
 New Column( "Week", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 2, 3] ) ),
 New Column( "1st_Name", Character, "Nominal", Set Values( {"David", "Tim", "Tina"} ) ),
 New Column( "1st_Score", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [5, 7, 6] ) ),
 New Column( "2nd_Name", Character, "Nominal", Set Values( {"Tim", "Alexis", "Rachel"} ) ),
 New Column( "2nd_Score", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 4, 5] ) ),
 New Column( "3rd_Name", Character, "Nominal", Set Values( {"Rachel", "Rachel", "David"} ) ),
 New Column( "3rd_Score", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 2, 3] ) )
);

dtStack = dt << Stack(
 columns(
  :"1st_Name"n,
  :"1st_Score"n,
  :"2nd_Name"n,
  :"2nd_Score"n,
  :"3rd_Name"n,
  :"3rd_Score"n
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ),
 Number of Series( 2 ),
 Output Table( "Stacked Data" )
);

dtFinal = dtStack << Split(
 Split By( :Data ),
 Split( :Data 2 ),
 Remaining Columns( Drop All ),
 Sort by Column Property
);

For( i=1, i<=N Cols(dtFinal), i++,
 missing = dtFinal << get rows where( isMissing(as column( i )));
 try(column(i)[missing]=0);
);