286546_fr-FR

liliconcom

Le script exécute automatiquement tout le sous-ensemble sélectionné

Salut,

existe-t-il une possibilité d'exécuter automatiquement toutes les colonnes de sous-ensemble par nom qui se composent de plus de 50 noms en même temps ?

lorsque j'ai fait un sous-ensemble par nom, j'obtiens toutes les données détaillées que je veux, mais je dois cliquer une par une pour exécuter l'analyse d'ajustement y par x. existe-t-il un moyen pour moi de tout sélectionner et d'exécuter automatiquement l'analyse d'ajustement y par x ? le nom de tous ces sous-ensembles peut changer à chaque fois.

Fusion et nettoyage des donnéesExploration et visualisation des donnéesRe : Script d'exécution automatique de tous les sous-ensembles sélectionnés

@tikhahabusamah

Supprimez ma solution ( @txnelson ) et sélectionnez @ts2 comme solution.C'est une meilleure solution !

Re : Script d'exécution automatique de tous les sous-ensembles sélectionnés

Pour votre information, lors du sous-ensemble, vous pouvez affecter vos tables de sous-ensemble sous forme de liste plutôt que d'utiliser N Table (), ce qui pourrait être problématique si vous avez un tas d'autres tables ouvertes (y compris généralement le sous-ensemble de table d'origine).

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/big class.jmp" );

// Perform the subsets
listDT = dt << Subset(
 By( :age ),
 All rows,
 Selected columns only( 0 ),
 columns( :name, :sex, :height, :weight )
);

// Loop across all new data tables and run Fit Y by X
For( i = 1, i <= N Items( listDT ), i++,
 listDT[i] << Bivariate( Y( :height ), X( :weight ) )
);

Re : Script d'exécution automatique de tous les sous-ensembles sélectionnés

Le problème est la valeur d'arrêt de votre boucle For().Vous spécifiez

For( i = 1, i <= N Table() - numDT, i++,

puis dans votre code, vous créez une nouvelle table de données, donc la prochaine fois que la boucle se produira, la valeur de

N Table()

a augmenté d'un nombre supplémentaire, de sorte que la variable 'i' ne peut jamais atteindre la valeur actuelle de N Table ()

Re : Script d'exécution automatique de tous les sous-ensembles sélectionnés

J'essaie de diviser par nom après le sous-ensemble, ce qui est avant que la table d'exécution ne corresponde à Y par X, mais chaque fois que j'essaie d'exécuter JMP, il ne répond plus. pourquoi ?

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/big class.jmp" );

// Get the current number of data tables
numDT = N Table();

// Perform the subsets
dt << Subset( By( :age ), All rows, Selected columns only( 0 ), columns( :name, :sex, :height, :weight ) );

// Loop across all new data tables and run Fit Y by X
For( i = 1, i <= N Table() - numDT, i++,
    Data Table( i ) << Split( Split By( :name ), Split( :sex, :height, :weight ) )
);

Re : Script d'exécution automatique de tous les sous-ensembles sélectionnés

Voici un petit script qui montre et un exemple d'une façon de faire ce que vous voulez

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/big class.jmp" );

// Get the current number of data tables
numDT = N Table();

// Perform the subsets
dt << Subset(
 By( :age ),
 All rows,
 Selected columns only( 0 ),
 columns( :name, :sex, :height, :weight )
);

// Loop across all new data tables and run Fit Y by X
For( i = 1, i <= N Table() - numDT, i++,
 Data Table( i ) << Bivariate( Y( :height ), X( :weight ) )
);