Not sure is this is possible...

UberBock

I have a data table that has a column which is either a 1 or 2 (its called channel).  In another column there is a designation of a 'test'.  It is numeric like 10 or 20 or 30.   

What I would like is to create another column that concates all the 'test' for channel 1 and then for channel 2.  So each line of data will have a column that has the concat of the test based on channel.   So it may look like 10|30|80 for channel 1 but 20|40|30 for channel 2.   

 

The data table could have 1000's lines of result data from different tests.  I am interested in seeing what channel uses which test by machine.  Since different machines can have different tests on different channels.

 

I might also need to add another qualifier.  So that the 'test' is  concate by not only by channel channel but also machine (which denoted by a serial number).

 

This would be in script for to include into a post-script query.

 

Any suggestions are appreciated! 

txnelson

Here is a script that calculates the tests into a single column.  Just make your table with the testnumber data the active data table, by clicking on it, and then run this script.

names default to here(1);

// Set up a handle to point to the example data table
dt=current data table();

// Find the testnumbers for each machine/channel combination
dtSumm = dt << summary(
	Group( :Machine, :Channel,:testnumber),
	N,
	Link to original data table(0)
);

// Create a new table to accumulate the testnumbers into a single value
dtFinal = New Table("Concat Test Number",
	New Column("Machine", character),
	New Column("Channel"),
	New Column("Tests", character)
);

For(i=1,i<=N Rows(dtSumm), i++,
	If(i==1,
		dtFinal << add Rows(1);
		dtFinal:Machine[N Rows(dtFinal)] = dtSumm:Machine[i];
		dtFinal:Channel[N Rows(dtFinal)] = dtSumm:Channel[i];
		dtFinal:Tests[N Rows(dtFinal)] = char( dtSumm:testnumber[i])
	,
	dtSumm:Machine[i] != dtSumm:Machine[i-1] |
		dtSumm:Channel[i] != dtSumm:Channel[i-1]
		,
		dtFinal << add Rows(1);
		dtFinal:Machine[N Rows(dtFinal)] = dtSumm:Machine[i];
		dtFinal:Channel[N Rows(dtFinal)] = dtSumm:Channel[i];
		dtFinal:Tests[N Rows(dtFinal)] = char( dtSumm:testnumber[i])
	,
	dtFinal:Tests[N Rows(dtFinal)] = dtFinal:Tests[N Rows(dtFinal)] || "/" || char( dtSumm:testnumber[i])
 	)
);

// Merge the new column back to the origianl table
dt = dt << Update(
	With( dtFinal ),
	Match Columns( :Machine = :Machine, :channel = :Channel )
);

close( dtSumm, nosave );
close( dtFinal, nosave );