286908_de-DE

liliconcom

Hinzufügen eines Werts zum Ende der Trendlinie

Ich habe eine Marke bei 1800 RFh gesetzt und meine Trendlinie zeigt, dass ich am Ende dieses Berichtszeitraums die Marke überschritten habe.

Wie kann ich jedoch am Ende der Trendlinie einen Wert hinzufügen, um den von JMP berechneten Wert anzuzeigen? Vorausgesetzt, Lamda ist Standard.

MassenanpassungBetreff: Hinzufügen eines Werts zum Ende der Trendlinie

@Salbei ,

 

JMP-Plattformen sind die Optionen unter Analyse und Diagramme. Die Anpassung von Y an X mit kontinuierlichem Y und X wird beispielsweise als bivariat bezeichnet. kontinuierliches Y und nominales X heißt Oneway oder wie in meinem Beitrag GraphBuilder dokumentiert.Ihr Diagramm sah aus wie ein Trend oder eine Zeitreihe. Ich wollte also sagen, dass ich nicht feststellen konnte, wie Sie die Grafik in Ihrem ursprünglichen Beitrag erstellt haben.

 

Die JMP-Meldungen (Befehle) zum Speichern der Werte oder Formeln der geglätteten Kurve können je nach Plattform unterschiedlich sein.Wenn Sie das Skript (Option mit umgekehrtem rotem Dreieck) für Ihr Diagramm im Skriptfenster speichern und veröffentlichen, könnte ein Skript bereitgestellt werden, das für Ihr Diagramm geeignet wäre.Vergessen Sie nicht, vor dem Posten Namen oder Werte zu ändern, die möglicherweise geschützte Informationen enthalten.

Betreff: Hinzufügen eines Werts zum Ende der Trendlinie

Danke!

Lass mich herumspielen und es herausfinden. Aufgrund von Covid-19 habe ich den JMP-Kurs noch nicht besucht.

Was meinst du mit Plattform? Ich verwende Version 15.1

Betreff: Hinzufügen eines Werts zum Ende der Trendlinie

@Salbei ,

 

Ich kann nicht erkennen, welche Plattform Sie verwenden.Hier ist ein Skript, das den letzten Wert eines Smoothers von der GraphBuilder-Plattform hinzufügt.Der Schlüssel hier besteht darin, die glatteren Werte in der Datentabelle zu speichern. Sie können diese neue Spalte mit glatteren Werten später löschen. Es sind einige Schritte erforderlich, um den letzten Wert zu finden, die x-Achse zu erweitern und den Text hinzuzufügen.

Names Default To Here( 1 );
dt = Open( "$sample_Data/Big Class.jmp" );

gb = dt << Graph Builder(
 Variables( X( :height ), Y( :weight ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
);

//get row where max X
xmax = Col Max( :height );
idx = (dt << get rows where( :height == xmax ))[1];
gbb = Report( gb )[Graph Builder Box( 1 )];
Wait( 0.5 );<BR /><BR />//smoother is the second element, save to the data table
gbb << Update Element( 1, 1, 2, {Save Formula} );

//smoother is in the last col

lastVal = Round( Column( dt, N Col( dt ) )[idx], 2 );

// here is the tricky part, if you want to annotate this to teh right of xmax you need to extend the x axis
gb_x = gbb[GraphBuilderAxisBox( 1 )];

xaxis_inc = gb_x << get inc;
xaxis_max = gb_x << get max;

//add a half inc ?? arbitrary

gb_x << Max( xaxis_max + 0.5 * xaxis_inc );

Eval(
 Eval Expr(
  gbb[FrameBox( 1 )] << Add Graphics Script(
   Text Font( "Arial", 10, "Bold" );
   Text Color( "Red" );
   Text( {Expr( xmax + 0.1 * xaxis_inc ), Expr( lastVal )}, Expr( Char( lastVal ) ) );
  )
 )
);