286284_es-ES

liliconcom

¿Existe una manera fácil de crear ID de conjuntos para conjuntos de datos dentro de una tabla de datos?

Tengo un número arbitrario de columnas que definen las entradas a un proceso, y un montón de otras columnas que son las salidas, y para cada conjunto de entradas hay un montón de filas de salida que están codificadas a tiempo.

 

¿Es posible con .jsl crear una nueva columna "setid" que comience con "1" en la fila 1, luego tome las columnas seleccionadas por el usuario (1 o más) y cada vez que cambie alguno de los valores en cualquiera de esas columnas, se incrementará el valor en la columna setid; de lo contrario, el setid permanece igual.  Podemos suponer que las filas están ordenadas razonablemente por conjunto.

Tabla de datosScriptingRe: ¿Existe una manera fácil de crear ID de conjuntos para conjuntos de datos dentro de una tabla de datos?

Aquí hay un pequeño ejemplo con el que puede comenzar.  Desenterré un código antiguo que hice hace muchos años y lo modifiqué.  Primero aparece un cuadro de diálogo

Y después de seleccionar las columnas, hace clic en Aceptar y crea la nueva columna.

Si no ha leído la Guía de secuencias de comandos ... ahora debería hacerlo.  Para ampliar este sencillo script, deberá comprender JSL y lo que puede hacer con él.  Aqui esta el guion

Clear Symbols();

Names Default To Here( 1 );
dt = Current Data Table();

allcolumnslist = dt << get column names( "string" );

nw = New Window( "Generate SETID Column",
 Border Box( Left( 3 ), top( 2 ),
  V List Box(
   Text Box( "Create a SETID Column" ),
   H List Box(
    V List Box(
    
     // Generate the master display box for the columns in the data table
     Panel Box( "Select Columns",
      colListData = Col List Box( width( 180 ), nLines( Min( N Cols( dt ), 15 ) ) ),
      colListData << append( dt << get column names( "string" ) ),    
      
      // At startup, sselect the columns in the selection box for 
      // the columns that are selected in the data table 
      For( II = 1, II <= N Items( All Columns list ), II++,
       If( Column( ii ) << get selected == 1,
        colListData << set selected( II )
       )
      );
      
     )
    ),    
    
    // Setup the selection buttons and the selection boxes
    Panel Box( "Selected Columns to Create SETID from",
     Lineup Box( N Col( 2 ), Spacing( 3 ),
      Button Box( "Add Column(s)", colListY << Append( colListData << GetSelected ) ),
      colListY = Col List Box( width( 180 ), nLines( 10 ), min col( 1 ), max col( 0 ) ), 

     )
    ),    
    
    // Setup the action buttons that control the window processing
    V List Box(
     Panel Box( "Action",
      Lineup Box( N Col( 1 ),
       Button Box( "OK",    
        // Check to see if the required data has been input
        If( N Items( colListY << GetItems ) == 0,
         Dialog( "No Y Columns Specified", Button( "OK" ) ),   
         
         // Process the Y Columns
         thecols = {};
         thecols = colListY << GetItems;
         
         nw << close window;
         
         runit();
        )
       ),
       Button Box( "Cancel", Stop() ),
       Text Box( " " ),
       Button Box( "Remove", colListY << RemoveSelected ),
       Button Box( "Help", notImplemented )
      )
     )
    ), 

   )
  )
 )
);

// Here is the function that calculates the new column.
runit = Function( {}, 

 If( Try( dt:SetID << get name, "" ) != "",
  dt << delete columns( {"SetID"} )
 );
 
 dt << New Column( "SetID", numeric );
 
 // Set the value for row 1
 mySetID = 1;
 
 dt:SetID[1] = mySetID;
 
 // Loop across the remaining rows, checking for a change from the previous row
 For( i = 2, i <= N Rows( dt ), i++,
  thesame = "Yes";
  For( k = 1, k <= N Items( thecols ), k++,
   If( Column( dt, thecols[k] )[i] != Column( dt, thecols[k] )[i - 1],
    thesame = "No"
   )
  );
  // If a change is found, increase the counter
  If( thesame == "No",
   mySetID
   ++);
  
  // Set the value of the new column
  dt:SetID[i] = mySetID;
 );
);