286284_it-IT

liliconcom

Esiste un modo semplice per creare ID set per set di dati all'interno di una tabella dati?

Ho un numero arbitrario di colonne che definiscono gli input di un processo e un mucchio di altre colonne che sono gli output, e per ogni set di input ci sono un gruppo di righe di output che vengono digitate in tempo.

 

È possibile con .jsl creare una nuova colonna "setid" che inizia con "1" nella riga 1, quindi prende le colonne selezionate dall'utente (1 o più) e ogni volta che uno qualsiasi dei valori in una qualsiasi di queste colonne cambia, aumenta il valore nella colonna setid - altrimenti il setid rimane lo stesso.  Possiamo supporre che le righe siano ordinate ragionevolmente per set.

Tabella datiScriptingRi: C'è un modo semplice per creare ID set per set di dati all'interno di una tabella dati?

Ecco un piccolo esempio con cui puoi iniziare.  Ho recuperato un vecchio codice che ho creato molti anni fa e l'ho modificato.  Viene prima visualizzata una finestra di dialogo

E dopo aver selezionato le colonne, fai clic su OK e crea la nuova colonna.

Se non hai letto la Guida allo scripting ..... ora dovresti farlo.  Per espandere questo semplice script, dovrai comprendere JSL e cosa puoi fare con esso.  Ecco il copione

Clear Symbols();

Names Default To Here( 1 );
dt = Current Data Table();

allcolumnslist = dt << get column names( "string" );

nw = New Window( "Generate SETID Column",
 Border Box( Left( 3 ), top( 2 ),
  V List Box(
   Text Box( "Create a SETID Column" ),
   H List Box(
    V List Box(
    
     // Generate the master display box for the columns in the data table
     Panel Box( "Select Columns",
      colListData = Col List Box( width( 180 ), nLines( Min( N Cols( dt ), 15 ) ) ),
      colListData << append( dt << get column names( "string" ) ),    
      
      // At startup, sselect the columns in the selection box for 
      // the columns that are selected in the data table 
      For( II = 1, II <= N Items( All Columns list ), II++,
       If( Column( ii ) << get selected == 1,
        colListData << set selected( II )
       )
      );
      
     )
    ),    
    
    // Setup the selection buttons and the selection boxes
    Panel Box( "Selected Columns to Create SETID from",
     Lineup Box( N Col( 2 ), Spacing( 3 ),
      Button Box( "Add Column(s)", colListY << Append( colListData << GetSelected ) ),
      colListY = Col List Box( width( 180 ), nLines( 10 ), min col( 1 ), max col( 0 ) ), 

     )
    ),    
    
    // Setup the action buttons that control the window processing
    V List Box(
     Panel Box( "Action",
      Lineup Box( N Col( 1 ),
       Button Box( "OK",    
        // Check to see if the required data has been input
        If( N Items( colListY << GetItems ) == 0,
         Dialog( "No Y Columns Specified", Button( "OK" ) ),   
         
         // Process the Y Columns
         thecols = {};
         thecols = colListY << GetItems;
         
         nw << close window;
         
         runit();
        )
       ),
       Button Box( "Cancel", Stop() ),
       Text Box( " " ),
       Button Box( "Remove", colListY << RemoveSelected ),
       Button Box( "Help", notImplemented )
      )
     )
    ), 

   )
  )
 )
);

// Here is the function that calculates the new column.
runit = Function( {}, 

 If( Try( dt:SetID << get name, "" ) != "",
  dt << delete columns( {"SetID"} )
 );
 
 dt << New Column( "SetID", numeric );
 
 // Set the value for row 1
 mySetID = 1;
 
 dt:SetID[1] = mySetID;
 
 // Loop across the remaining rows, checking for a change from the previous row
 For( i = 2, i <= N Rows( dt ), i++,
  thesame = "Yes";
  For( k = 1, k <= N Items( thecols ), k++,
   If( Column( dt, thecols[k] )[i] != Column( dt, thecols[k] )[i - 1],
    thesame = "No"
   )
  );
  // If a change is found, increase the counter
  If( thesame == "No",
   mySetID
   ++);
  
  // Set the value of the new column
  dt:SetID[i] = mySetID;
 );
);