41166_es-ES

liliconcom

Investigación del consumidor: categórica: orden descendente por puntuación media o por respuestas totales

Querida comunidad,

 

Tengo el siguiente script con " Ordenar por puntuación media ( 1 ) "pero no afecta el resultado final. ¿Panel Box tiene tales efectos o estoy haciendo algo mal?

 

Agradezco cualquier idea ...

 

 

 

Panel Box(
    "Resorts:YASMIN, Report:GSQ, SubReport:Marketing, Author:SaitCopuroglu,  " || Long Date( Today() ) || " "
     || Format( Time Of Day( Today() ), "h:m" ),
    Data Table( "Veri_SelectionsTest2016RESORTS.jmp" ) << Categorical(
        Grouping Option( Each Individually ),
        X( :Agency ),
        Responses( :Answer Categorical ),
        Frequencies( 0 ),
        Share Chart( 0 ),
        Legend( 0 ),
        Mean Score( 1 ),
        Std Dev Score( 1 ),
        Order by Mean Score( 1 ),
        Local Data Filter(
            Close Outline( 1 ),
            Conditional,
            Add Filter(
                columns( :Resort, :Year, :Record Date ),
                Where( :Resort == "YASMIN" ),
                Where( :Year == 2017 ),
                Where( :Record Date >= 01May2017 & :Record Date <= Today() ),
                Display( :Resort, Size( 123, 21 ), Check Box Display ),
                Display( :Year, Size( 110, 40 ), Check Box Display )
            )
        ),
        SendToReport(
            Dispatch( {}, "Categorical", OutlineBox, {Set Title( "YASMIN RESORT 2017" )} ),
            Dispatch( {}, "(Resort = YASMIN) and (Record Date == 22May2017)", TextBox, {Set Wrap( 1200 )} ),
            Dispatch(
                {},
                "Responses( Answer Categorical ) By Agency",
                OutlineBox,
                {Set Title( "Responses By AGENCY" )}
            )
        )
    )
)

 

Re: Investigación del consumidor: categórico: orden descendente por puntuación media o por respuestas totales

No es necesario ir a Excel para resolver el problema.  Si bien la solución no es la más simple, la salida de la Plataforma categórica se puede convertir en una tabla de datos JMP directamente.  A continuación se muestra un script "no genérico" que muestra cómo hacer esto.  El script se puede convertir en un código genérico, que funcionaría en la mayoría de los casos.

Names Default To Here( 1 );
dt = Current Data Table();
rpt = dt << Categorical(
 GroupingOption( EachIndividually ),
 X( :SECTION, :MARKET, :COUNTRY ),
 Responses( :VALUE ),
 Frequencies( 0 ),
 ShareChart( 0 ),
 Legend( 0 ),
 MeanScore( 1 ),
 OrderByMeanScore( 1 )
);

dtCountry = New Table( "Country" );

// Build the Country Coulumn
CountryString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridCellBox( 10 )] << get text;
// Buildthe list of Countries
CountryStringList = {};
WordCNT = 3;
While( Trim( Word( WordCNT, CountryString, "\!n" ) ) != "",
 Insert Into( CountryStringLIst, Trim( Word( WordCNT, CountryString, "\!n" ) ) );
 WordCNT++;, 

);
dtCountry << New Column( "Country", character, values( CountryStringList ) );

// Build the Percent Columns
dtCountry << New Column( "Çok iyi", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "İyi", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "Ortalama", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "Zayıf", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "Çok Zayıf", Format( "Percent", 7, 2 ) );
PercentString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridMultiCellBox( 2 )] << get text;
WordCNT = 1;
While( Trim( Word( WordCNT, PercentString, "\!n" ) ) == "", WordCNT++ );
RowCNT = WordCNT - 1;
While( Trim( Word( WordCNT, PercentString, "\!n" ) ) != "",
 TheLine = Trim( Word( WordCNT, PercentString, "\!n" ) );
 For( i = 1, i <= 5, i++,
  Column( dtCountry, i + 1 )[WordCNT - RowCNT] = Num( Trim( Word( i, Theline, "%" ) ) ) / 100
 );
 WordCNT++;
);

// Add the Total Responses Column
TotalString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridCellBox( 2 )] << get text;
TotalStringList = {};
WordCNT = 3;
While( Trim( Word( WordCNT, TotalString, "\!n" ) ) != "",
 Insert Into( TotalStringLIst, Num( Trim( Word( WordCNT, TotalString, "\!n" ) ) ) );
 WordCNT++;,

);
dtCountry << New Column( "Total Responses", values( TotalStringList ) );

// Add the Mean Column
MeanString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridCellBox( 4 )] << get text;
MeanStringList = {};
WordCNT = 3;
While( Trim( Word( WordCNT, MeanString, "\!n" ) ) != "",
 Insert Into( MeanStringLIst, Num( Trim( Word( WordCNT, MeanString, "\!n" ) ) ) );
 WordCNT++;,

);
dtCountry << New Column( "Mean", values( MeanStringList ) );

// Sort the table
dtCountry << Sort( By( :Mean ), Order( Ascending ), Replace Table( 1 ) );

Re: Investigación del consumidor: categórico: orden descendente por puntuación media o por respuestas totales

El problema es que los resultados son un informe de tabla cruzada (no una tabla de datos estándar).  Una solución parcial sería guardar sus resultados en Excel y luego editarlos allí.  Por ejemplo:

NamesDefaultToHere(1);
dt = CurrentDataTable();
rpt = dt << Categorical(
 GroupingOption( EachIndividually ),
 X( :SECTION, :MARKET, :COUNTRY ), Responses( :VALUE ),
 Frequencies(0), ShareChart(0), Legend(0),
 MeanScore(1), OrderByMeanScore(1)
);
rpt << SaveExcelFile( "C:\Categorical.jmp",
 SeparateRowsForEachCellStatistic(1)
);

 

Los siguientes pasos son:

• Abra el archivo de Excel guardado
• Eliminar manualmente las columnas y filas de Excel innecesarias
• Guarde los datos nuevamente en una o más tablas de datos JMP
• Usar ordenación de tabla JMP

 

Re: Investigación del consumidor: categórico: orden descendente por puntuación media o por respuestas totales

Gracias por tu respuesta

Adjunté una tabla de datos simplificada con el script "categórico". La misma pregunta para este análisis específico es, si hay una opción para la disposición de la tabla ascendente o descendente de acuerdo con las respuestas totales y la puntuación media

Intenté "ordenar el valor" de la columna "PAÍS", pero cada vez que se actualizan los datos, el orden del valor también ...

Gracias de antemano

Re: Investigación del consumidor: categórico: orden descendente por puntuación media o por respuestas totales

¿Puede proporcionar una tabla de datos de muestra para este script?