Hallo Anders,
ja das
query_terms = dt3:organism id << get values;
ist im Grunde der Schlüssel, um all diese Werte zu erhalten.
Und Sie haben Recht, es gibt hier eine Einschränkung bei Sequoia. Wenn Sie dies mit 1000
Die Antwort, die Sequoia Ihnen gibt, hat ähnliche Einschränkungen wie die Webansicht. Sie zeigt nur so viel an, dass Sie nach der nächsten "Seite" der Ergebnisse fragen müssen. Eine Umgehung für den Moment wäre, dass Sie etwas mehr Code hinzufügen, der die Anzahl der Elemente in Ihrer query_items-Liste zählt, und dann die Abfrage schleifen, um Teilmengen dieser Daten in jeder Runde der Schleife abzurufen.
Etwas in der Art von Schleifen = N Elemente (Abfragetermine) / (Anzahl_der_Max_Ergebnisse_von_Sequoia) und dann eine Schleife Für i = 1, i
Hoffentlich hilft das,
Alex
Danke Alexander,
Ich habe es für kleinere Datentabellen verwendet, aber bei Verwendung größerer Listen (> 1000 Einträge) erhalte ich keine Antwort. Ist das vielleicht eine Einschränkung in Sequoia?
Ansonsten denke ich, dass das Skript Daten sehr schnell abruft.
Hier ist eine kleine Änderung, die ich vorgenommen habe, um ~ 10 Organism ID-Einträge aus einer Datentabelle aufzurufen.
dt3 = Open("N:\Projects\High pH Amylase\ADW_GODperid\Summary data\Joined_data_Screening to FSW.xlsx",
0,
0,
0,
0);
Namespace("JSON") << show contents;
base_url = "http://nzdb.nzcorp.net/organism/all/large" || "?accept=application%2Fjson";
query_columns = {"identifier", "code", "synonym", "from"};
cols = "&cols=" || Concat Items(query_columns, "%2C" );
query_terms = dt3:organism id << get values;
query = "&q=" || Concat Items(query_terms, " OR " );;
url = base_url ||cols || query;
show(url);
dt = JSON:Make Table( open(url, HTML Table(2)) );
close (dt3, nosave);
Hallo,
Es ist möglich, aber Sie müssen es selbst skripten, da kein vorkonfiguriertes Skript bereitsteht. Ich verbringe jedoch nur einige Zeit damit, ein kleines Beispiel zusammenzustellen. Sie können wahrscheinlich herausfinden, wie Sie dies verwenden können, um die gewünschten Informationen von SEQUOIA zu erhalten. Erwarten Sie nicht, dass dies sehr schnell ausgeführt wird, da es einen anderen Weg gibt, der jedoch eine weitere Vorkonfiguration erfordert (kurz: Fügen Sie den Datensee als Datenquelle in JMP hinzu und verwenden Sie dann SQL-Abfragen, um die gewünschten Informationen zu erhalten gerne bekommen).
Das Skript, das ich aufgenommen habe, besteht aus einem großen Teil des Codes, der die JSON-formatierte Antwort von SEQUOIA analysiert. Damit müssen Sie nichts anfangen. Darunter befinden sich einige Codezeilen, die Ihnen zeigen, wie Sie die Informationen abfragen und in eine JMP-Tabelle übertragen, die Sie dann in JMP weiter maninpulieren können, um sie mit Ihren Daten zu verknüpfen.
Beachten Sie, dass Sie Änderungen vornehmen müssen gereinigte Probe je nachdem wo / was in SEQUOIA Sie suchen.
Dies ist der Teil des Codes, den Sie bearbeiten müssten, um die Daten, an denen Sie interessiert sind, in JMP zu übertragen:
base_url = "http://nzdb.nzcorp.net/purifiedsample/all/large" || "?accept=application%2Fjson";
query_columns = {"organism_code","identifier", "a280"};
cols = "&cols=" || Concat Items(query_columns, "%2C" );
query_terms = {"U6ESJ","U8GF4"};
query = "&q=" || Concat Items(query_terms, " OR " );;
url = base_url ||cols || query;
show(url);
dt = JSON:Make Table( open(url, HTML Table(2)) ); (Der obige Code benötigt einige zusätzliche Funktionen, die im jsl-Skript enthalten sind, das diesem Beitrag beigefügt ist. Laden Sie die * .jsl-Datei herunter, um das Beispiel auszuführen.)
Als Referenz ist dies das vollständige Skript:
New Namespace("JSON",
{
Char Escape = Function({c},
Match(c,
"\!"", "\!"",
"b", "\!u0008",
"f", "\!u000C",
"n", "\!u000A",
"r", "\!u000D",
"t", "\!u0009",
c
)
);
,
Unicode Escape = Function( {u},
u = "\!"\!\!u" || u || "\!"";
Parse( u );
);
,
Pattern Name =
"\!"" // leading quotation mark
+ pattest( value = ""; 1) // init string accumulator
+ patrepeat(
(Pat break( "\!\\!"" ) >> temp + Pat Test( value ||= temp; 1; )) // run of characters that are not \ or "
|
("\u"+patlen(4)>>temp+pattest(value ||= JSON:Unicode Escape(temp);1)) // \uXXXX
|
("\"+patlen(1)>>temp+pattest(value ||= JSON:Char Escape(temp);1)) // \", for example...embedded quotation mark
)
+ "\!""; // trailing quotation mark
,
Pattern Number = patspan("0123456789-+eE.") >> temp + pattest(value=num(temp);1);
,
starttime=0;
,
progressTable=0;
,
progress = Function( {p},
If( Is Empty( JSON:progressTable ),
JSON:progressTable = New Table( "JSON Parsing Progress Log", New Column( "Time" ), New Column( "Percent" ) );
JSON:progressTable << Graph Builder(
Show Control Panel( 0 ),
Variables( X( :Time ), Y( :Percent ) ),
Elements(
Points( X, Y, Legend( 1 ), Jitter( 1 ) ),
Line Of Fit(
X,
Y,
Legend( 3 ),
Confidence of Fit( 1 ),
Confidence of Prediction( 0 ),
Degree( "Linear" ),
Equation( 0 ),
Root Mean Square Error( 0 ),
R²( 0 )
)
)
);
);
JSON:progressTable << addrows( 1 );
JSON:progressTable:time = Tick Seconds() - JSON:starttime;
JSON:progressTable:percent = 100 * p;
);
,
PatternParse = patpos(0) + patrepeat(patpos(/* remember how far we parsed for error message */)>>failpos
/* comment out this line for a little more speed */+pattest(if(tickseconds()-lasttime>1,JSON:progress(failpos/totalLen);lasttime=tickseconds();wait(0));1)
+patfence(/* fence off previously parsed text...ain't no going back */)
+( patregex("\s*") // ignore whitespace
| JSON:Pattern Name
| ( ":" + pattest(key=value;1) )
| JSON:Pattern Number
| ("true" + pattest(value = 1;1))
| ("false" + pattest(value = 0;1))
| ("null" + pattest(value = .;1))
| ("[" + pattest(Insert Into( stack, {{}}, 1 );value = Empty();1))
| ("{" + pattest(Insert Into( stack, Associative Array(), 1 );value = Empty();Insert Into( keys, key, 1 );1))
| ("]" + pattest(If( !Is Empty( value ),Insert Into( stack[1], value, 1 /*needs reverse later*/ ));value = stack[1];value=reverse(value);Remove From( stack, 1 );1))
| ("}" + pattest(If( !Is Empty( value ),stack[1][key] = value);value = stack[1];Remove From( stack, 1 );key = keys[1];Remove From( keys, 1 );1))
| ("," + pattest(If( Is List( stack[1] ),Insert Into( stack[1], value, 1 /*needs reverse later*/ ),stack[1][key] = value);value = Empty();1))
)) + patrpos(0);
,
Parse = Function( {json},
{stack = {}, keys = {}, key = "", value = Empty(), temp=0,totalLen = length(json),lasttime = tickseconds(),failpos=0},
JSON:starttime = tickseconds();
JSON:progressTable=empty();
if( !try(patmatch(json,JSON:PatternParse),0), Throw( "unrecognized JSON at " || Char( failpos ) ));
value;
);
,
Append Rows = Function( {dt, start, prefix, a},
{key, value, dc, c, nc, r, delta, added = 0},
If(
Is List( a ),
For( r = 1, r <= Length( a ), r++,
delta = JSON:Append Rows( dt, start + added, prefix, a[r] );
added += delta;
);
// fill empty cells
nc = N Col( dt );
For( c = 1, c <= nc, c++,
dc = Column( dt, c );
value = dc[start];
For( r = start + 1, r <= N Row( dt ), r++,
If( dc[r] == "",
dc[r] = value
)
);
);,
Is Associative Array( a ),
key = a << First;
While( !Is Empty( key ),
value = a[key];
delta = JSON:Append Rows( dt, start, If( prefix == "", key, prefix || "." || key ), value );
added = Max( added, delta );
key = a << Next( key );
);,
// else a literal
If( prefix == "",
prefix = "v"
); // can only happen in a top array of literals
dc = Try( Column( dt, prefix ), dt << New Column( prefix, "Character" ) );
added = 1; // don't count padding
If( N Rows( dt ) < start,
dt << Add Rows( start - N Rows( dt ) )
);
// fill to end in case a previous column was a JSON array
For( r = start, r <= N Rows( dt ), r++,
dc[r] = Char( a )
);
);
added;
);
,
Make Table = Function( {json},
{dt},
If( Is String( json ),
json = JSON:Parse( json )
);
dt = New Table();
dt << Begin Data Update();
JSON:Append Rows( dt, N Rows( dt ) + 1, "", json );
dt << End Data Update();
dt;
);
}); // end namespace
Delete Globals();
Namespace("JSON") << show contents;
base_url = "http://nzdb.nzcorp.net/purifiedsample/all/large" || "?accept=application%2Fjson";
query_columns = {"organism_code","identifier", "a280"};
cols = "&cols=" || Concat Items(query_columns, "%2C" );
query_terms = {"U6ESJ","U8GF4"};
query = "&q=" || Concat Items(query_terms, " OR " );;
url = base_url ||cols || query;
show(url);
dt = JSON:Make Table( open(url, HTML Table(2)) );