283993_ko-KR

liliconcom

분할 열의 막대 그래프

안녕,
많은 열이 있는 테이블이 있습니다. 하나는 0,1이고 레이블이 0=아니요, 1=예인 이진 변수입니다.
다른 하나는 0-5의 숫자로 범주형인 다른 여러 항목을 기반으로 하는 수식 열입니다.
x축에 범주형 열을 사용하고 y축으로 각 범주에서 예의 백분율을 사용하여 막대 그래프를 만들고 싶습니다.
이 두 열(분할 기준 = 범주형 열 및 분할 열 = 이진 열)을 사용하여 테이블을 분할하여 이 데이터를 얻은 다음 모든 열(=원래 범주)의 분포를 얻고 확률을 확인합니다.

그러나 이것을 막대 그래프로 어떻게 얻을 수 있습니까?
이것은 저주받은 데이터의 사진입니다.

그리고 이것은 내가 만들고 싶은 종류의 그래프의 사진입니다:

티아

제도법Re: 분할 열의 막대 그래프

이것은 다음을 사용하여 상당히 간단하게 수행할 수 있습니다.

분석==>표 작성

그런 다음 결과 테이블에서 데이터를 그래프로 표시

1. 2개의 열로 시작합니다. 하나는 0-1 값이고 다른 하나는 0-4 값입니다. 두 열 모두 모델링 유형이 서수여야 합니다.나는 행을 "개입" 및 "긍정적 위험 요소의 수"라고 불렀습니다.
   1. 열 그룹화 변수로 "개입" 배치
   2. 행 그룹화 변수로 "긍정적 위험 요소의 수"를 배치합니다.
   3. 통계를 행 %로 설정
2. 빨간색 삼각형으로 이동하여 "데이터 테이블로 만들기"를 선택합니다.
3. "Row %(1)" 열의 이름을 "Rate of Intervention"으로 변경하십시오.
4. 그래프 빌더로 이동하여 그래프 생성
   1. "긍정적 위험 요소의 수"를 X축으로 끌어다 놓습니다.
   2. "개입률"을 Y축으로 끌어다 놓습니다.
   3. 막대 그래프 아이콘을 클릭하여 그래프를 막대 차트로 변경합니다.
   4. 창 왼쪽에 있는 막대 세부정보 섹션에서 레이블을 "값별 레이블"로 변경합니다.

다음은 위의 내용을 생성하는 스크립트입니다.

Names Default to Here(1);
dt=new table("Example",
 add rows(400),
 new column("Intervention", ordinal, set each value(Random Integer(0,1))),
 new column("Number of Positive Risk Factors",ordinal,set each value(Random Integer(0,4)))
);

// Calculate the Statistic
tab = dt << Tabulate(invisible,
 Add Table(
  Column Table( Grouping Columns( :Intervention ), Statistics( Row % ) ),
  Row Table( Grouping Columns( :Number of Positive Risk Factors) )
 )
);
dtFinal = tab << make into data table;

// Change Column Name
dtFinal:Name("Row %(1)") << Set Name("Rate of Intervention");

// Create Graph
Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Number of Positive Risk Factors ), Y( :Rate of Intervention ) ),
 Elements( Bar( X, Y, Legend( 6 ), Label( "Label by Value" ) ) )
);