Need Help with JSL for Pressure Compensated Temperature Formula

Question

Hello,

I am looking for an example or some guidance on how to get started writing JSL for the following Pressure Compensated Temperature:

* Create a UI to select a Temperature column and Pressure Column.  Also have user input a Reference Pressure, Conversion Factor, Purity factor.
* Calculate the Pressure Compensated Temperature for each row using several IF statements and mathematical expressions using the UI data.
* Create a new column and fill it in with the Pressure Compensated Temperature calculated above.

Any help is appreciated!

txnelson · Accepted Answer

* Read the Scripting Guide in the JMP Documentation Library downloaded when JMP was installed
* I can help you a bit with the UI, but "Calculate the Pressure Compensated Temperature for each row using several IF statements and mathematical expressions using the UI data."  is too vague to really guide you.

Here is the JSL for the above.  You will just need to take the info from the window and plug it into your formulas.  Read the sections in the documentation on Column Dialog() and on New Column()

names default to here(1);
dtList = New Table("Example Data",
	new column("Temperature"),
	new column("Pressure")
);

dlg = Column Dialog(
	temperatureCol = ColList( "Temperature", Min Col( 1 ), Max Col( 2 ), Data Type( "Numeric" ) ),
	pressureCol = ColList( "Pressure", Max Col( 1 ), Modeling Type( {"Continuous", "Multiple Response"} ) ),
	Line Up( 2,
		Text Box( "Reference Pressure" ), refPressure = EditNumber( . ),
		Text Box( "Conversion Factor" ), conFactor = EditNumber( . ),
		Text Box( "Purity Factor" ), purFactor = EditNumber( . )
	));

show(dlg);

Craige_Hales · Accepted Answer

Cool! not sure I ever used column dialog, but it seems perfect for this job.

After you get Jim's example running, try some code like this to add a formula column to your table.

Eval( // run the code below
	Eval Expr( // convert the Expr(...) below into a hard coded value
		// eval(evalexpr(expr(...))) is a pattern for getting values from the dlg INTO
		// A FORMULA. if you follow this pattern, the formula will be self contained.
		dtList << New Column( "adjusted",
			formula( // random formula that uses all the variables AND shows an if() stmt
				If( Expr( dlg["refPressure"] ) > Expr( dlg["pressureCol"][1] ), 
					Expr( dlg["temperatureCol"][1] ) + // first item of list
					Expr( dlg["pressureCol"][1] ) + //
					Expr( dlg["conFactor"] ) + // simple value
					Expr( dlg["purFactor"] ) + //
					Expr( dlg["refPressure"] )// do the ususal stuff...
				, // else refPressure <= pressureCol...
					Expr( dlg["temperatureCol"][1] ) + // first item of list
					Expr( dlg["pressureCol"][1] ) + //
					Expr( dlg["conFactor"] ) + // simple value
					Expr( dlg["purFactor"] ) + //
					Sqrt( Expr( dlg["refPressure"] ) )// do something extra for low ref
				)
			)
		)
	)
);

There are several things going on here.

* formula() does not evaluate its argument, so you have to give it some help
* I fall back on the eval(evalexpr(expr(...))) technique. There are other ways.
* you said you need an if(...) so I made one. You can use any JSL you like that produces a simple number for a result. The result of an if() is the last value it computes.
* if you need to use a variable more than once in your formula, look at the formula above.
* Clearly my formula is not the one you are looking for!
* For simple formulas, you don't need all the evalexpr stuff. formula(:pressure * :temperature) works fine. But in this example, you don't know the names of the columns; instead you know the name of a variable that holds the name of the column.

for reference, the dlg returns this list:

// this is what the dlg returns; the columns are a list of 1 item
// and the parameters are simple values:
//
// {temperatureCol = {:Temperature}, pressureCol = {:Pressure}, 
// Text Box, refPressure = 3, Text Box, conFactor = 33, 
// Text Box, purFactor = 333, Button( 1 )}

Finally, be sure to look at the formula you created using the formula editor to make sure it is really what you expect!

Click the + next to the column name to open the formula in the editor