285880_it-IT

liliconcom

come posso ottenere la stima dell'output del profiler di previsione in uno script?

Ciao a tutti,

Ho un esperimento con molti output e desidero ottenere i valori forniti dalla formula di previsione in uno script per inviarli a una tabella di dati. Qualcuno sa come farlo?

 

Grazie,

José Angelo

 

DAIRi: come posso ottenere la stima dell'output del profiler di previsione in uno script?

Prova questo nel tuo script

 

rfit = fit << Report;

pf=rfit["Prediction Profiler"] << get scriptable object;

pf << Remember Settings;

dtout = (rfit["Prediction Profiler"]["Remembered Settings"][Table Box(1)]<< Make Into Data Table);

Ri: come posso ottenere la stima dell'output del profiler di previsione in uno script?

Il suggerimento di salvare il modello come formula di colonna è valido. Ci sono molti modi per usarlo.

 

Questo esempio illustra come è possibile ottenere direttamente il valore visualizzato nel profiler in un altro modo:

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

fit = dt << Fit Model(
 Y( :weight ),
 Effects( :age, :sex, :height ),
 Personality( "Standard Least Squares" ),
 Emphasis( "Minimal Report" ),
 Run(
  Profiler(
   1,
   Confidence Intervals( 1 ),
   Term Value(
    age( 12, Lock( 0 ), Show( 1 ) ),
    sex( "F", Lock( 0 ), Show( 1 ) ),
    height( 62.55, Lock( 0 ), Show( 1 ) )
   )
  ),
  :weight << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
  Parameter Estimates( 1 ), Scaled Estimates( 0 ),
  Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
  Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
  Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
  Box Cox Y Transformation( 0 )}
 )
);

fit rep = fit << Report;

prediction = Num( fit rep["Prediction Profiler"][AxisBox(1)][TextBox(2)] << Get Text );

Ri: come posso ottenere la stima dell'output del profiler di previsione in uno script?

Se selezioni il triangolo rosso accanto a Risposta>Salva colonne>Formula di previsione , aggiungerà una colonna alla tabella di dati che contiene la formula di previsione. Se fai clic con il pulsante destro del mouse su quella colonna e vai alla Formula (avrà un segno di spunta accanto) puoi visualizzare la formula.