283993_es-ES

liliconcom

Gráfico de barras de columna dividida

Hola,
Tengo una tabla con muchas columnas. una es una variable binaria con 0,1 y etiquetas 0=No, 1=Si.
Otra es una columna de fórmula basada en varias otras que es categórica con los números 0-5.
Me gustaría crear un gráfico de barras con la columna categórica en el eje x y el porcentaje de sí en cada categoría como el eje y.
Podría obtener estos datos dividiendo la tabla usando estas dos columnas (dividida por = la columna categórica y columna dividida = columna binaria) y luego obtengo la distribución de todas las columnas (= categorías originales), y miro el problema de Sí.

pero ¿cómo obtengo esto en un gráfico de barras?
esta es una foto de los datos despechados:

y esta es una foto del tipo de gráfico que me gustaría crear:

AIT

GráficosRe: Gráfico de barras de columna dividida

Esto se puede lograr bastante simplemente usando

Analizar==>Tabular

y luego graficar los datos de la tabla resultante

1. Comience con sus 2 columnas, una con valores 0-1 y la otra con sus valores 0-4. Ambas columnas deben tener un tipo de modelado de Ordinal.He llamado a las filas "Intervención" y "Número de factores de riesgo positivos".
   1. Coloque "intervención como una variable de agrupación de columnas
   2. Coloque "Número de factores de riesgo positivos" como una variable de agrupación de filas
   3. Establezca la estadística como % de fila
2. Vaya al triángulo rojo y seleccione "Convertir en tabla de datos"
3. Cambiar el nombre de la Columna "Fila %(1)" a "Tasa de Intervención"
4. Vaya a Graph Builder y cree el gráfico.
   1. Arrastre "Número de factores de riesgo positivos" al eje X
   2. Arrastre "Tasa de intervención" al eje Y
   3. Haga clic en el icono de gráfico de barras para cambiar el gráfico a un gráfico de barras
   4. En la sección de detalles de la barra en el lado izquierdo de la ventana, cambie la etiqueta a "Etiqueta por valor"

Aquí hay un script que produce lo anterior.

Names Default to Here(1);
dt=new table("Example",
 add rows(400),
 new column("Intervention", ordinal, set each value(Random Integer(0,1))),
 new column("Number of Positive Risk Factors",ordinal,set each value(Random Integer(0,4)))
);

// Calculate the Statistic
tab = dt << Tabulate(invisible,
 Add Table(
  Column Table( Grouping Columns( :Intervention ), Statistics( Row % ) ),
  Row Table( Grouping Columns( :Number of Positive Risk Factors) )
 )
);
dtFinal = tab << make into data table;

// Change Column Name
dtFinal:Name("Row %(1)") << Set Name("Rate of Intervention");

// Create Graph
Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Number of Positive Risk Factors ), Y( :Rate of Intervention ) ),
 Elements( Bar( X, Y, Legend( 6 ), Label( "Label by Value" ) ) )
);